scripts/feeds

   1 #!/usr/bin/env perl
   2 use Getopt::Std;
   3 use FindBin;
   4 use Cwd;
   5 use lib "$FindBin::Bin";
   6 use metadata;
   7 use warnings;
   8 use strict;
   9 use Cwd 'abs_path';
  10
  11 chdir "$FindBin::Bin/..";
  12 $ENV{TOPDIR} //= getcwd();
  13 chdir $ENV{TOPDIR};
  14 $ENV{GIT_CONFIG_PARAMETERS}="'core.autocrlf=false'";
  15 $ENV{GREP_OPTIONS}="";
  16
  17 my $mk=`which gmake 2>/dev/null`;       # select the right 'make' program
  18 chomp($mk);             # trim trailing newline
  19 $mk or $mk = "make";    # default to 'make'
  20
  21 # check version of make
  22 my @mkver = split /\s+/, `$mk -v`, 4;
  23 my $valid_mk = 1;
  24 $mkver[0] =~ /^GNU/ or $valid_mk = 0;
  25 $mkver[1] =~ /^Make/ or $valid_mk = 0;
  26
  27 my ($mkv1, $mkv2) = split /\./, $mkver[2];
  28 ($mkv1 >= 4 || ($mkv1 == 3 && $mkv2 >= 81)) or $valid_mk = 0;
  29
  30 $valid_mk or die "Unsupported version of make found: $mk\n";
  31
  32 my @feeds;
  33 my %build_packages;
  34 my %installed;
  35 my %installed_targets;
  36 my %feed_cache;
  37
  38 my $feed_package = {};
  39 my $feed_src = {};
  40 my $feed_target = {};
  41
  42 sub parse_config() {
  43         my $line = 0;
  44         my %name;
  45
  46         open FEEDS, "feeds.conf" or
  47                 open FEEDS, "feeds.conf.default" or
  48                 die "Unable to open feeds configuration";
  49         while (<FEEDS>) {
  50                 chomp;
  51                 s/#.+$//;
  52                 next unless /\S/;
  53                 my @line = split /\s+/, $_, 3;
  54                 my @src;
  55                 $line++;
  56
  57                 my $valid = 1;
  58                 $line[0] =~ /^src-[\w-]+$/ or $valid = 0;
  59                 $line[1] =~ /^\w+$/ or $valid = 0;
  60                 @src = split /\s+/, $line[2];
  61                 $valid or die "Syntax error in feeds.conf, line: $line\n";
  62
  63                 $name{$line[1]} and die "Duplicate feed name '$line[1]', line: $line\n";
  64                 $name{$line[1]} = 1;
  65
  66                 push @feeds, [$line[0], $line[1], \@src];
  67         }
  68         close FEEDS;
  69 }
  70
  71 sub update_location($$)
  72 {
  73         my $name = shift;
  74         my $url  = shift;
  75         my $old_url;
  76
  77         -d "./feeds/$name.tmp" or mkdir "./feeds/$name.tmp" or return 1;
  78
  79         if( open LOC, "< ./feeds/$name.tmp/location" )
  80         {
  81                 chomp($old_url = readline LOC);
  82                 close LOC;
  83         }
  84
  85         if( !$old_url || $old_url ne $url )
  86         {
  87                 if( open LOC, "> ./feeds/$name.tmp/location" )
  88                 {
  89                         print LOC $url, "\n";
  90                         close LOC;
  91                 }
  92                 return $old_url ? 1 : 0;
  93         }
  94
  95         return 0;
  96 }
  97
  98 sub update_index($)
  99 {
 100         my $name = shift;
 101
 102         -d "./feeds/$name.tmp" or mkdir "./feeds/$name.tmp" or return 1;
 103         -d "./feeds/$name.tmp/info" or mkdir "./feeds/$name.tmp/info" or return 1;
 104
 105         system("$mk -s prepare-mk OPENWRT_BUILD= TMP_DIR=\"$ENV{TOPDIR}/feeds/$name.tmp\"");
 106         system("$mk -s -f include/scan.mk IS_TTY=1 SCAN_TARGET=\"packageinfo\" SCAN_DIR=\"feeds/$name\" SCAN_NAME=\"package\" SCAN_DEPS=\"$ENV{TOPDIR}/include/package*.mk\" SCAN_DEPTH=5 SCAN_EXTRA=\"\" TMP_DIR=\"$ENV{TOPDIR}/feeds/$name.tmp\"");
 107         system("$mk -s -f include/scan.mk IS_TTY=1 SCAN_TARGET=\"targetinfo\" SCAN_DIR=\"feeds/$name\" SCAN_NAME=\"target\" SCAN_DEPS=\"profiles/*.mk $ENV{TOPDIR}/include/target.mk\" SCAN_DEPTH=5 SCAN_EXTRA=\"\" SCAN_MAKEOPTS=\"TARGET_BUILD=1\" TMP_DIR=\"$ENV{TOPDIR}/feeds/$name.tmp\"");
 108         system("ln -sf $name.tmp/.packageinfo ./feeds/$name.index");
 109         system("ln -sf $name.tmp/.targetinfo ./feeds/$name.targetindex");
 110
 111         return 0;
 112 }
 113
 114 my %update_method = (
 115         'src-svn' => {
 116                 'init'          => "svn checkout '%s' '%s'",
 117                 'update'        => "svn update",
 118                 'controldir'    => ".svn",
 119                 'revision'      => "svn info | grep 'Revision' | cut -d ' ' -f 2 | tr -d '\n'"},
 120         'src-cpy' => {
 121                 'init'          => "cp -Rf '%s' '%s'",
 122                 'update'        => "",
 123                 'revision'      => "echo -n 'local'"},
 124         'src-link' => {
 125                 'init'          => "ln -s '%s' '%s'",
 126                 'update'        => "",
 127                 'revision'      => "echo -n 'local'"},
 128         'src-git' => {
 129                 'init'          => "git clone --depth 1 '%s' '%s'",
 130                 'init_branch'   => "git clone --depth 1 --branch '%s' '%s' '%s'",
 131                 'init_commit'   => "git clone '%s' '%s' && cd '%s' && git checkout -b '%s' '%s' && cd -",
 132                 'update'        => "git pull --ff",
 133                 'controldir'    => ".git",
 134                 'revision'      => "git rev-parse --short HEAD | tr -d '\n'"},
 135         'src-git-full' => {
 136                 'init'          => "git clone '%s' '%s'",
 137                 'init_branch'   => "git clone --branch '%s' '%s' '%s'",
 138                 'init_commit'   => "git clone '%s' '%s' && cd '%s' && git checkout -b '%s' '%s' && cd -",
 139                 'update'        => "git pull --ff",
 140                 'controldir'    => ".git",
 141                 'revision'      => "git rev-parse --short HEAD | tr -d '\n'"},
 142         'src-gitsvn' => {
 143                 'init'  => "git svn clone -r HEAD '%s' '%s'",
 144                 'update'        => "git svn rebase",
 145                 'controldir'    => ".git",
 146                 'revision'      => "git rev-parse --short HEAD | tr -d '\n'"},
 147         'src-bzr' => {
 148                 'init'          => "bzr checkout --lightweight '%s' '%s'",
 149                 'update'        => "bzr update",
 150                 'controldir'    => ".bzr"},
 151         'src-hg' => {
 152                 'init'          => "hg clone '%s' '%s'",
 153                 'update'        => "hg pull --update",
 154                 'controldir'    => ".hg"},
 155         'src-darcs' => {
 156                 'init'    => "darcs get '%s' '%s'",
 157                 'update'  => "darcs pull -a",
 158                 'controldir' => "_darcs"},
 159 );
 160
 161 # src-git: pull broken
 162 # src-cpy: broken if `basename $src` != $name
 163
 164 sub update_feed_via($$$$) {
 165         my $type = shift;
 166         my $name = shift;
 167         my $src = shift;
 168         my $relocate = shift;
 169
 170         my $m = $update_method{$type};
 171         my $localpath = "./feeds/$name";
 172         my $safepath = $localpath;
 173         $safepath =~ s/'/'\\''/;
 174         my ($base_branch, $branch) = split(/;/, $src, 2);
 175         my ($base_commit, $commit) = split(/\^/, $src, 2);
 176
 177         if( $relocate || !$m->{'update'} || !-d "$localpath/$m->{'controldir'}" ) {
 178                 system("rm -rf '$safepath'");
 179                 if ($m->{'init_branch'} and $branch) {
 180                         system(sprintf($m->{'init_branch'}, $branch, $base_branch, $safepath)) == 0 or return 1;
 181                 } elsif ($m->{'init_commit'} and $commit) {
 182                         system(sprintf($m->{'init_commit'}, $base_commit, $safepath, $safepath, $commit, $commit)) == 0 or return 1;
 183                 } else {
 184                         system(sprintf($m->{'init'}, $src, $safepath)) == 0 or return 1;
 185                 }
 186         } elsif ($m->{'init_commit'} and $commit) {
 187                 # in case git hash has been provided don't update the feed
 188         } else {
 189                 system("cd '$safepath'; $m->{'update'}") == 0 or return 1;
 190         }
 191
 192         return 0;
 193 }
 194
 195 sub get_targets($) {
 196         my $file = shift;
 197         my @target = parse_target_metadata($file);
 198         my %target;
 199         foreach my $target (@target) {
 200                 $target{$target->{id}} = $target;
 201         }
 202         return %target
 203 }
 204
 205 sub get_feed($) {
 206         my $feed = shift;
 207
 208         if (!defined($feed_cache{$feed})) {
 209                 my $file = "./feeds/$feed.index";
 210
 211                 clear_packages();
 212                 -f $file or do {
 213                         print "Ignoring feed '$feed' - index missing\n";
 214                         return;
 215                 };
 216                 parse_package_metadata($file) or return;
 217                 my %target = get_targets("./feeds/$feed.targetindex");
 218
 219                 $feed_cache{$feed} = [ { %package }, { %srcpackage }, { %target } ];
 220         }
 221
 222         $feed_package = $feed_cache{$feed}->[0];
 223         $feed_src = $feed_cache{$feed}->[1];
 224         $feed_target = $feed_cache{$feed}->[2];
 225         return $feed_cache{$feed}->[0];
 226 }
 227
 228 sub get_installed() {
 229         system("$mk -s prepare-tmpinfo OPENWRT_BUILD=");
 230         clear_packages();
 231         parse_package_metadata("./tmp/.packageinfo");
 232         %installed = %package;
 233         %installed_targets = get_targets("./tmp/.targetinfo");
 234 }
 235
 236 sub search_feed {
 237         my $feed = shift;
 238         my @substr = @_;
 239         my $display;
 240
 241         return unless @substr > 0;
 242         get_feed($feed);
 243         foreach my $name (sort { lc($a) cmp lc($b) } keys %$feed_package) {
 244                 my $pkg = $feed_package->{$name};
 245                 my $substr;
 246                 my $pkgmatch = 1;
 247
 248                 next if $pkg->{vdepends};
 249                 foreach my $substr (@substr) {
 250                         my $match;
 251                         foreach my $key (qw(name title description src)) {
 252                                 $pkg->{$key} and $substr and $pkg->{$key} =~ m/$substr/i and $match = 1;
 253                         }
 254                         $match or undef $pkgmatch;
 255                 };
 256                 $pkgmatch and do {
 257                         $display or do {
 258                                 print "Search results in feed '$feed':\n";
 259                                 $display = 1;
 260                         };
 261                         printf "\%-25s\t\%s\n", $pkg->{name}, $pkg->{title};
 262                 };
 263         }
 264
 265         foreach my $name (sort { lc($a) cmp lc($b) } keys %$feed_target) {
 266                 my $target = $feed_target->{$name};
 267                 my $targetmatch = 1;
 268
 269                 foreach my $substr (@substr) {
 270                         my $match;
 271                         foreach my $key (qw(id name description)) {
 272                                 $target->{$key} and $substr and $target->{$key} =~ m/$substr/i and $match = 1;
 273                         }
 274                         $match or undef $targetmatch;
 275                 };
 276                 $targetmatch and do {
 277                         $display or do {
 278                                 print "Search results in feed '$feed':\n";
 279                                 $display = 1;
 280                         };
 281                         printf "TARGET: \%-17s\t\%s\n", $target->{id}, $target->{name};
 282                 };
 283         }
 284         return 0;
 285 }
 286
 287 sub search {
 288         my %opts;
 289
 290         getopt('r:', \%opts);
 291         foreach my $feed (@feeds) {
 292                 search_feed($feed->[1], @ARGV) if (!defined($opts{r}) or $opts{r} eq $feed->[1]);
 293         }
 294 }
 295
 296 sub list_feed {
 297         my $feed = shift;
 298
 299         get_feed($feed);
 300         foreach my $name (sort { lc($a) cmp lc($b) } keys %$feed_package) {
 301                 my $pkg = $feed_package->{$name};
 302                 next if $pkg->{vdepends};
 303                 if($pkg->{name}) {
 304                         printf "\%-32s\t\%s\n", $pkg->{name}, $pkg->{title};
 305                 }
 306         }
 307
 308         foreach my $name (sort { lc($a) cmp lc($b) } keys %$feed_target) {
 309                 my $target = $feed_target->{$name};
 310                 if($target->{name}) {
 311                         printf "TARGET: \%-24s\t\%s\n", $target->{id}, $target->{name};
 312                 }
 313         }
 314
 315         return 0;
 316 }
 317
 318 sub list {
 319         my %opts;
 320
 321         getopts('r:d:nshf', \%opts);
 322         if ($opts{h}) {
 323                 usage();
 324                 return 0;
 325         }
 326         if ($opts{n}) {
 327                 foreach my $feed (@feeds) {
 328                         printf "%s\n", $feed->[1];
 329                 }
 330                 return 0;
 331         }
 332         if ($opts{s}) {
 333                 foreach my $feed (@feeds) {
 334                         my $localpath = "./feeds/$feed->[1]";
 335                         my $m = $update_method{$feed->[0]};
 336                         my $revision;
 337                         if (!-d "$localpath" || !$m->{'revision'}) {
 338                                 $revision = "X";
 339                         }
 340                         elsif( $m->{'controldir'} && -d "$localpath/$m->{'controldir'}" ) {
 341                                 $revision = `cd '$localpath'; $m->{'revision'}`;
 342                         }
 343                         else {
 344                                 $revision = "local";
 345                         }
 346                         if ($opts{d}) {
 347                                 printf "%s%s%s%s%s%s%s\n", $feed->[1], $opts{d}, $feed->[0], $opts{d}, $revision, $opts{d}, join(", ", @{$feed->[2]});
 348                         }
 349                         elsif ($opts{f}) {
 350                                 my $uri = join(", ", @{$feed->[2]});
 351                                 if ($revision ne "local" && $revision ne "X") {
 352                                         $uri =~ s/[;^].*//;
 353                                         $uri .= "^" . $revision;
 354                                 }
 355                                 printf "%s %s %s\n", $feed->[0], $feed->[1], $uri;
 356                         }
 357                         else {
 358                                 printf "\%-10s \%-8s \%-8s \%s\n", $feed->[1], $feed->[0], $revision, join(", ", @{$feed->[2]});
 359                         }
 360                 }
 361                 return 0;
 362         }
 363         foreach my $feed (@feeds) {
 364                 list_feed($feed->[1], @ARGV) if (!defined($opts{r}) or $opts{r} eq $feed->[1]);
 365         }
 366         return 0;
 367 }
 368
 369 sub do_install_package($$) {
 370         my $feed = shift;
 371         my $pkg = shift;
 372         my $path = $pkg->{makefile};
 373
 374         if($path) {
 375                 $path =~ s/\/Makefile$//;
 376
 377                 -d "./package/feeds" or mkdir "./package/feeds";
 378                 -d "./package/feeds/$feed->[1]" or mkdir "./package/feeds/$feed->[1]";
 379                 system("ln -sf ../../../$path ./package/feeds/$feed->[1]/");
 380         } else {
 381                 warn "Package is not valid\n";
 382                 return 1;
 383         }
 384
 385         return 0;
 386 }
 387
 388 sub do_install_target($) {
 389         my $target = shift;
 390         my $path = $target->{makefile};
 391
 392         if ($path) {
 393                 $path =~ s/\/Makefile$//;
 394                 my $name = $path;
 395                 $name =~ s/.*\///;
 396                 my $dest = "./target/linux/$name";
 397
 398                 -e $dest and do {
 399                         warn "Path $dest already exists";
 400                         return 1;
 401                 };
 402
 403                 system("ln -sf ../../$path ./target/linux/");
 404         } else {
 405                 warn "Target is not valid\n";
 406                 return 1;
 407         }
 408
 409         return 0;
 410 }
 411
 412 sub lookup_package($$) {
 413         my $feed = shift;
 414         my $package = shift;
 415
 416         foreach my $feed ($feed, @feeds) {
 417                 next unless $feed->[1];
 418                 next unless $feed_cache{$feed->[1]};
 419                 $feed_cache{$feed->[1]}->[0]->{$package} and return $feed;
 420         }
 421         return;
 422 }
 423
 424 sub lookup_target($$) {
 425         my $feed = shift;
 426         my $target = shift;
 427
 428         foreach my $feed ($feed, @feeds) {
 429                 next unless $feed->[1];
 430                 next unless $feed_cache{$feed->[1]};
 431                 $feed_cache{$feed->[1]}->[2]->{$target} and return $feed;
 432         }
 433         return;
 434 }
 435
 436 sub is_core_package($) {
 437         my $package = shift;
 438         foreach my $file ("tmp/info/.packageinfo-$package", glob("tmp/info/.packageinfo-*_$package")) {
 439                 next unless index($file, "tmp/info/.packageinfo-feeds_");
 440                 return 1 if -s $file;
 441         }
 442         return 0;
 443 }
 444
 445 sub install_target {
 446         my $feed = shift;
 447         my $name = shift;
 448
 449         $feed = $feed_cache{$feed->[1]}->[2];
 450         $feed or return 0;
 451
 452         my $target = $feed->{$name};
 453         $target or return 0;
 454
 455         warn "Installing target '$name'\n";
 456         return do_install_target($target);
 457 }
 458
 459 sub install_package {
 460         my $feed = shift;
 461         my $name = shift;
 462         my $force = shift;
 463         my $ret = 0;
 464
 465         my $this_feed_target = lookup_target($feed, $name);
 466         $this_feed_target and do {
 467                 $installed_targets{$name} and return 0;
 468                 install_target($this_feed_target, $name);
 469                 return 0;
 470         };
 471
 472         $feed = lookup_package($feed, $name);
 473         $feed or do {
 474                 $installed{$name} and return 0;
 475                 # TODO: check if it's already installed within ./package directory
 476                 $feed_src->{$name} or is_core_package($name) or warn "WARNING: No feed for package '$name' found, maybe it's already part of the standard packages?\n";
 477                 return 0;
 478         };
 479
 480         # switch to the metadata for the selected feed
 481         my $cur = get_feed($feed->[1]);
 482
 483         my $pkg = $cur->{$name} or return 1;
 484         $pkg->{name} or do {
 485                 $installed{$name} and return 0;
 486                 # TODO: check if this is an alias package, maybe it's known by another name
 487                 warn "WARNING: Package '$name' is not available in feed $feed->[1].\n";
 488                 return 0;
 489         };
 490         my $src = $pkg->{src};
 491         my $type = $feed->[0];
 492         $src or $src = $name;
 493
 494         # If it's a core package and we don't want to override, just return
 495         !$force and is_core_package($src) and return 0;
 496
 497         # previously installed packages set the runtime package
 498         # newly installed packages set the source package to 1
 499         $installed{$src} and $installed{$src} == 1 and return 0;
 500
 501         # we'll trigger the override only with the 3 conditions below:
 502         # - override is allowed by command line (-f)
 503         # - a package with the same src exists in the core packages list
 504         # - the package previously installed is not from a feed
 505         my $override = 1 if ($force and is_core_package($src) and !$installed{$name}->{feed});
 506
 507         # check previously installed packages
 508         $installed{$name} and !$override and return 0;
 509         $installed{$src} = 1;
 510
 511         defined($override) and $override == 1
 512                 and warn "Overriding core package '$src' with version from $feed->[1]\n"
 513                 or warn "Installing package '$src' from $feed->[1]\n";
 514
 515         do_install_package($feed, $pkg) == 0 or do {
 516                 warn "failed.\n";
 517                 return 1;
 518         };
 519
 520         # install all dependencies referenced from the source package
 521         foreach my $vpkg (@{$feed_src->{$src}}) {
 522                 foreach my $dep (@{$vpkg->{depends}}, @{$vpkg->{builddepends}}, @{$vpkg->{"builddepends/host"}}) {
 523                         next if $dep =~ /@/;
 524                         $dep =~ s/^\+//;
 525                         $dep =~ s/^.+://;
 526                         $dep =~ s/\/.+$//;
 527                         next unless $dep;
 528                         install_package($feed, $dep, 0) == 0 or $ret = 1;
 529                 }
 530         }
 531
 532         return $ret;
 533 }
 534
 535 sub refresh_config {
 536         my $default = shift;
 537
 538         # Don't create .config if it doesn't already exist so that making a
 539         # config only occurs when the user intends it do (however we do
 540         # want to refresh an existing config).
 541         return if not (-e '.config');
 542
 543         # workaround for timestamp check
 544         system("rm -f tmp/.packageinfo");
 545
 546         # refresh the config
 547         if ($default) {
 548                 system("$mk oldconfig CONFDEFAULT=\"$default\" Config.in >/dev/null 2>/dev/null");
 549         } else {
 550                 system("$mk defconfig Config.in >/dev/null 2>/dev/null");
 551         }
 552 }
 553
 554 sub install {
 555         my $name;
 556         my %opts;
 557         my $feed;
 558         my $ret = 0;
 559
 560         getopts('ap:d:fh', \%opts);
 561
 562         if ($opts{h}) {
 563                 usage();
 564                 return 0;
 565         }
 566
 567         get_installed();
 568
 569         foreach my $f (@feeds) {
 570                 # fetch all feeds
 571                 get_feed($f->[1]);
 572
 573                 # look up the preferred feed
 574                 $opts{p} and $f->[1] eq $opts{p} and $feed = $f;
 575         }
 576
 577         if($opts{a}) {
 578                 foreach my $f (@feeds) {
 579                         if (!defined($opts{p}) or $opts{p} eq $f->[1]) {
 580                                 printf "Installing all packages from feed %s.\n", $f->[1];
 581                                 get_feed($f->[1]);
 582                                 foreach my $name (sort { lc($a) cmp lc($b) } keys %$feed_package) {
 583                                         my $p = $feed_package->{$name};
 584                                         next if $p->{vdepends};
 585                                         if( $p->{name} ) {
 586                                                 install_package($feed, $p->{name}, exists($opts{f})) == 0 or $ret = 1;
 587                                                 get_feed($f->[1]);
 588                                         }
 589                                 }
 590                         }
 591                 }
 592         } else {
 593                 while ($name = shift @ARGV) {
 594                         install_package($feed, $name, exists($opts{f})) == 0 or $ret = 1;
 595                 }
 596         }
 597
 598         # workaround for timestamp check
 599
 600         # set the defaults
 601         if ($opts{d} and $opts{d} =~ /^[ymn]$/) {
 602                 refresh_config($opts{d});
 603         }
 604
 605         return $ret;
 606 }
 607
 608 sub uninstall_target($) {
 609         my $dir = shift;
 610         my $name = $dir;
 611         $name =~ s/.*\///g;
 612
 613         my $dest = readlink $dir;
 614         return unless $dest =~ /..\/..\/feeds/;
 615         warn "Uninstalling target '$name'\n";
 616         unlink "$dir";
 617 }
 618
 619 sub uninstall {
 620         my %opts;
 621         my $name;
 622         my $uninstall;
 623
 624         getopts('ah', \%opts);
 625
 626         if ($opts{h}) {
 627                 usage();
 628                 return 0;
 629         }
 630
 631         if ($opts{a}) {
 632                 system("rm -rvf ./package/feeds");
 633                 foreach my $dir (glob "target/linux/*") {
 634                         next unless -l $dir;
 635                         uninstall_target($dir);
 636                 }
 637                 $uninstall = 1;
 638         } else {
 639                 if($#ARGV == -1) {
 640                         warn "WARNING: no package to uninstall\n";
 641                         return 0;
 642                 }
 643                 get_installed();
 644                 while ($name = shift @ARGV) {
 645                         my $target = "target/linux/$name";
 646                         -l "$target" and do {
 647                                 uninstall_target($target);
 648                                 $uninstall = 1;
 649                                 next;
 650                         };
 651
 652                         my $pkg = $installed{$name};
 653                         $pkg or do {
 654                                 warn "WARNING: $name not installed\n";
 655                                 next;
 656                         };
 657                         $pkg->{src} and $name = $pkg->{src};
 658                         warn "Uninstalling package '$name'\n";
 659                         system("rm -f ./package/feeds/*/$name");
 660                         $uninstall = 1;
 661                 }
 662         }
 663         $uninstall and refresh_config();
 664         return 0;
 665 }
 666
 667 sub update_feed($$$$)
 668 {
 669         my $type=shift;
 670         my $name=shift;
 671         my $src=shift;
 672         my $perform_update=shift;
 673         my $force_relocate=update_location( $name, "@$src" );
 674
 675         if( $force_relocate ) {
 676                 warn "Source of feed $name has changed, replacing copy\n";
 677         }
 678         $update_method{$type} or do {
 679                 warn "Unknown type '$type' in feed $name\n";
 680                 return 1;
 681         };
 682         $perform_update and do {
 683                 my $failed = 1;
 684                 foreach my $feedsrc (@$src) {
 685                         warn "Updating feed '$name' from '$feedsrc' ...\n";
 686                         next unless update_feed_via($type, $name, $feedsrc, $force_relocate) == 0;
 687                         $failed = 0;
 688                         last;
 689                 }
 690                 $failed and do {
 691                         warn "failed.\n";
 692                         return 1;
 693                 };
 694         };
 695         warn "Create index file './feeds/$name.index' \n";
 696         update_index($name) == 0 or do {
 697                 warn "failed.\n";
 698                 return 1;
 699         };
 700         return 0;
 701 }
 702
 703 sub update {
 704         my %opts;
 705         my $feed_name;
 706         my $perform_update=1;
 707         my $failed=0;
 708
 709         $ENV{SCAN_COOKIE} = $$;
 710         $ENV{OPENWRT_VERBOSE} = 's';
 711
 712         getopts('ahi', \%opts);
 713
 714         if ($opts{h}) {
 715                 usage();
 716                 return 0;
 717         }
 718
 719         if ($opts{i}) {
 720                 # don't update from (remote) repository
 721                 # only re-create index information
 722                 $perform_update=0;
 723         }
 724
 725         -d "feeds" or do {
 726                         mkdir "feeds" or die "Unable to create the feeds directory";
 727                 };
 728
 729         if ( ($#ARGV == -1) or $opts{a}) {
 730                 foreach my $feed (@feeds) {
 731                         my ($type, $name, $src) = @$feed;
 732                         update_feed($type, $name, $src, $perform_update) == 0 or $failed=1;
 733                 }
 734         } else {
 735                 while ($feed_name = shift @ARGV) {
 736                         foreach my $feed (@feeds) {
 737                                 my ($type, $name, $src) = @$feed;
 738                                 if($feed_name ne $name) {
 739                                         next;
 740                                 }
 741                                 update_feed($type, $name, $src, $perform_update) == 0 or $failed=1;
 742                         }
 743                 }
 744         }
 745
 746         refresh_config();
 747
 748         return $failed;
 749 }
 750
 751 sub feed_config() {
 752         foreach my $feed (@feeds) {
 753                 my $installed = (-f "feeds/$feed->[1].index");
 754
 755                 printf "\tconfig FEED_%s\n", $feed->[1];
 756                 printf "\t\tbool \"Enable feed %s\"\n", $feed->[1];
 757                 printf "\t\tdepends on PER_FEED_REPO\n";
 758                 printf "\t\tdefault y\n" if $installed;
 759                 printf "\t\thelp\n";
 760                 printf "\t\t Enable the \\\"%s\\\" feed at %s.\n", $feed->[1], $feed->[2][0];
 761                 printf "\n";
 762         }
 763
 764         return 0;
 765 }
 766
 767 sub usage() {
 768         print <<EOF;
 769 Usage: $0 <command> [options]
 770
 771 Commands:
 772         list [options]: List feeds, their content and revisions (if installed)
 773         Options:
 774             -n :            List of feed names.
 775             -s :            List of feed names and their URL.
 776             -r <feedname>:  List packages of specified feed.
 777             -d <delimiter>: Use specified delimiter to distinguish rows (default: spaces)
 778             -f :            List feeds in feeds.conf compatible format (when using -s).
 779
 780         install [options] <package>: Install a package
 781         Options:
 782             -a :           Install all packages from all feeds or from the specified feed using the -p option.
 783             -p <feedname>: Prefer this feed when installing packages.
 784             -d <y|m|n>:    Set default for newly installed packages.
 785             -f :           Install will be forced even if the package exists in core OpenWrt (override)
 786
 787         search [options] <substring>: Search for a package
 788         Options:
 789             -r <feedname>: Only search in this feed
 790
 791         uninstall -a|<package>: Uninstall a package
 792         Options:
 793             -a :           Uninstalls all packages.
 794
 795         update -a|<feedname(s)>: Update packages and lists of feeds in feeds.conf .
 796         Options:
 797             -a :           Update all feeds listed within feeds.conf. Otherwise the specified feeds will be updated.
 798             -i :           Recreate the index only. No feed update from repository is performed.
 799
 800         clean:             Remove downloaded/generated files.
 801
 802 EOF
 803         exit(1);
 804 }
 805
 806 my %commands = (
 807         'list' => \&list,
 808         'update' => \&update,
 809         'install' => \&install,
 810         'search' => \&search,
 811         'uninstall' => \&uninstall,
 812         'feed_config' => \&feed_config,
 813         'clean' => sub {
 814                 system("rm -rf ./feeds ./package/feeds");
 815         }
 816 );
 817
 818 my $arg = shift @ARGV;
 819 $arg or usage();
 820 parse_config;
 821 foreach my $cmd (keys %commands) {
 822         $arg eq $cmd and do {
 823                 exit(&{$commands{$cmd}}());
 824         };
 825 }
 826 usage();