scripts/feeds

   1 #!/usr/bin/perl
   2 use Getopt::Std;
   3 use FindBin;
   4 use Cwd;
   5 use lib "$FindBin::Bin";
   6 use metadata;
   7 use warnings;
   8 use strict;
   9 use Cwd 'abs_path';
  10
  11 chdir "$FindBin::Bin/..";
  12 $ENV{TOPDIR}=getcwd();
  13 $ENV{GIT_CONFIG_PARAMETERS}="'core.autocrlf=false'";
  14 $ENV{GREP_OPTIONS}="";
  15
  16 my $mk=`which gmake 2>/dev/null`;       # select the right 'make' program
  17 chomp($mk);             # trim trailing newline
  18 $mk or $mk = "make";    # default to 'make'
  19
  20 # check version of make
  21 my @mkver = split /\s+/, `$mk -v`, 4;
  22 my $valid_mk = 1;
  23 $mkver[0] =~ /^GNU/ or $valid_mk = 0;
  24 $mkver[1] =~ /^Make/ or $valid_mk = 0;
  25 $mkver[2] >= "3.81" or $valid_mk = 0;
  26 $valid_mk or die "Unsupported version of make found: $mk\n";
  27
  28 my @feeds;
  29 my %build_packages;
  30 my %installed;
  31 my %feed_cache;
  32
  33 my $feed_package = {};
  34 my $feed_src = {};
  35
  36 sub parse_config() {
  37         my $line = 0;
  38         my %name;
  39
  40         open FEEDS, "feeds.conf" or
  41                 open FEEDS, "feeds.conf.default" or
  42                 die "Unable to open feeds configuration";
  43         while (<FEEDS>) {
  44                 chomp;
  45                 s/#.+$//;
  46                 next unless /\S/;
  47                 my @line = split /\s+/, $_, 3;
  48                 my @src;
  49                 $line++;
  50
  51                 my $valid = 1;
  52                 $line[0] =~ /^src-\w+$/ or $valid = 0;
  53                 $line[1] =~ /^\w+$/ or $valid = 0;
  54                 @src = split /\s+/, $line[2];
  55                 $valid or die "Syntax error in feeds.conf, line: $line\n";
  56
  57                 $name{$line[1]} and die "Duplicate feed name '$line[1]', line: $line\n";
  58                 $name{$line[1]} = 1;
  59
  60                 push @feeds, [$line[0], $line[1], \@src];
  61         }
  62         close FEEDS;
  63 }
  64
  65 sub update_location($$)
  66 {
  67         my $name = shift;
  68         my $url  = shift;
  69         my $old_url;
  70
  71         -d "./feeds/$name.tmp" or mkdir "./feeds/$name.tmp" or return 1;
  72
  73         if( open LOC, "< ./feeds/$name.tmp/location" )
  74         {
  75                 chomp($old_url = readline LOC);
  76                 close LOC;
  77         }
  78
  79         if( !$old_url || $old_url ne $url )
  80         {
  81                 if( open LOC, "> ./feeds/$name.tmp/location" )
  82                 {
  83                         print LOC $url, "\n";
  84                         close LOC;
  85                 }
  86                 return $old_url ? 1 : 0;
  87         }
  88
  89         return 0;
  90 }
  91
  92 sub update_index($)
  93 {
  94         my $name = shift;
  95
  96         -d "./feeds/$name.tmp" or mkdir "./feeds/$name.tmp" or return 1;
  97         -d "./feeds/$name.tmp/info" or mkdir "./feeds/$name.tmp/info" or return 1;
  98
  99         system("$mk -s prepare-mk OPENWRT_BUILD= TMP_DIR=\"$ENV{TOPDIR}/feeds/$name.tmp\"");
 100         system("$mk -s -f include/scan.mk IS_TTY=1 SCAN_TARGET=\"packageinfo\" SCAN_DIR=\"feeds/$name\" SCAN_NAME=\"package\" SCAN_DEPS=\"$ENV{TOPDIR}/include/package*.mk\" SCAN_DEPTH=5 SCAN_EXTRA=\"\" TMP_DIR=\"$ENV{TOPDIR}/feeds/$name.tmp\"");
 101         system("ln -sf $name.tmp/.packageinfo ./feeds/$name.index");
 102
 103         return 0;
 104 }
 105
 106 my %update_method = (
 107         'src-svn' => {
 108                 'init'          => "svn checkout '%s' '%s'",
 109                 'update'        => "svn update",
 110                 'controldir'    => ".svn",
 111                 'revision'      => "svn info | grep 'Revision' | cut -d ' ' -f 2 | tr -d '\n'"},
 112         'src-cpy' => {
 113                 'init'          => "cp -Rf '%s' '%s'",
 114                 'update'        => "",
 115                 'revision'      => "echo -n 'local'"},
 116         'src-link' => {
 117                 'init'          => "ln -s '%s' '%s'",
 118                 'update'        => "",
 119                 'revision'      => "echo -n 'local'"},
 120         'src-git' => {
 121                 'init'          => "git clone --depth 1 '%s' '%s'",
 122                 'init_branch'   => "git clone --depth 1 --branch '%s' '%s' '%s'",
 123                 'init_commit'   => "git clone '%s' '%s' && cd '%s' && git checkout -b '%s' '%s' && cd -",
 124                 'update'        => "git pull --ff",
 125                 'controldir'    => ".git",
 126                 'revision'      => "git show --abbrev-commit HEAD | head -n 1 | cut -d ' ' -f 2 | tr -d '\n'"},
 127         'src-gitsvn' => {
 128                 'init'  => "git svn clone -r HEAD '%s' '%s'",
 129                 'update'        => "git svn rebase",
 130                 'controldir'    => ".git",
 131                 'revision'      => "git show --abbrev-commit HEAD | head -n 1 | cut -d ' ' -f 2 | tr -d '\n'"},
 132         'src-bzr' => {
 133                 'init'          => "bzr checkout --lightweight '%s' '%s'",
 134                 'update'        => "bzr update",
 135                 'controldir'    => ".bzr"},
 136         'src-hg' => {
 137                 'init'          => "hg clone '%s' '%s'",
 138                 'update'        => "hg pull --update",
 139                 'controldir'    => ".hg"},
 140         'src-darcs' => {
 141                 'init'    => "darcs get '%s' '%s'",
 142                 'update'  => "darcs pull -a",
 143                 'controldir' => "_darcs"},
 144 );
 145
 146 # src-git: pull broken
 147 # src-cpy: broken if `basename $src` != $name
 148
 149 sub update_feed_via($$$$) {
 150         my $type = shift;
 151         my $name = shift;
 152         my $src = shift;
 153         my $relocate = shift;
 154
 155         my $m = $update_method{$type};
 156         my $localpath = "./feeds/$name";
 157         my $safepath = $localpath;
 158         $safepath =~ s/'/'\\''/;
 159         my ($base_branch, $branch) = split(/;/, $src, 2);
 160         my ($base_commit, $commit) = split(/\^/, $src, 2);
 161
 162         if( $relocate || !$m->{'update'} || !-d "$localpath/$m->{'controldir'}" ) {
 163                 system("rm -rf '$safepath'");
 164                 if ($m->{'init_branch'} and $branch) {
 165                         system(sprintf($m->{'init_branch'}, $branch, $base_branch, $safepath)) == 0 or return 1;
 166                 } elsif ($m->{'init_commit'} and $commit) {
 167                         system(sprintf($m->{'init_commit'}, $base_commit, $safepath, $safepath, $commit, $commit)) == 0 or return 1;
 168                 } else {
 169                         system(sprintf($m->{'init'}, $src, $safepath)) == 0 or return 1;
 170                 }
 171         } elsif ($m->{'init_commit'} and $commit) {
 172                 # in case git hash has been provided don't update the feed
 173         } else {
 174                 system("cd '$safepath'; $m->{'update'}") == 0 or return 1;
 175         }
 176
 177         return 0;
 178 }
 179
 180 sub get_feed($) {
 181         my $feed = shift;
 182
 183         if (!defined($feed_cache{$feed})) {
 184                 my $file = "./feeds/$feed.index";
 185
 186                 clear_packages();
 187                 -f $file or do {
 188                         print "Ignoring feed '$feed' - index missing\n";
 189                         return;
 190                 };
 191                 parse_package_metadata($file) or return;
 192                 $feed_cache{$feed} = [ { %package }, { %srcpackage } ];
 193         }
 194
 195         $feed_package = $feed_cache{$feed}->[0];
 196         $feed_src = $feed_cache{$feed}->[1];
 197         return $feed_cache{$feed}->[0];
 198 }
 199
 200 sub get_installed() {
 201         system("$mk -s prepare-tmpinfo OPENWRT_BUILD=");
 202         clear_packages();
 203         parse_package_metadata("./tmp/.packageinfo");
 204         %installed = %package;
 205 }
 206
 207 sub search_feed {
 208         my $feed = shift;
 209         my @substr = @_;
 210         my $display;
 211
 212         return unless @substr > 0;
 213         get_feed($feed);
 214         foreach my $name (sort { lc($a) cmp lc($b) } keys %$feed_package) {
 215                 my $pkg = $feed_package->{$name};
 216                 my $substr;
 217                 my $pkgmatch = 1;
 218
 219                 next if $pkg->{vdepends};
 220                 foreach my $substr (@substr) {
 221                         my $match;
 222                         foreach my $key (qw(name title description src)) {
 223                                 $pkg->{$key} and $substr and $pkg->{$key} =~ m/$substr/i and $match = 1;
 224                         }
 225                         $match or undef $pkgmatch;
 226                 };
 227                 $pkgmatch and do {
 228                         $display or do {
 229                                 print "Search results in feed '$feed':\n";
 230                                 $display = 1;
 231                         };
 232                         printf "\%-25s\t\%s\n", $pkg->{name}, $pkg->{title};
 233                 };
 234         }
 235         return 0;
 236 }
 237
 238 sub search {
 239         my %opts;
 240
 241         getopt('r:', \%opts);
 242         foreach my $feed (@feeds) {
 243                 search_feed($feed->[1], @ARGV) if (!defined($opts{r}) or $opts{r} eq $feed->[1]);
 244         }
 245 }
 246
 247 sub list_feed {
 248         my $feed = shift;
 249
 250         get_feed($feed);
 251         foreach my $name (sort { lc($a) cmp lc($b) } keys %$feed_package) {
 252                 my $pkg = $feed_package->{$name};
 253                 next if $pkg->{vdepends};
 254                 if($pkg->{name}) {
 255                         printf "\%-32s\t\%s\n", $pkg->{name}, $pkg->{title};
 256                 }
 257         }
 258
 259         return 0;
 260 }
 261
 262 sub list {
 263         my %opts;
 264
 265         getopts('r:d:nsh', \%opts);
 266         if ($opts{h}) {
 267                 usage();
 268                 return 0;
 269         }
 270         if ($opts{n}) {
 271                 foreach my $feed (@feeds) {
 272                         printf "%s\n", $feed->[1];
 273                 }
 274                 return 0;
 275         }
 276         if ($opts{s}) {
 277                 foreach my $feed (@feeds) {
 278                         my $localpath = "./feeds/$feed->[1]";
 279                         my $m = $update_method{$feed->[0]};
 280                         my $revision;
 281                         if( !$m->{'revision'} ) {
 282                                 $revision = "X";
 283                         }
 284                         elsif( $m->{'controldir'} && -d "$localpath/$m->{'controldir'}" ) {
 285                                 $revision = `cd '$localpath'; $m->{'revision'}`;
 286                         }
 287                         else {
 288                                 $revision = "local";
 289                         }
 290                         if ($opts{d}) {
 291                                 printf "%s%s%s%s%s%s%s\n", $feed->[1], $opts{d}, $feed->[0], $opts{d}, $revision, $opts{d}, join(", ", @{$feed->[2]});
 292                         }
 293                         else {
 294                                 printf "\%-8s \%-8s \%-8s \%s\n", $feed->[1], $feed->[0], $revision, join(", ", @{$feed->[2]});
 295                         }
 296                 }
 297                 return 0;
 298         }
 299         foreach my $feed (@feeds) {
 300                 list_feed($feed->[1], @ARGV) if (!defined($opts{r}) or $opts{r} eq $feed->[1]);
 301         }
 302         return 0;
 303 }
 304
 305 sub install_generic() {
 306         my $feed = shift;
 307         my $pkg = shift;
 308         my $path = $pkg->{makefile};
 309
 310         if($path) {
 311                 $path =~ s/\/Makefile$//;
 312
 313                 -d "./package/feeds" or mkdir "./package/feeds";
 314                 -d "./package/feeds/$feed->[1]" or mkdir "./package/feeds/$feed->[1]";
 315                 system("ln -sf ../../../$path ./package/feeds/$feed->[1]/");
 316         } else {
 317                 warn "Package is not valid\n";
 318                 return 1;
 319         }
 320
 321         return 0;
 322 }
 323
 324 my %install_method = (
 325         'src-svn' => \&install_generic,
 326         'src-cpy' => \&install_generic,
 327         'src-link' => \&install_generic,
 328         'src-git' => \&install_generic,
 329         'src-gitsvn' => \&install_generic,
 330         'src-bzr' => \&install_generic,
 331         'src-hg' => \&install_generic,
 332         'src-darcs' => \&install_generic,
 333 );
 334
 335 my %feed;
 336
 337 sub lookup_package($$) {
 338         my $feed = shift;
 339         my $package = shift;
 340
 341         foreach my $feed ($feed, @feeds) {
 342                 next unless $feed->[1];
 343                 next unless $feed{$feed->[1]};
 344                 $feed{$feed->[1]}->{$package} and return $feed;
 345         }
 346         return;
 347 }
 348
 349 sub is_core_package($) {
 350         my $package = shift;
 351         foreach my $file ("tmp/info/.packageinfo-$package", glob("tmp/info/.packageinfo-*_$package")) {
 352                 next unless index($file, "tmp/info/.packageinfo-feeds_");
 353                 return 1 if -s $file;
 354         }
 355         return 0;
 356 }
 357
 358 sub install_package {
 359         my $feed = shift;
 360         my $name = shift;
 361         my $ret = 0;
 362
 363         $feed = lookup_package($feed, $name);
 364         $feed or do {
 365                 $installed{$name} and return 0;
 366                 # TODO: check if it's already installed within ./package directory
 367                 $feed_src->{$name} or is_core_package($name) or warn "WARNING: No feed for package '$name' found, maybe it's already part of the standard packages?\n";
 368                 return 0;
 369         };
 370
 371         # switch to the metadata for the selected feed
 372         get_feed($feed->[1]);
 373
 374         my $pkg = $feed{$feed->[1]}->{$name} or return 1;
 375         $pkg->{name} or do {
 376                 $installed{$name} and return 0;
 377                 # TODO: check if this is an alias package, maybe it's known by another name
 378                 warn "WARNING: Package '$name' is not available in feed $feed->[1].\n";
 379                 return 0;
 380         };
 381         my $src = $pkg->{src};
 382         my $type = $feed->[0];
 383         $src or $src = $name;
 384
 385         # previously installed packages set the runtime package
 386         # newly installed packages set the source package
 387         $installed{$src} and return 0;
 388
 389         # check previously installed packages
 390         $installed{$name} and return 0;
 391         $installed{$src} = 1;
 392         warn "Installing package '$src'\n";
 393
 394         $install_method{$type} or do {
 395                 warn "Unknown installation method: '$type'\n";
 396                 return 1;
 397         };
 398
 399         &{$install_method{$type}}($feed, $pkg) == 0 or do {
 400                 warn "failed.\n";
 401                 return 1;
 402         };
 403
 404         # install all dependencies referenced from the source package
 405         foreach my $vpkg (@{$feed_src->{$src}}) {
 406                 foreach my $dep (@{$vpkg->{depends}}, @{$vpkg->{builddepends}}, @{$vpkg->{"builddepends/host"}}) {
 407                         next if $dep =~ /@/;
 408                         $dep =~ s/^\+//;
 409                         $dep =~ s/^.+://;
 410                         $dep =~ s/\/.+$//;
 411                         next unless $dep;
 412                         install_package($feed, $dep) == 0 or $ret = 1;
 413                 }
 414         }
 415
 416         return $ret;
 417 }
 418
 419 sub refresh_config {
 420         my $default = shift;
 421
 422         # workaround for timestamp check
 423         system("rm -f tmp/.packageinfo");
 424
 425         # refresh the config
 426         if ($default) {
 427                 system("$mk oldconfig CONFDEFAULT=\"$default\" Config.in >/dev/null 2>/dev/null");
 428         } else {
 429                 system("$mk defconfig Config.in >/dev/null 2>/dev/null");
 430         }
 431 }
 432
 433 sub install {
 434         my $name;
 435         my %opts;
 436         my $feed;
 437         my $ret = 0;
 438
 439         getopts('ap:d:h', \%opts);
 440
 441         if ($opts{h}) {
 442                 usage();
 443                 return 0;
 444         }
 445
 446         get_installed();
 447
 448         foreach my $f (@feeds) {
 449                 # index all feeds
 450                 $feed{$f->[1]} = get_feed($f->[1]);
 451
 452                 # look up the preferred feed
 453                 $opts{p} and $f->[1] eq $opts{p} and $feed = $f;
 454         }
 455
 456         if($opts{a}) {
 457                 foreach my $f (@feeds) {
 458                         if (!defined($opts{p}) or $opts{p} eq $f->[1]) {
 459                                 printf "Installing all packages from feed %s.\n", $f->[1];
 460                                 get_feed($f->[1]);
 461                                 foreach my $name (sort { lc($a) cmp lc($b) } keys %$feed_package) {
 462                                         my $p = $feed_package->{$name};
 463                                         next if $p->{vdepends};
 464                                         if( $p->{name} ) {
 465                                                 install_package($feed, $p->{name}) == 0 or $ret = 1;
 466                                                 get_feed($f->[1]);
 467                                         }
 468                                 }
 469                         }
 470                 }
 471         } else {
 472                 while ($name = shift @ARGV) {
 473                         install_package($feed, $name) == 0 or $ret = 1;
 474                 }
 475         }
 476
 477         # workaround for timestamp check
 478
 479         # set the defaults
 480         if ($opts{d} and $opts{d} =~ /^[ymn]$/) {
 481                 refresh_config($opts{d});
 482         }
 483
 484         return $ret;
 485 }
 486
 487 sub uninstall {
 488         my %opts;
 489         my $name;
 490         my $uninstall;
 491
 492         getopts('ah', \%opts);
 493
 494         if ($opts{h}) {
 495                 usage();
 496                 return 0;
 497         }
 498
 499         if ($opts{a}) {
 500                 system("rm -rvf ./package/feeds");
 501                 $uninstall = 1;
 502         } else {
 503                 if($#ARGV == -1) {
 504                         warn "WARNING: no package to uninstall\n";
 505                         return 0;
 506                 }
 507                 get_installed();
 508                 while ($name = shift @ARGV) {
 509                         my $pkg = $installed{$name};
 510                         $pkg or do {
 511                                 warn "WARNING: $name not installed\n";
 512                                 next;
 513                         };
 514                         $pkg->{src} and $name = $pkg->{src};
 515                         warn "Uninstalling package '$name'\n";
 516                         system("rm -f ./package/feeds/*/$name");
 517                         $uninstall = 1;
 518                 }
 519         }
 520         $uninstall and refresh_config();
 521         return 0;
 522 }
 523
 524 sub update_feed($$$$)
 525 {
 526         my $type=shift;
 527         my $name=shift;
 528         my $src=shift;
 529         my $perform_update=shift;
 530         my $force_relocate=update_location( $name, "@$src" );
 531
 532         if( $force_relocate ) {
 533                 warn "Source of feed $name has changed, replacing copy\n";
 534         }
 535         $update_method{$type} or do {
 536                 warn "Unknown type '$type' in feed $name\n";
 537                 return 1;
 538         };
 539         $perform_update and do {
 540                 my $failed = 1;
 541                 foreach my $feedsrc (@$src) {
 542                         warn "Updating feed '$name' from '$feedsrc' ...\n";
 543                         next unless update_feed_via($type, $name, $feedsrc, $force_relocate) == 0;
 544                         $failed = 0;
 545                         last;
 546                 }
 547                 $failed and do {
 548                         warn "failed.\n";
 549                         return 1;
 550                 };
 551         };
 552         warn "Create index file './feeds/$name.index' \n";
 553         update_index($name) == 0 or do {
 554                 warn "failed.\n";
 555                 return 1;
 556         };
 557         return 0;
 558 }
 559
 560 sub update {
 561         my %opts;
 562         my $feed_name;
 563         my $perform_update=1;
 564
 565         $ENV{SCAN_COOKIE} = $$;
 566         $ENV{OPENWRT_VERBOSE} = 's';
 567
 568         getopts('ahi', \%opts);
 569
 570         if ($opts{h}) {
 571                 usage();
 572                 return 0;
 573         }
 574
 575         if ($opts{i}) {
 576                 # don't update from (remote) repository
 577                 # only re-create index information
 578                 $perform_update=0;
 579         }
 580
 581         -d "feeds" or do {
 582                         mkdir "feeds" or die "Unable to create the feeds directory";
 583                 };
 584
 585         if ( ($#ARGV == -1) or $opts{a}) {
 586                 foreach my $feed (@feeds) {
 587                         my ($type, $name, $src) = @$feed;
 588                         update_feed($type, $name, $src, $perform_update);
 589                 }
 590         } else {
 591                 while ($feed_name = shift @ARGV) {
 592                         foreach my $feed (@feeds) {
 593                                 my ($type, $name, $src) = @$feed;
 594                                 if($feed_name ne $name) {
 595                                         next;
 596                                 }
 597                                 update_feed($type, $name, $src, $perform_update);
 598                         }
 599                 }
 600         }
 601
 602         refresh_config();
 603
 604         return 0;
 605 }
 606
 607 sub feed_config() {
 608         foreach my $feed (@feeds) {
 609                 my $installed = (-f "feeds/$feed->[1].index");
 610
 611                 printf "\tconfig FEED_%s\n", $feed->[1];
 612                 printf "\t\tbool \"Enable feed %s\"\n", $feed->[1];
 613                 printf "\t\tdepends on PER_FEED_REPO\n";
 614                 printf "\t\tdefault y\n" if $installed;
 615                 printf "\t\thelp\n";
 616                 printf "\t\t Enable the \\\"%s\\\" feed at %s.\n", $feed->[1], $feed->[2][0];
 617                 printf "\n";
 618         }
 619
 620         return 0;
 621 }
 622
 623 sub usage() {
 624         print <<EOF;
 625 Usage: $0 <command> [options]
 626
 627 Commands:
 628         list [options]: List feeds, their content and revisions (if installed)
 629         Options:
 630             -n :            List of feed names.
 631             -s :            List of feed names and their URL.
 632             -r <feedname>:  List packages of specified feed.
 633             -d <delimiter>: Use specified delimiter to distinguish rows (default: spaces)
 634
 635         install [options] <package>: Install a package
 636         Options:
 637             -a :           Install all packages from all feeds or from the specified feed using the -p option.
 638             -p <feedname>: Prefer this feed when installing packages.
 639             -d <y|m|n>:    Set default for newly installed packages.
 640
 641         search [options] <substring>: Search for a package
 642         Options:
 643             -r <feedname>: Only search in this feed
 644
 645         uninstall -a|<package>: Uninstall a package
 646         Options:
 647             -a :           Uninstalls all packages.
 648
 649         update -a|<feedname(s)>: Update packages and lists of feeds in feeds.conf .
 650         Options:
 651             -a :           Update all feeds listed within feeds.conf. Otherwise the specified feeds will be updated.
 652             -i :           Recreate the index only. No feed update from repository is performed.
 653
 654         clean:             Remove downloaded/generated files.
 655
 656 EOF
 657         exit(1);
 658 }
 659
 660 my %commands = (
 661         'list' => \&list,
 662         'update' => \&update,
 663         'install' => \&install,
 664         'search' => \&search,
 665         'uninstall' => \&uninstall,
 666         'feed_config' => \&feed_config,
 667         'clean' => sub {
 668                 system("rm -rf feeds");
 669         }
 670 );
 671
 672 my $arg = shift @ARGV;
 673 $arg or usage();
 674 parse_config;
 675 foreach my $cmd (keys %commands) {
 676         $arg eq $cmd and do {
 677                 exit(&{$commands{$cmd}}());
 678         };
 679 }
 680 usage();