009ed3b689f457568260fa367d5b3992bc6ebae9
[openwrt/openwrt.git] / openwrt / scripts / download.pl
1 #!/usr/bin/perl
2 #
3 # Copyright (C) 2006 OpenWrt.org
4 #
5 # This is free software, licensed under the GNU General Public License v2.
6 # See /LICENSE for more information.
7 #
8
9 use strict;
10 use warnings;
11
12 my $target = shift @ARGV;
13 my $filename = shift @ARGV;
14 my $md5sum = shift @ARGV;
15 my @mirrors;
16
17 my $ok;
18
19 @ARGV > 0 or die "Syntax: $0 <target dir> <filename> <md5sum> <mirror> [<mirror> ...]\n";
20
21 my $md5cmd = `which md5sum`;
22 $md5cmd =~ /not found/ and $md5cmd = `which md5`;
23 $md5cmd =~ /not found/ and die 'no md5 checksum program found, please install md5 or md5sum';
24
25 sub download
26 {
27 my $mirror = shift;
28
29 open WGET, "wget -t1 --timeout=20 -O- \"$mirror/$filename\" |" or die "Cannot launch wget.\n";
30 open MD5SUM, "| $md5cmd > \"$target/$filename.md5sum\"" or die "Cannot launch md5sum.\n";
31 open OUTPUT, "> $target/$filename.dl" or die "Cannot create file $target/$filename.dl: $!\n";
32 my $buffer;
33 while (read WGET, $buffer, 1048576) {
34 print MD5SUM $buffer;
35 print OUTPUT $buffer;
36 }
37 close MD5SUM;
38 close WGET;
39 close OUTPUT;
40
41 if (($? >> 8) != 0 ) {
42 print STDERR "Download failed.\n";
43 cleanup();
44 return;
45 }
46
47 my $sum = `cat "$target/$filename.md5sum"`;
48 $sum =~ /^(\w+)\s+/ or die "Could not generate md5sum\n";
49 $sum = $1;
50
51 if (($md5sum =~ /\w{32}/) and ($sum ne $md5sum)) {
52 print STDERR "MD5 sum of the downloaded file does not match - deleting download.\n";
53 cleanup();
54 return;
55 }
56
57 unlink "$target/$filename";
58 system("mv \"$target/$filename.dl\" \"$target/$filename\"");
59 cleanup();
60 }
61
62 sub cleanup
63 {
64 unlink "$target/$filename.dl";
65 unlink "$target/$filename.md5sum";
66 }
67
68 foreach my $mirror (@ARGV) {
69 if ($mirror =~ /^\@SF\/(.+)$/) {
70 my $sfpath = $1;
71 open SF, "wget -t1 -q -O- 'http://prdownloads.sourceforge.net/$sfpath/$filename' |";
72 while (<SF>) {
73 /RADIO NAME=use_default VALUE=(\w+) OnClick="form\.submit\(\)">/ or
74 /type="radio" name="use_default" value="(\w+)" onclick="form\.submit\(\)"\/>/ and do {
75 push @mirrors, "http://$1.dl.sourceforge.net/sourceforge/$sfpath";
76 };
77 /<a href="\/.+\?use_mirror=(\w+)"><b>Download/ and do {
78 push @mirrors, "http://$1.dl.sourceforge.net/sourceforge/$sfpath";
79 };
80 }
81 push @mirrors, "http://dl.sourceforge.net/sourceforge/$sfpath";
82 close SF;
83 } elsif ($mirror =~ /^\@GNU\/(.+)$/) {
84 my $gnupath = $1;
85 push @mirrors, "ftp://ftp.gnu.org/gnu/$gnupath";
86 push @mirrors, "ftp://ftp.belnet.be/mirror/ftp.gnu.org/gnu/$gnupath";
87 push @mirrors, "ftp://ftp.mirror.nl/pub/mirror/gnu/$gnupath";
88 push @mirrors, "http://mirror.switch.ch/ftp/mirror/gnu/$gnupath";
89 push @mirrors, "ftp://ftp.uu.net/archive/systems/gnu/$gnupath";
90 push @mirrors, "ftp://ftp.eu.uu.net/pub/gnu/$gnupath";
91 push @mirrors, "ftp://ftp.leo.org/pub/comp/os/unix/gnu/$gnupath";
92 push @mirrors, "ftp://ftp.digex.net/pub/gnu/$gnupath";
93 } else {
94 push @mirrors, $mirror;
95 }
96 }
97
98 #push @mirrors, 'http://mirror1.openwrt.org/';
99 push @mirrors, 'http://mirror2.openwrt.org/sources';
100 push @mirrors, 'http://downloads.openwrt.org/sources/';
101
102 while (!$ok) {
103 my $mirror = shift @mirrors;
104 $mirror or die "No more mirrors to try - giving up.\n";
105
106 download($mirror);
107 -f "$target/$filename" and $ok = 1;
108 }
109
110 $SIG{INT} = \&cleanup;
111