drivers/cadence/uart/aarch64/cdns_console.S

   1 /*
   2  * Copyright (c) 2016-2017, ARM Limited and Contributors. All rights reserved.
   3  *
   4  * SPDX-License-Identifier: BSD-3-Clause
   5  */
   6 #include <arch.h>
   7 #include <asm_macros.S>
   8 #include <assert_macros.S>
   9 #include <cadence/cdns_uart.h>
  10 #define USE_FINISH_CONSOLE_REG_2
  11 #include <console_macros.S>
  12
  13         /*
  14          * "core" functions are low-level implementations that don't require
  15          * writable memory and are thus safe to call in BL1 crash context.
  16          */
  17         .globl console_cdns_core_init
  18         .globl console_cdns_core_putc
  19         .globl console_cdns_core_getc
  20         .globl console_cdns_core_flush
  21
  22         .globl  console_cdns_putc
  23         .globl  console_cdns_getc
  24         .globl  console_cdns_flush
  25
  26         /* -----------------------------------------------
  27          * int console_cdns_core_init(uintptr_t base_addr)
  28          * Function to initialize the console without a
  29          * C Runtime to print debug information. This
  30          * function will be accessed by console_init and
  31          * crash reporting.
  32          * We assume that the bootloader already set up
  33          * the HW (baud, ...) and only enable the trans-
  34          * mitter and receiver here.
  35          * In: x0 - console base address
  36          * Out: return 1 on success else 0 on error
  37          * Clobber list : x1, x2, x3
  38          * -----------------------------------------------
  39          */
  40 func console_cdns_core_init
  41         /* Check the input base address */
  42         cbz     x0, core_init_fail
  43
  44         /* RX/TX enabled & reset */
  45         mov     w3, #(R_UART_CR_TX_EN | R_UART_CR_RX_EN | R_UART_CR_TXRST | R_UART_CR_RXRST)
  46         str     w3, [x0, #R_UART_CR]
  47
  48         mov     w0, #1
  49         ret
  50 core_init_fail:
  51         mov     w0, wzr
  52         ret
  53 endfunc console_cdns_core_init
  54
  55 #if MULTI_CONSOLE_API
  56         .globl console_cdns_register
  57
  58         /* -----------------------------------------------
  59          * int console_cdns_register(uintptr_t baseaddr,
  60          *     uint32_t clock, uint32_t baud,
  61          *     console_cdns_t *console);
  62          * Function to initialize and register a new CDNS
  63          * console. Storage passed in for the console struct
  64          * *must* be persistent (i.e. not from the stack).
  65          * In: x0 - UART register base address
  66          *     w1 - UART clock in Hz
  67          *     w2 - Baud rate
  68          *     x3 - pointer to empty console_16550_t struct
  69          * Out: return 1 on success, 0 on error
  70          * Clobber list : x0, x1, x2, x6, x7, x14
  71          * -----------------------------------------------
  72          */
  73 func console_cdns_register
  74         mov     x7, x30
  75         mov     x6, x3
  76         cbz     x6, register_fail
  77         str     x0, [x6, #CONSOLE_T_CDNS_BASE]
  78
  79         bl      console_cdns_core_init
  80         cbz     x0, register_fail
  81
  82         mov     x0, x6
  83         mov     x30, x7
  84         finish_console_register cdns putc=1, getc=1, flush=1
  85
  86 register_fail:
  87         ret     x7
  88 endfunc console_cdns_register
  89 #else
  90         .globl console_core_init
  91         .globl console_core_putc
  92         .globl console_core_getc
  93         .globl console_core_flush
  94         .equ console_core_init,console_cdns_core_init
  95         .equ console_core_putc,console_cdns_core_putc
  96         .equ console_core_getc,console_cdns_core_getc
  97         .equ console_core_flush,console_cdns_core_flush
  98 #endif
  99
 100         /* --------------------------------------------------------
 101          * int console_cdns_core_putc(int c, uintptr_t base_addr)
 102          * Function to output a character over the console. It
 103          * returns the character printed on success or -1 on error.
 104          * In : w0 - character to be printed
 105          *      x1 - console base address
 106          * Out : return -1 on error else return character.
 107          * Clobber list : x2
 108          * --------------------------------------------------------
 109          */
 110 func console_cdns_core_putc
 111 #if ENABLE_ASSERTIONS
 112         cmp     x1, #0
 113         ASM_ASSERT(ne)
 114 #endif /* ENABLE_ASSERTIONS */
 115
 116         /* Prepend '\r' to '\n' */
 117         cmp     w0, #0xA
 118         b.ne    2f
 119 1:
 120         /* Check if the transmit FIFO is full */
 121         ldr     w2, [x1, #R_UART_SR]
 122         tbnz    w2, #UART_SR_INTR_TFUL_BIT, 1b
 123         mov     w2, #0xD
 124         str     w2, [x1, #R_UART_TX]
 125 2:
 126         /* Check if the transmit FIFO is full */
 127         ldr     w2, [x1, #R_UART_SR]
 128         tbnz    w2, #UART_SR_INTR_TFUL_BIT, 2b
 129         str     w0, [x1, #R_UART_TX]
 130         ret
 131 endfunc console_cdns_core_putc
 132
 133         /* --------------------------------------------------------
 134          * int console_cdns_putc(int c, console_cdns_t *cdns)
 135          * Function to output a character over the console. It
 136          * returns the character printed on success or -1 on error.
 137          * In : w0 - character to be printed
 138          *      x1 - pointer to console_t structure
 139          * Out : return -1 on error else return character.
 140          * Clobber list : x2
 141          * --------------------------------------------------------
 142          */
 143 func console_cdns_putc
 144 #if ENABLE_ASSERTIONS
 145         cmp     x1, #0
 146         ASM_ASSERT(ne)
 147 #endif /* ENABLE_ASSERTIONS */
 148         ldr     x1, [x1, #CONSOLE_T_CDNS_BASE]
 149         b       console_cdns_core_putc
 150 endfunc console_cdns_putc
 151
 152         /* ---------------------------------------------
 153          * int console_cdns_core_getc(uintptr_t base_addr)
 154          * Function to get a character from the console.
 155          * It returns the character grabbed on success
 156          * or -1 if no character is available.
 157          * In : x0 - console base address
 158          * Out: w0 - character if available, else -1
 159          * Clobber list : x0, x1
 160          * ---------------------------------------------
 161          */
 162 func console_cdns_core_getc
 163 #if ENABLE_ASSERTIONS
 164         cmp     x0, #0
 165         ASM_ASSERT(ne)
 166 #endif /* ENABLE_ASSERTIONS */
 167
 168         /* Check if the receive FIFO is empty */
 169         ldr     w1, [x0, #R_UART_SR]
 170         tbnz    w1, #UART_SR_INTR_REMPTY_BIT, no_char
 171         ldr     w1, [x0, #R_UART_RX]
 172         mov     w0, w1
 173         ret
 174 no_char:
 175         mov     w0, #ERROR_NO_PENDING_CHAR
 176         ret
 177 endfunc console_cdns_core_getc
 178
 179         /* ---------------------------------------------
 180          * int console_cdns_getc(console_cdns_t *console)
 181          * Function to get a character from the console.
 182          * It returns the character grabbed on success
 183          * or -1 if no character is available.
 184          * In : x0 - pointer to console_t structure
 185          * Out: w0 - character if available, else -1
 186          * Clobber list : x0, x1
 187          * ---------------------------------------------
 188          */
 189 func console_cdns_getc
 190 #if ENABLE_ASSERTIONS
 191         cmp     x0, #0
 192         ASM_ASSERT(ne)
 193 #endif /* ENABLE_ASSERTIONS */
 194         ldr     x0, [x0, #CONSOLE_T_CDNS_BASE]
 195         b       console_cdns_core_getc
 196 endfunc console_cdns_getc
 197
 198         /* ---------------------------------------------
 199          * int console_cdns_core_flush(uintptr_t base_addr)
 200          * Function to force a write of all buffered
 201          * data that hasn't been output.
 202          * In : x0 - console base address
 203          * Out : return -1 on error else return 0.
 204          * Clobber list : x0, x1
 205          * ---------------------------------------------
 206          */
 207 func console_cdns_core_flush
 208 #if ENABLE_ASSERTIONS
 209         cmp     x0, #0
 210         ASM_ASSERT(ne)
 211 #endif /* ENABLE_ASSERTIONS */
 212         /* Placeholder */
 213         mov     w0, #0
 214         ret
 215 endfunc console_cdns_core_flush
 216
 217         /* ---------------------------------------------
 218          * int console_cdns_flush(console_pl011_t *console)
 219          * Function to force a write of all buffered
 220          * data that hasn't been output.
 221          * In : x0 - pointer to console_t structure
 222          * Out : return -1 on error else return 0.
 223          * Clobber list : x0, x1
 224          * ---------------------------------------------
 225          */
 226 func console_cdns_flush
 227 #if ENABLE_ASSERTIONS
 228         cmp     x0, #0
 229         ASM_ASSERT(ne)
 230 #endif /* ENABLE_ASSERTIONS */
 231         ldr     x0, [x0, #CONSOLE_T_CDNS_BASE]
 232         b       console_cdns_core_flush
 233 endfunc console_cdns_flush