scripts/feeds

   1 #!/usr/bin/env perl
   2 use Getopt::Std;
   3 use FindBin;
   4 use Cwd;
   5 use lib "$FindBin::Bin";
   6 use metadata;
   7 use warnings;
   8 use strict;
   9 use Cwd 'abs_path';
  10
  11 chdir "$FindBin::Bin/..";
  12 $ENV{TOPDIR} //= getcwd();
  13 chdir $ENV{TOPDIR};
  14 $ENV{GIT_CONFIG_PARAMETERS}="'core.autocrlf=false'";
  15 $ENV{GREP_OPTIONS}="";
  16
  17 my $mk=`which gmake 2>/dev/null`;       # select the right 'make' program
  18 chomp($mk);             # trim trailing newline
  19 $mk or $mk = "make";    # default to 'make'
  20
  21 # check version of make
  22 my @mkver = split /\s+/, `$mk -v`, 4;
  23 my $valid_mk = 1;
  24 $mkver[0] =~ /^GNU/ or $valid_mk = 0;
  25 $mkver[1] =~ /^Make/ or $valid_mk = 0;
  26
  27 my ($mkv1, $mkv2) = split /\./, $mkver[2];
  28 ($mkv1 >= 4 || ($mkv1 == 3 && $mkv2 >= 81)) or $valid_mk = 0;
  29
  30 $valid_mk or die "Unsupported version of make found: $mk\n";
  31
  32 my @feeds;
  33 my %build_packages;
  34 my %installed;
  35 my %installed_targets;
  36 my %feed_cache;
  37
  38 my $feed_package = {};
  39 my $feed_src = {};
  40 my $feed_target = {};
  41
  42 sub parse_config() {
  43         my $line = 0;
  44         my %name;
  45
  46         open FEEDS, "feeds.conf" or
  47                 open FEEDS, "feeds.conf.default" or
  48                 die "Unable to open feeds configuration";
  49         while (<FEEDS>) {
  50                 chomp;
  51                 s/#.+$//;
  52                 next unless /\S/;
  53                 my @line = split /\s+/, $_, 3;
  54                 my @src;
  55                 $line++;
  56
  57                 my $valid = 1;
  58                 $line[0] =~ /^src-[\w-]+$/ or $valid = 0;
  59                 $line[1] =~ /^\w+$/ or $valid = 0;
  60                 @src = split /\s+/, $line[2];
  61                 $valid or die "Syntax error in feeds.conf, line: $line\n";
  62
  63                 $name{$line[1]} and die "Duplicate feed name '$line[1]', line: $line\n";
  64                 $name{$line[1]} = 1;
  65
  66                 push @feeds, [$line[0], $line[1], \@src];
  67         }
  68         close FEEDS;
  69 }
  70
  71 sub update_location($$)
  72 {
  73         my $name = shift;
  74         my $url  = shift;
  75         my $old_url;
  76
  77         -d "./feeds/$name.tmp" or mkdir "./feeds/$name.tmp" or return 1;
  78
  79         if( open LOC, "< ./feeds/$name.tmp/location" )
  80         {
  81                 chomp($old_url = readline LOC);
  82                 close LOC;
  83         }
  84
  85         if( !$old_url || $old_url ne $url )
  86         {
  87                 if( open LOC, "> ./feeds/$name.tmp/location" )
  88                 {
  89                         print LOC $url, "\n";
  90                         close LOC;
  91                 }
  92                 return $old_url ? 1 : 0;
  93         }
  94
  95         return 0;
  96 }
  97
  98 sub update_index($)
  99 {
 100         my $name = shift;
 101
 102         -d "./feeds/$name.tmp" or mkdir "./feeds/$name.tmp" or return 1;
 103         -d "./feeds/$name.tmp/info" or mkdir "./feeds/$name.tmp/info" or return 1;
 104
 105         system("$mk -s prepare-mk OPENWRT_BUILD= TMP_DIR=\"$ENV{TOPDIR}/feeds/$name.tmp\"");
 106         system("$mk -s -f include/scan.mk IS_TTY=1 SCAN_TARGET=\"packageinfo\" SCAN_DIR=\"feeds/$name\" SCAN_NAME=\"package\" SCAN_DEPS=\"$ENV{TOPDIR}/include/package*.mk\" SCAN_DEPTH=5 SCAN_EXTRA=\"\" TMP_DIR=\"$ENV{TOPDIR}/feeds/$name.tmp\"");
 107         system("$mk -s -f include/scan.mk IS_TTY=1 SCAN_TARGET=\"targetinfo\" SCAN_DIR=\"feeds/$name\" SCAN_NAME=\"target\" SCAN_DEPS=\"profiles/*.mk $ENV{TOPDIR}/include/target.mk\" SCAN_DEPTH=5 SCAN_EXTRA=\"\" SCAN_MAKEOPTS=\"TARGET_BUILD=1\" TMP_DIR=\"$ENV{TOPDIR}/feeds/$name.tmp\"");
 108         system("ln -sf $name.tmp/.packageinfo ./feeds/$name.index");
 109         system("ln -sf $name.tmp/.targetinfo ./feeds/$name.targetindex");
 110
 111         return 0;
 112 }
 113
 114 my %update_method = (
 115         'src-svn' => {
 116                 'init'          => "svn checkout '%s' '%s'",
 117                 'update'        => "svn update",
 118                 'controldir'    => ".svn",
 119                 'revision'      => "svn info | grep 'Revision' | cut -d ' ' -f 2 | tr -d '\n'"},
 120         'src-cpy' => {
 121                 'init'          => "cp -Rf '%s' '%s'",
 122                 'update'        => "",
 123                 'revision'      => "echo -n 'local'"},
 124         'src-link' => {
 125                 'init'          => "ln -s '%s' '%s'",
 126                 'update'        => "",
 127                 'revision'      => "echo -n 'local'"},
 128         'src-git' => {
 129                 'init'          => "git clone --depth 1 '%s' '%s'",
 130                 'init_branch'   => "git clone --depth 1 --branch '%s' '%s' '%s'",
 131                 'init_commit'   => "git clone '%s' '%s' && cd '%s' && git checkout -b '%s' '%s' && cd -",
 132                 'update'        => "git pull --ff",
 133                 'update_force'  => "git pull --ff || (git reset --hard HEAD; git pull --ff; exit 1)",
 134                 'controldir'    => ".git",
 135                 'revision'      => "git rev-parse --short HEAD | tr -d '\n'"},
 136         'src-git-full' => {
 137                 'init'          => "git clone '%s' '%s'",
 138                 'init_branch'   => "git clone --branch '%s' '%s' '%s'",
 139                 'init_commit'   => "git clone '%s' '%s' && cd '%s' && git checkout -b '%s' '%s' && cd -",
 140                 'update'        => "git pull --ff",
 141                 'update_force'  => "git pull --ff || (git reset --hard HEAD; git pull --ff; exit 1)",
 142                 'controldir'    => ".git",
 143                 'revision'      => "git rev-parse --short HEAD | tr -d '\n'"},
 144         'src-gitsvn' => {
 145                 'init'  => "git svn clone -r HEAD '%s' '%s'",
 146                 'update'        => "git svn rebase",
 147                 'controldir'    => ".git",
 148                 'revision'      => "git rev-parse --short HEAD | tr -d '\n'"},
 149         'src-bzr' => {
 150                 'init'          => "bzr checkout --lightweight '%s' '%s'",
 151                 'update'        => "bzr update",
 152                 'controldir'    => ".bzr"},
 153         'src-hg' => {
 154                 'init'          => "hg clone '%s' '%s'",
 155                 'update'        => "hg pull --update",
 156                 'controldir'    => ".hg"},
 157         'src-darcs' => {
 158                 'init'    => "darcs get '%s' '%s'",
 159                 'update'  => "darcs pull -a",
 160                 'controldir' => "_darcs"},
 161 );
 162
 163 # src-git: pull broken
 164 # src-cpy: broken if `basename $src` != $name
 165
 166 sub update_feed_via($$$$$) {
 167         my $type = shift;
 168         my $name = shift;
 169         my $src = shift;
 170         my $relocate = shift;
 171         my $force = shift;
 172
 173         my $m = $update_method{$type};
 174         my $localpath = "./feeds/$name";
 175         my $safepath = $localpath;
 176         $safepath =~ s/'/'\\''/;
 177         my ($base_branch, $branch) = split(/;/, $src, 2);
 178         my ($base_commit, $commit) = split(/\^/, $src, 2);
 179
 180         if( $relocate || !$m->{'update'} || !-d "$localpath/$m->{'controldir'}" ) {
 181                 system("rm -rf '$safepath'");
 182                 if ($m->{'init_branch'} and $branch) {
 183                         system(sprintf($m->{'init_branch'}, $branch, $base_branch, $safepath)) == 0 or return 1;
 184                 } elsif ($m->{'init_commit'} and $commit) {
 185                         system(sprintf($m->{'init_commit'}, $base_commit, $safepath, $safepath, $commit, $commit)) == 0 or return 1;
 186                 } else {
 187                         system(sprintf($m->{'init'}, $src, $safepath)) == 0 or return 1;
 188                 }
 189         } elsif ($m->{'init_commit'} and $commit) {
 190                 # in case git hash has been provided don't update the feed
 191         } else {
 192                 my $update_cmd = $m->{'update'};
 193                 if ($force && exists $m->{'update_force'}) {
 194                         $update_cmd = $m->{'update_force'};
 195                 }
 196                 system("cd '$safepath'; $update_cmd") == 0 or return 1;
 197         }
 198
 199         return 0;
 200 }
 201
 202 sub get_targets($) {
 203         my $file = shift;
 204         my @target = parse_target_metadata($file);
 205         my %target;
 206         foreach my $target (@target) {
 207                 $target{$target->{id}} = $target;
 208         }
 209         return %target
 210 }
 211
 212 sub get_feed($) {
 213         my $feed = shift;
 214
 215         if (!defined($feed_cache{$feed})) {
 216                 my $file = "./feeds/$feed.index";
 217
 218                 clear_packages();
 219                 -f $file or do {
 220                         print "Ignoring feed '$feed' - index missing\n";
 221                         return;
 222                 };
 223                 parse_package_metadata($file) or return;
 224                 my %target = get_targets("./feeds/$feed.targetindex");
 225
 226                 $feed_cache{$feed} = [ { %package }, { %srcpackage }, { %target } ];
 227         }
 228
 229         $feed_package = $feed_cache{$feed}->[0];
 230         $feed_src = $feed_cache{$feed}->[1];
 231         $feed_target = $feed_cache{$feed}->[2];
 232         return $feed_cache{$feed}->[0];
 233 }
 234
 235 sub get_installed() {
 236         system("$mk -s prepare-tmpinfo OPENWRT_BUILD=");
 237         clear_packages();
 238         parse_package_metadata("./tmp/.packageinfo");
 239         %installed = %package;
 240         %installed_targets = get_targets("./tmp/.targetinfo");
 241 }
 242
 243 sub search_feed {
 244         my $feed = shift;
 245         my @substr = @_;
 246         my $display;
 247
 248         return unless @substr > 0;
 249         get_feed($feed);
 250         foreach my $name (sort { lc($a) cmp lc($b) } keys %$feed_package) {
 251                 my $pkg = $feed_package->{$name};
 252                 my $substr;
 253                 my $pkgmatch = 1;
 254
 255                 next if $pkg->{vdepends};
 256                 foreach my $substr (@substr) {
 257                         my $match;
 258                         foreach my $key (qw(name title description src)) {
 259                                 $pkg->{$key} and $substr and $pkg->{$key} =~ m/$substr/i and $match = 1;
 260                         }
 261                         $match or undef $pkgmatch;
 262                 };
 263                 $pkgmatch and do {
 264                         $display or do {
 265                                 print "Search results in feed '$feed':\n";
 266                                 $display = 1;
 267                         };
 268                         printf "\%-25s\t\%s\n", $pkg->{name}, $pkg->{title};
 269                 };
 270         }
 271
 272         foreach my $name (sort { lc($a) cmp lc($b) } keys %$feed_target) {
 273                 my $target = $feed_target->{$name};
 274                 my $targetmatch = 1;
 275
 276                 foreach my $substr (@substr) {
 277                         my $match;
 278                         foreach my $key (qw(id name description)) {
 279                                 $target->{$key} and $substr and $target->{$key} =~ m/$substr/i and $match = 1;
 280                         }
 281                         $match or undef $targetmatch;
 282                 };
 283                 $targetmatch and do {
 284                         $display or do {
 285                                 print "Search results in feed '$feed':\n";
 286                                 $display = 1;
 287                         };
 288                         printf "TARGET: \%-17s\t\%s\n", $target->{id}, $target->{name};
 289                 };
 290         }
 291         return 0;
 292 }
 293
 294 sub search {
 295         my %opts;
 296
 297         getopt('r:', \%opts);
 298         foreach my $feed (@feeds) {
 299                 search_feed($feed->[1], @ARGV) if (!defined($opts{r}) or $opts{r} eq $feed->[1]);
 300         }
 301 }
 302
 303 sub list_feed {
 304         my $feed = shift;
 305
 306         get_feed($feed);
 307         foreach my $name (sort { lc($a) cmp lc($b) } keys %$feed_package) {
 308                 my $pkg = $feed_package->{$name};
 309                 next if $pkg->{vdepends};
 310                 if($pkg->{name}) {
 311                         printf "\%-32s\t\%s\n", $pkg->{name}, $pkg->{title};
 312                 }
 313         }
 314
 315         foreach my $name (sort { lc($a) cmp lc($b) } keys %$feed_target) {
 316                 my $target = $feed_target->{$name};
 317                 if($target->{name}) {
 318                         printf "TARGET: \%-24s\t\%s\n", $target->{id}, $target->{name};
 319                 }
 320         }
 321
 322         return 0;
 323 }
 324
 325 sub list {
 326         my %opts;
 327
 328         getopts('r:d:nshf', \%opts);
 329         if ($opts{h}) {
 330                 usage();
 331                 return 0;
 332         }
 333         if ($opts{n}) {
 334                 foreach my $feed (@feeds) {
 335                         printf "%s\n", $feed->[1];
 336                 }
 337                 return 0;
 338         }
 339         if ($opts{s}) {
 340                 foreach my $feed (@feeds) {
 341                         my $localpath = "./feeds/$feed->[1]";
 342                         my $m = $update_method{$feed->[0]};
 343                         my $revision;
 344                         if (!-d "$localpath" || !$m->{'revision'}) {
 345                                 $revision = "X";
 346                         }
 347                         elsif( $m->{'controldir'} && -d "$localpath/$m->{'controldir'}" ) {
 348                                 $revision = `cd '$localpath'; $m->{'revision'}`;
 349                         }
 350                         else {
 351                                 $revision = "local";
 352                         }
 353                         if ($opts{d}) {
 354                                 printf "%s%s%s%s%s%s%s\n", $feed->[1], $opts{d}, $feed->[0], $opts{d}, $revision, $opts{d}, join(", ", @{$feed->[2]});
 355                         }
 356                         elsif ($opts{f}) {
 357                                 my $uri = join(", ", @{$feed->[2]});
 358                                 if ($revision ne "local" && $revision ne "X") {
 359                                         $uri =~ s/[;^].*//;
 360                                         $uri .= "^" . $revision;
 361                                 }
 362                                 printf "%s %s %s\n", $feed->[0], $feed->[1], $uri;
 363                         }
 364                         else {
 365                                 printf "\%-10s \%-8s \%-8s \%s\n", $feed->[1], $feed->[0], $revision, join(", ", @{$feed->[2]});
 366                         }
 367                 }
 368                 return 0;
 369         }
 370         foreach my $feed (@feeds) {
 371                 list_feed($feed->[1], @ARGV) if (!defined($opts{r}) or $opts{r} eq $feed->[1]);
 372         }
 373         return 0;
 374 }
 375
 376 sub do_install_package($$) {
 377         my $feed = shift;
 378         my $pkg = shift;
 379         my $path = $pkg->{makefile};
 380
 381         if($path) {
 382                 $path =~ s/\/Makefile$//;
 383
 384                 -d "./package/feeds" or mkdir "./package/feeds";
 385                 -d "./package/feeds/$feed->[1]" or mkdir "./package/feeds/$feed->[1]";
 386                 system("ln -sf ../../../$path ./package/feeds/$feed->[1]/");
 387         } else {
 388                 warn "Package is not valid\n";
 389                 return 1;
 390         }
 391
 392         return 0;
 393 }
 394
 395 sub do_install_target($) {
 396         my $target = shift;
 397         my $path = $target->{makefile};
 398
 399         if ($path) {
 400                 $path =~ s/\/Makefile$//;
 401                 my $name = $path;
 402                 $name =~ s/.*\///;
 403                 my $dest = "./target/linux/$name";
 404
 405                 -e $dest and do {
 406                         warn "Path $dest already exists";
 407                         return 1;
 408                 };
 409
 410                 system("ln -sf ../../$path ./target/linux/");
 411         } else {
 412                 warn "Target is not valid\n";
 413                 return 1;
 414         }
 415
 416         return 0;
 417 }
 418
 419 sub lookup_package($$) {
 420         my $feed = shift;
 421         my $package = shift;
 422
 423         foreach my $feed ($feed, @feeds) {
 424                 next unless $feed->[1];
 425                 next unless $feed_cache{$feed->[1]};
 426                 $feed_cache{$feed->[1]}->[0]->{$package} and return $feed;
 427         }
 428         return;
 429 }
 430
 431 sub lookup_target($$) {
 432         my $feed = shift;
 433         my $target = shift;
 434
 435         foreach my $feed ($feed, @feeds) {
 436                 next unless $feed->[1];
 437                 next unless $feed_cache{$feed->[1]};
 438                 $feed_cache{$feed->[1]}->[2]->{$target} and return $feed;
 439         }
 440         return;
 441 }
 442
 443 sub is_core_package($) {
 444         my $package = shift;
 445         foreach my $file ("tmp/info/.packageinfo-$package", glob("tmp/info/.packageinfo-*_$package")) {
 446                 next unless index($file, "tmp/info/.packageinfo-feeds_");
 447                 return 1 if -s $file;
 448         }
 449         return 0;
 450 }
 451
 452 sub install_target {
 453         my $feed = shift;
 454         my $name = shift;
 455
 456         $feed = $feed_cache{$feed->[1]}->[2];
 457         $feed or return 0;
 458
 459         my $target = $feed->{$name};
 460         $target or return 0;
 461
 462         warn "Installing target '$name'\n";
 463         return do_install_target($target);
 464 }
 465
 466 sub install_package {
 467         my $feed = shift;
 468         my $name = shift;
 469         my $force = shift;
 470         my $ret = 0;
 471
 472         my $this_feed_target = lookup_target($feed, $name);
 473         $this_feed_target and do {
 474                 $installed_targets{$name} and return 0;
 475                 install_target($this_feed_target, $name);
 476                 return 0;
 477         };
 478
 479         $feed = lookup_package($feed, $name);
 480         $feed or do {
 481                 $installed{$name} and return 0;
 482                 # TODO: check if it's already installed within ./package directory
 483                 $feed_src->{$name} or is_core_package($name) or warn "WARNING: No feed for package '$name' found, maybe it's already part of the standard packages?\n";
 484                 return 0;
 485         };
 486
 487         # switch to the metadata for the selected feed
 488         my $cur = get_feed($feed->[1]);
 489
 490         my $pkg = $cur->{$name} or return 1;
 491         $pkg->{name} or do {
 492                 $installed{$name} and return 0;
 493                 # TODO: check if this is an alias package, maybe it's known by another name
 494                 warn "WARNING: Package '$name' is not available in feed $feed->[1].\n";
 495                 return 0;
 496         };
 497         my $src = $pkg->{src};
 498         my $type = $feed->[0];
 499         $src or $src = $name;
 500
 501         # If it's a core package and we don't want to override, just return
 502         !$force and is_core_package($src) and return 0;
 503
 504         # previously installed packages set the runtime package
 505         # newly installed packages set the source package to 1
 506         $installed{$src} and $installed{$src} == 1 and return 0;
 507
 508         # we'll trigger the override only with the 3 conditions below:
 509         # - override is allowed by command line (-f)
 510         # - a package with the same src exists in the core packages list
 511         # - the package previously installed is not from a feed
 512         my $override = 1 if ($force and is_core_package($src) and !$installed{$name}->{feed});
 513
 514         # check previously installed packages
 515         $installed{$name} and !$override and return 0;
 516         $installed{$src} = 1;
 517
 518         defined($override) and $override == 1
 519                 and warn "Overriding core package '$src' with version from $feed->[1]\n"
 520                 or warn "Installing package '$src' from $feed->[1]\n";
 521
 522         do_install_package($feed, $pkg) == 0 or do {
 523                 warn "failed.\n";
 524                 return 1;
 525         };
 526
 527         # install all dependencies referenced from the source package
 528         foreach my $vpkg (@{$feed_src->{$src}}) {
 529                 foreach my $dep (@{$vpkg->{depends}}, @{$vpkg->{builddepends}}, @{$vpkg->{"builddepends/host"}}) {
 530                         next if $dep =~ /@/;
 531                         $dep =~ s/^\+//;
 532                         $dep =~ s/^.+://;
 533                         $dep =~ s/\/.+$//;
 534                         next unless $dep;
 535                         install_package($feed, $dep, 0) == 0 or $ret = 1;
 536                 }
 537         }
 538
 539         return $ret;
 540 }
 541
 542 sub refresh_config {
 543         my $default = shift;
 544
 545         # Don't create .config if it doesn't already exist so that making a
 546         # config only occurs when the user intends it do (however we do
 547         # want to refresh an existing config).
 548         return if not (-e '.config');
 549
 550         # workaround for timestamp check
 551         system("rm -f tmp/.packageinfo");
 552
 553         # refresh the config
 554         if ($default) {
 555                 system("$mk oldconfig CONFDEFAULT=\"$default\" Config.in >/dev/null 2>/dev/null");
 556         } else {
 557                 system("$mk defconfig Config.in >/dev/null 2>/dev/null");
 558         }
 559 }
 560
 561 sub install {
 562         my $name;
 563         my %opts;
 564         my $feed;
 565         my $ret = 0;
 566
 567         getopts('ap:d:fh', \%opts);
 568
 569         if ($opts{h}) {
 570                 usage();
 571                 return 0;
 572         }
 573
 574         get_installed();
 575
 576         foreach my $f (@feeds) {
 577                 # fetch all feeds
 578                 get_feed($f->[1]);
 579
 580                 # look up the preferred feed
 581                 $opts{p} and $f->[1] eq $opts{p} and $feed = $f;
 582         }
 583
 584         if($opts{a}) {
 585                 foreach my $f (@feeds) {
 586                         if (!defined($opts{p}) or $opts{p} eq $f->[1]) {
 587                                 printf "Installing all packages from feed %s.\n", $f->[1];
 588                                 get_feed($f->[1]);
 589                                 foreach my $name (sort { lc($a) cmp lc($b) } keys %$feed_package) {
 590                                         my $p = $feed_package->{$name};
 591                                         next if $p->{vdepends};
 592                                         if( $p->{name} ) {
 593                                                 install_package($feed, $p->{name}, exists($opts{f})) == 0 or $ret = 1;
 594                                                 get_feed($f->[1]);
 595                                         }
 596                                 }
 597                         }
 598                 }
 599         } else {
 600                 while ($name = shift @ARGV) {
 601                         install_package($feed, $name, exists($opts{f})) == 0 or $ret = 1;
 602                 }
 603         }
 604
 605         # workaround for timestamp check
 606
 607         # set the defaults
 608         if ($opts{d} and $opts{d} =~ /^[ymn]$/) {
 609                 refresh_config($opts{d});
 610         }
 611
 612         return $ret;
 613 }
 614
 615 sub uninstall_target($) {
 616         my $dir = shift;
 617         my $name = $dir;
 618         $name =~ s/.*\///g;
 619
 620         my $dest = readlink $dir;
 621         return unless $dest =~ /..\/..\/feeds/;
 622         warn "Uninstalling target '$name'\n";
 623         unlink "$dir";
 624 }
 625
 626 sub uninstall {
 627         my %opts;
 628         my $name;
 629         my $uninstall;
 630
 631         getopts('ah', \%opts);
 632
 633         if ($opts{h}) {
 634                 usage();
 635                 return 0;
 636         }
 637
 638         if ($opts{a}) {
 639                 system("rm -rvf ./package/feeds");
 640                 foreach my $dir (glob "target/linux/*") {
 641                         next unless -l $dir;
 642                         uninstall_target($dir);
 643                 }
 644                 $uninstall = 1;
 645         } else {
 646                 if($#ARGV == -1) {
 647                         warn "WARNING: no package to uninstall\n";
 648                         return 0;
 649                 }
 650                 get_installed();
 651                 while ($name = shift @ARGV) {
 652                         my $target = "target/linux/$name";
 653                         -l "$target" and do {
 654                                 uninstall_target($target);
 655                                 $uninstall = 1;
 656                                 next;
 657                         };
 658
 659                         my $pkg = $installed{$name};
 660                         $pkg or do {
 661                                 warn "WARNING: $name not installed\n";
 662                                 next;
 663                         };
 664                         $pkg->{src} and $name = $pkg->{src};
 665                         warn "Uninstalling package '$name'\n";
 666                         system("rm -f ./package/feeds/*/$name");
 667                         $uninstall = 1;
 668                 }
 669         }
 670         $uninstall and refresh_config();
 671         return 0;
 672 }
 673
 674 sub update_feed($$$$$)
 675 {
 676         my $type=shift;
 677         my $name=shift;
 678         my $src=shift;
 679         my $perform_update=shift;
 680         my $force_update=shift;
 681         my $force_relocate=update_location( $name, "@$src" );
 682         my $rv=0;
 683
 684         if( $force_relocate ) {
 685                 warn "Source of feed $name has changed, replacing copy\n";
 686         }
 687         $update_method{$type} or do {
 688                 warn "Unknown type '$type' in feed $name\n";
 689                 return 1;
 690         };
 691         $perform_update and do {
 692                 my $failed = 1;
 693                 foreach my $feedsrc (@$src) {
 694                         warn "Updating feed '$name' from '$feedsrc' ...\n";
 695                         if (update_feed_via($type, $name, $feedsrc, $force_relocate, $force_update) != 0) {
 696                                 if ($force_update) {
 697                                         $rv=1;
 698                                         $failed=0;
 699                                         warn "failed, ignore.\n";
 700                                         next;
 701                                 }
 702                                 last;
 703                         }
 704                         $failed = 0;
 705                 }
 706                 $failed and do {
 707                         warn "failed.\n";
 708                         return 1;
 709                 };
 710         };
 711         warn "Create index file './feeds/$name.index' \n";
 712         update_index($name) == 0 or do {
 713                 warn "failed.\n";
 714                 return 1;
 715         };
 716         return $rv;
 717 }
 718
 719 sub update {
 720         my %opts;
 721         my $feed_name;
 722         my $perform_update=1;
 723         my $failed=0;
 724
 725         $ENV{SCAN_COOKIE} = $$;
 726         $ENV{OPENWRT_VERBOSE} = 's';
 727
 728         getopts('ahif', \%opts);
 729
 730         if ($opts{h}) {
 731                 usage();
 732                 return 0;
 733         }
 734
 735         if ($opts{i}) {
 736                 # don't update from (remote) repository
 737                 # only re-create index information
 738                 $perform_update=0;
 739         }
 740
 741         -d "feeds" or do {
 742                         mkdir "feeds" or die "Unable to create the feeds directory";
 743                 };
 744
 745         if ( ($#ARGV == -1) or $opts{a}) {
 746                 foreach my $feed (@feeds) {
 747                         my ($type, $name, $src) = @$feed;
 748                         update_feed($type, $name, $src, $perform_update, $opts{f}) == 0 or $failed=1;
 749                 }
 750         } else {
 751                 while ($feed_name = shift @ARGV) {
 752                         foreach my $feed (@feeds) {
 753                                 my ($type, $name, $src) = @$feed;
 754                                 if($feed_name ne $name) {
 755                                         next;
 756                                 }
 757                                 update_feed($type, $name, $src, $perform_update, $opts{f}) == 0 or $failed=1;
 758                         }
 759                 }
 760         }
 761
 762         refresh_config();
 763
 764         return $failed;
 765 }
 766
 767 sub feed_config() {
 768         foreach my $feed (@feeds) {
 769                 my $installed = (-f "feeds/$feed->[1].index");
 770
 771                 printf "\tconfig FEED_%s\n", $feed->[1];
 772                 printf "\t\tbool \"Enable feed %s\"\n", $feed->[1];
 773                 printf "\t\tdepends on PER_FEED_REPO\n";
 774                 printf "\t\tdefault y\n" if $installed;
 775                 printf "\t\thelp\n";
 776                 printf "\t\t Enable the \\\"%s\\\" feed at %s.\n", $feed->[1], $feed->[2][0];
 777                 printf "\n";
 778         }
 779
 780         return 0;
 781 }
 782
 783 sub usage() {
 784         print <<EOF;
 785 Usage: $0 <command> [options]
 786
 787 Commands:
 788         list [options]: List feeds, their content and revisions (if installed)
 789         Options:
 790             -n :            List of feed names.
 791             -s :            List of feed names and their URL.
 792             -r <feedname>:  List packages of specified feed.
 793             -d <delimiter>: Use specified delimiter to distinguish rows (default: spaces)
 794             -f :            List feeds in feeds.conf compatible format (when using -s).
 795
 796         install [options] <package>: Install a package
 797         Options:
 798             -a :           Install all packages from all feeds or from the specified feed using the -p option.
 799             -p <feedname>: Prefer this feed when installing packages.
 800             -d <y|m|n>:    Set default for newly installed packages.
 801             -f :           Install will be forced even if the package exists in core OpenWrt (override)
 802
 803         search [options] <substring>: Search for a package
 804         Options:
 805             -r <feedname>: Only search in this feed
 806
 807         uninstall -a|<package>: Uninstall a package
 808         Options:
 809             -a :           Uninstalls all packages.
 810
 811         update -a|<feedname(s)>: Update packages and lists of feeds in feeds.conf .
 812         Options:
 813             -a :           Update all feeds listed within feeds.conf. Otherwise the specified feeds will be updated.
 814             -i :           Recreate the index only. No feed update from repository is performed.
 815             -f :           Force updating feeds even if there are changed, uncommitted files.
 816
 817         clean:             Remove downloaded/generated files.
 818
 819 EOF
 820         exit(1);
 821 }
 822
 823 my %commands = (
 824         'list' => \&list,
 825         'update' => \&update,
 826         'install' => \&install,
 827         'search' => \&search,
 828         'uninstall' => \&uninstall,
 829         'feed_config' => \&feed_config,
 830         'clean' => sub {
 831                 system("rm -rf ./feeds ./package/feeds");
 832         }
 833 );
 834
 835 my $arg = shift @ARGV;
 836 $arg or usage();
 837 parse_config;
 838 foreach my $cmd (keys %commands) {
 839         $arg eq $cmd and do {
 840                 exit(&{$commands{$cmd}}());
 841         };
 842 }
 843 usage();