scripts/feeds

   1 #!/usr/bin/env perl
   2 use Getopt::Std;
   3 use FindBin;
   4 use Cwd;
   5 use lib "$FindBin::Bin";
   6 use metadata;
   7 use warnings;
   8 use strict;
   9 use Cwd 'abs_path';
  10
  11 chdir "$FindBin::Bin/..";
  12 $ENV{TOPDIR} //= getcwd();
  13 chdir $ENV{TOPDIR};
  14 $ENV{GIT_CONFIG_PARAMETERS}="'core.autocrlf=false'";
  15 $ENV{GREP_OPTIONS}="";
  16
  17 my $mk=`which gmake 2>/dev/null`;       # select the right 'make' program
  18 chomp($mk);             # trim trailing newline
  19 $mk or $mk = "make";    # default to 'make'
  20
  21 # check version of make
  22 my @mkver = split /\s+/, `$mk -v`, 4;
  23 my $valid_mk = 1;
  24 $mkver[0] =~ /^GNU/ or $valid_mk = 0;
  25 $mkver[1] =~ /^Make/ or $valid_mk = 0;
  26
  27 my ($mkv1, $mkv2) = split /\./, $mkver[2];
  28 ($mkv1 >= 4 || ($mkv1 == 3 && $mkv2 >= 81)) or $valid_mk = 0;
  29
  30 $valid_mk or die "Unsupported version of make found: $mk\n";
  31
  32 my @feeds;
  33 my %build_packages;
  34 my %installed;
  35 my %installed_targets;
  36 my %feed_cache;
  37
  38 my $feed_package = {};
  39 my $feed_src = {};
  40 my $feed_target = {};
  41
  42 sub parse_config() {
  43         my $line = 0;
  44         my %name;
  45
  46         open FEEDS, "feeds.conf" or
  47                 open FEEDS, "feeds.conf.default" or
  48                 die "Unable to open feeds configuration";
  49         while (<FEEDS>) {
  50                 chomp;
  51                 s/#.+$//;
  52                 next unless /\S/;
  53                 my @line = split /\s+/, $_, 3;
  54                 my @src;
  55                 $line++;
  56
  57                 my $valid = 1;
  58                 $line[0] =~ /^src-[\w-]+$/ or $valid = 0;
  59                 $line[1] =~ /^\w+$/ or $valid = 0;
  60                 @src = split /\s+/, $line[2];
  61                 $valid or die "Syntax error in feeds.conf, line: $line\n";
  62
  63                 $name{$line[1]} and die "Duplicate feed name '$line[1]', line: $line\n";
  64                 $name{$line[1]} = 1;
  65
  66                 push @feeds, [$line[0], $line[1], \@src];
  67         }
  68         close FEEDS;
  69 }
  70
  71 sub update_location($$)
  72 {
  73         my $name = shift;
  74         my $url  = shift;
  75         my $old_url;
  76
  77         -d "./feeds/$name.tmp" or mkdir "./feeds/$name.tmp" or return 1;
  78
  79         if( open LOC, "< ./feeds/$name.tmp/location" )
  80         {
  81                 chomp($old_url = readline LOC);
  82                 close LOC;
  83         }
  84
  85         if( !$old_url || $old_url ne $url )
  86         {
  87                 if( open LOC, "> ./feeds/$name.tmp/location" )
  88                 {
  89                         print LOC $url, "\n";
  90                         close LOC;
  91                 }
  92                 return $old_url ? 1 : 0;
  93         }
  94
  95         return 0;
  96 }
  97
  98 sub update_index($)
  99 {
 100         my $name = shift;
 101
 102         -d "./feeds/$name.tmp" or mkdir "./feeds/$name.tmp" or return 1;
 103         -d "./feeds/$name.tmp/info" or mkdir "./feeds/$name.tmp/info" or return 1;
 104
 105         system("$mk -s prepare-mk OPENWRT_BUILD= TMP_DIR=\"$ENV{TOPDIR}/feeds/$name.tmp\"");
 106         system("$mk -s -f include/scan.mk IS_TTY=1 SCAN_TARGET=\"packageinfo\" SCAN_DIR=\"feeds/$name\" SCAN_NAME=\"package\" SCAN_DEPS=\"$ENV{TOPDIR}/include/package*.mk\" SCAN_DEPTH=5 SCAN_EXTRA=\"\" TMP_DIR=\"$ENV{TOPDIR}/feeds/$name.tmp\"");
 107         system("$mk -s -f include/scan.mk IS_TTY=1 SCAN_TARGET=\"targetinfo\" SCAN_DIR=\"feeds/$name\" SCAN_NAME=\"target\" SCAN_DEPS=\"profiles/*.mk $ENV{TOPDIR}/include/target.mk\" SCAN_DEPTH=5 SCAN_EXTRA=\"\" SCAN_MAKEOPTS=\"TARGET_BUILD=1\" TMP_DIR=\"$ENV{TOPDIR}/feeds/$name.tmp\"");
 108         system("ln -sf $name.tmp/.packageinfo ./feeds/$name.index");
 109         system("ln -sf $name.tmp/.targetinfo ./feeds/$name.targetindex");
 110
 111         return 0;
 112 }
 113
 114 my %update_method = (
 115         'src-svn' => {
 116                 'init'          => "svn checkout '%s' '%s'",
 117                 'update'        => "svn update",
 118                 'controldir'    => ".svn",
 119                 'revision'      => "svn info | grep 'Revision' | cut -d ' ' -f 2 | tr -d '\n'"},
 120         'src-cpy' => {
 121                 'init'          => "cp -Rf '%s' '%s'",
 122                 'update'        => "",
 123                 'revision'      => "echo -n 'local'"},
 124         'src-link' => {
 125                 'init'          => "ln -s '%s' '%s'",
 126                 'update'        => "",
 127                 'revision'      => "echo -n 'local'"},
 128         'src-git' => {
 129                 'init'          => "git clone --depth 1 '%s' '%s'",
 130                 'init_branch'   => "git clone --depth 1 --branch '%s' '%s' '%s'",
 131                 'init_commit'   => "git clone '%s' '%s' && cd '%s' && git checkout -b '%s' '%s' && cd -",
 132                 'update'        => "git pull --ff",
 133                 'update_force'  => "git pull --ff || (git reset --hard HEAD; git pull --ff; exit 1)",
 134                 'controldir'    => ".git",
 135                 'revision'      => "git rev-parse --short HEAD | tr -d '\n'"},
 136         'src-git-full' => {
 137                 'init'          => "git clone '%s' '%s'",
 138                 'init_branch'   => "git clone --branch '%s' '%s' '%s'",
 139                 'init_commit'   => "git clone '%s' '%s' && cd '%s' && git checkout -b '%s' '%s' && cd -",
 140                 'update'        => "git pull --ff",
 141                 'update_force'  => "git pull --ff || (git reset --hard HEAD; git pull --ff; exit 1)",
 142                 'controldir'    => ".git",
 143                 'revision'      => "git rev-parse --short HEAD | tr -d '\n'"},
 144         'src-gitsvn' => {
 145                 'init'  => "git svn clone -r HEAD '%s' '%s'",
 146                 'update'        => "git svn rebase",
 147                 'controldir'    => ".git",
 148                 'revision'      => "git rev-parse --short HEAD | tr -d '\n'"},
 149         'src-bzr' => {
 150                 'init'          => "bzr checkout --lightweight '%s' '%s'",
 151                 'update'        => "bzr update",
 152                 'controldir'    => ".bzr"},
 153         'src-hg' => {
 154                 'init'          => "hg clone '%s' '%s'",
 155                 'update'        => "hg pull --update",
 156                 'controldir'    => ".hg"},
 157         'src-darcs' => {
 158                 'init'    => "darcs get '%s' '%s'",
 159                 'update'  => "darcs pull -a",
 160                 'controldir' => "_darcs"},
 161 );
 162
 163 # src-git: pull broken
 164 # src-cpy: broken if `basename $src` != $name
 165
 166 sub update_feed_via($$$$$) {
 167         my $type = shift;
 168         my $name = shift;
 169         my $src = shift;
 170         my $relocate = shift;
 171         my $force = shift;
 172
 173         my $m = $update_method{$type};
 174         my $localpath = "./feeds/$name";
 175         my $safepath = $localpath;
 176         $safepath =~ s/'/'\\''/;
 177         my ($base_branch, $branch) = split(/;/, $src, 2);
 178         my ($base_commit, $commit) = split(/\^/, $src, 2);
 179
 180         if( $relocate || !$m->{'update'} || !-d "$localpath/$m->{'controldir'}" ) {
 181                 system("rm -rf '$safepath'");
 182                 if ($m->{'init_branch'} and $branch) {
 183                         system(sprintf($m->{'init_branch'}, $branch, $base_branch, $safepath)) == 0 or return 1;
 184                 } elsif ($m->{'init_commit'} and $commit) {
 185                         system(sprintf($m->{'init_commit'}, $base_commit, $safepath, $safepath, $commit, $commit)) == 0 or return 1;
 186                 } else {
 187                         system(sprintf($m->{'init'}, $src, $safepath)) == 0 or return 1;
 188                 }
 189         } elsif ($m->{'init_commit'} and $commit) {
 190                 # in case git hash has been provided don't update the feed
 191         } else {
 192                 my $update_cmd = $m->{'update'};
 193                 if ($force && exists $m->{'update_force'}) {
 194                         $update_cmd = $m->{'update_force'};
 195                 }
 196                 system("cd '$safepath'; $update_cmd") == 0 or return 1;
 197         }
 198
 199         return 0;
 200 }
 201
 202 sub get_targets($) {
 203         my $file = shift;
 204         my @target = parse_target_metadata($file);
 205         my %target;
 206         foreach my $target (@target) {
 207                 $target{$target->{id}} = $target;
 208         }
 209         return %target
 210 }
 211
 212 sub get_feed($) {
 213         my $feed = shift;
 214
 215         if (!defined($feed_cache{$feed})) {
 216                 my $file = "./feeds/$feed.index";
 217
 218                 clear_packages();
 219                 -f $file or do {
 220                         print "Ignoring feed '$feed' - index missing\n";
 221                         return;
 222                 };
 223                 parse_package_metadata($file) or return;
 224                 my %target = get_targets("./feeds/$feed.targetindex");
 225
 226                 $feed_cache{$feed} = [ { %package }, { %srcpackage }, { %target } ];
 227         }
 228
 229         $feed_package = $feed_cache{$feed}->[0];
 230         $feed_src = $feed_cache{$feed}->[1];
 231         $feed_target = $feed_cache{$feed}->[2];
 232         return $feed_cache{$feed}->[0];
 233 }
 234
 235 sub get_installed() {
 236         system("$mk -s prepare-tmpinfo OPENWRT_BUILD=");
 237         clear_packages();
 238         parse_package_metadata("./tmp/.packageinfo");
 239         %installed = %package;
 240         %installed_targets = get_targets("./tmp/.targetinfo");
 241 }
 242
 243 sub search_feed {
 244         my $feed = shift;
 245         my @substr = @_;
 246         my $display;
 247
 248         return unless @substr > 0;
 249         get_feed($feed);
 250         foreach my $name (sort { lc($a) cmp lc($b) } keys %$feed_package) {
 251                 my $pkg = $feed_package->{$name};
 252                 my $substr;
 253                 my $pkgmatch = 1;
 254
 255                 next if $pkg->{vdepends};
 256                 foreach my $substr (@substr) {
 257                         my $match;
 258                         foreach my $key (qw(name title description src)) {
 259                                 $pkg->{$key} and $substr and $pkg->{$key} =~ m/$substr/i and $match = 1;
 260                         }
 261                         $match or undef $pkgmatch;
 262                 };
 263                 $pkgmatch and do {
 264                         $display or do {
 265                                 print "Search results in feed '$feed':\n";
 266                                 $display = 1;
 267                         };
 268                         printf "\%-25s\t\%s\n", $pkg->{name}, $pkg->{title};
 269                 };
 270         }
 271
 272         foreach my $name (sort { lc($a) cmp lc($b) } keys %$feed_target) {
 273                 my $target = $feed_target->{$name};
 274                 my $targetmatch = 1;
 275
 276                 foreach my $substr (@substr) {
 277                         my $match;
 278                         foreach my $key (qw(id name description)) {
 279                                 $target->{$key} and $substr and $target->{$key} =~ m/$substr/i and $match = 1;
 280                         }
 281                         $match or undef $targetmatch;
 282                 };
 283                 $targetmatch and do {
 284                         $display or do {
 285                                 print "Search results in feed '$feed':\n";
 286                                 $display = 1;
 287                         };
 288                         printf "TARGET: \%-17s\t\%s\n", $target->{id}, $target->{name};
 289                 };
 290         }
 291         return 0;
 292 }
 293
 294 sub search {
 295         my %opts;
 296
 297         getopt('r:', \%opts);
 298         foreach my $feed (@feeds) {
 299                 search_feed($feed->[1], @ARGV) if (!defined($opts{r}) or $opts{r} eq $feed->[1]);
 300         }
 301 }
 302
 303 sub list_feed {
 304         my $feed = shift;
 305
 306         get_feed($feed);
 307         foreach my $name (sort { lc($a) cmp lc($b) } keys %$feed_package) {
 308                 my $pkg = $feed_package->{$name};
 309                 next if $pkg->{vdepends};
 310                 if($pkg->{name}) {
 311                         printf "\%-32s\t\%s\n", $pkg->{name}, $pkg->{title};
 312                 }
 313         }
 314
 315         foreach my $name (sort { lc($a) cmp lc($b) } keys %$feed_target) {
 316                 my $target = $feed_target->{$name};
 317                 if($target->{name}) {
 318                         printf "TARGET: \%-24s\t\%s\n", $target->{id}, $target->{name};
 319                 }
 320         }
 321
 322         return 0;
 323 }
 324
 325 sub list {
 326         my %opts;
 327
 328         getopts('r:d:nshf', \%opts);
 329         if ($opts{h}) {
 330                 usage();
 331                 return 0;
 332         }
 333         if ($opts{n}) {
 334                 foreach my $feed (@feeds) {
 335                         printf "%s\n", $feed->[1];
 336                 }
 337                 return 0;
 338         }
 339         if ($opts{s}) {
 340                 foreach my $feed (@feeds) {
 341                         my $localpath = "./feeds/$feed->[1]";
 342                         my $m = $update_method{$feed->[0]};
 343                         my $revision;
 344                         if (!-d "$localpath" || !$m->{'revision'}) {
 345                                 $revision = "X";
 346                         }
 347                         elsif( $m->{'controldir'} && -d "$localpath/$m->{'controldir'}" ) {
 348                                 $revision = `cd '$localpath'; $m->{'revision'}`;
 349                         }
 350                         else {
 351                                 $revision = "local";
 352                         }
 353                         if ($opts{d}) {
 354                                 printf "%s%s%s%s%s%s%s\n", $feed->[1], $opts{d}, $feed->[0], $opts{d}, $revision, $opts{d}, join(", ", @{$feed->[2]});
 355                         }
 356                         elsif ($opts{f}) {
 357                                 my $uri = join(", ", @{$feed->[2]});
 358                                 if ($revision ne "local" && $revision ne "X") {
 359                                         $uri =~ s/[;^].*//;
 360                                         $uri .= "^" . $revision;
 361                                 }
 362                                 printf "%s %s %s\n", $feed->[0], $feed->[1], $uri;
 363                         }
 364                         else {
 365                                 printf "\%-10s \%-8s \%-8s \%s\n", $feed->[1], $feed->[0], $revision, join(", ", @{$feed->[2]});
 366                         }
 367                 }
 368                 return 0;
 369         }
 370         foreach my $feed (@feeds) {
 371                 list_feed($feed->[1], @ARGV) if (!defined($opts{r}) or $opts{r} eq $feed->[1]);
 372         }
 373         return 0;
 374 }
 375
 376 # TODO: do_install_package etc. should deal with source packages rather
 377 # than binary packages
 378 sub do_install_package($$) {
 379         my $feed = shift;
 380         my $pkg = shift;
 381
 382         my $path;
 383         $pkg->{src} and $path = $pkg->{src}{makefile};
 384
 385         if($path) {
 386                 $path =~ s/\/Makefile$//;
 387
 388                 -d "./package/feeds" or mkdir "./package/feeds";
 389                 -d "./package/feeds/$feed->[1]" or mkdir "./package/feeds/$feed->[1]";
 390                 system("ln -sf ../../../$path ./package/feeds/$feed->[1]/");
 391         } else {
 392                 warn "Package is not valid\n";
 393                 return 1;
 394         }
 395
 396         return 0;
 397 }
 398
 399 sub do_install_target($) {
 400         my $target = shift;
 401         my $path = $target->{makefile};
 402
 403         if ($path) {
 404                 $path =~ s/\/Makefile$//;
 405                 my $name = $path;
 406                 $name =~ s/.*\///;
 407                 my $dest = "./target/linux/$name";
 408
 409                 -e $dest and do {
 410                         warn "Path $dest already exists";
 411                         return 1;
 412                 };
 413
 414                 system("ln -sf ../../$path ./target/linux/");
 415         } else {
 416                 warn "Target is not valid\n";
 417                 return 1;
 418         }
 419
 420         return 0;
 421 }
 422
 423 sub lookup_package($$) {
 424         my $feed = shift;
 425         my $package = shift;
 426
 427         foreach my $feed ($feed, @feeds) {
 428                 next unless $feed->[1];
 429                 next unless $feed_cache{$feed->[1]};
 430                 $feed_cache{$feed->[1]}->[0]->{$package} and return $feed;
 431         }
 432         return;
 433 }
 434
 435 sub lookup_target($$) {
 436         my $feed = shift;
 437         my $target = shift;
 438
 439         foreach my $feed ($feed, @feeds) {
 440                 next unless $feed->[1];
 441                 next unless $feed_cache{$feed->[1]};
 442                 $feed_cache{$feed->[1]}->[2]->{$target} and return $feed;
 443         }
 444         return;
 445 }
 446
 447 sub is_core_package($) {
 448         my $package = shift;
 449         foreach my $file ("tmp/info/.packageinfo-$package", glob("tmp/info/.packageinfo-*_$package")) {
 450                 next unless index($file, "tmp/info/.packageinfo-feeds_");
 451                 return 1 if -s $file;
 452         }
 453         return 0;
 454 }
 455
 456 sub install_target {
 457         my $feed = shift;
 458         my $name = shift;
 459
 460         $feed = $feed_cache{$feed->[1]}->[2];
 461         $feed or return 0;
 462
 463         my $target = $feed->{$name};
 464         $target or return 0;
 465
 466         warn "Installing target '$name'\n";
 467         return do_install_target($target);
 468 }
 469
 470 sub install_package {
 471         my $feed = shift;
 472         my $name = shift;
 473         my $force = shift;
 474         my $ret = 0;
 475
 476         my $this_feed_target = lookup_target($feed, $name);
 477         $this_feed_target and do {
 478                 $installed_targets{$name} and return 0;
 479                 install_target($this_feed_target, $name);
 480                 return 0;
 481         };
 482
 483         $feed = lookup_package($feed, $name);
 484         $feed or do {
 485                 $installed{$name} and return 0;
 486                 # TODO: check if it's already installed within ./package directory
 487                 $feed_src->{$name} or is_core_package($name) or warn "WARNING: No feed for package '$name' found, maybe it's already part of the standard packages?\n";
 488                 return 0;
 489         };
 490
 491         # switch to the metadata for the selected feed
 492         my $cur = get_feed($feed->[1]);
 493
 494         my $pkg = $cur->{$name} or return 1;
 495         $pkg->{name} or do {
 496                 $installed{$name} and return 0;
 497                 # TODO: check if this is an alias package, maybe it's known by another name
 498                 warn "WARNING: Package '$name' is not available in feed $feed->[1].\n";
 499                 return 0;
 500         };
 501         my $src = $pkg->{src}{name};
 502         my $type = $feed->[0];
 503         $src or $src = $name;
 504
 505         # If it's a core package and we don't want to override, just return
 506         !$force and is_core_package($src) and return 0;
 507
 508         # previously installed packages set the runtime package
 509         # newly installed packages set the source package to 1
 510         $installed{$src} and $installed{$src} == 1 and return 0;
 511
 512         # we'll trigger the override only with the 3 conditions below:
 513         # - override is allowed by command line (-f)
 514         # - a package with the same src exists in the core packages list
 515         # - the package previously installed is not from a feed
 516         my $override = 1 if ($force and is_core_package($src) and !$installed{$name}->{feed});
 517
 518         # check previously installed packages
 519         $installed{$name} and !$override and return 0;
 520         $installed{$src} = 1;
 521
 522         defined($override) and $override == 1
 523                 and warn "Overriding core package '$src' with version from $feed->[1]\n"
 524                 or warn "Installing package '$src' from $feed->[1]\n";
 525
 526         do_install_package($feed, $pkg) == 0 or do {
 527                 warn "failed.\n";
 528                 return 1;
 529         };
 530
 531         # install all dependencies referenced from the source package
 532         foreach my $dep (
 533                 @{$feed_src->{$src}{builddepends}},
 534                 @{$feed_src->{$src}{"builddepends/host"}},
 535                 map { @{$_->{depends}} } @{$feed_src->{$src}{packages}}
 536         ) {
 537                 next if $dep =~ /@/;
 538                 $dep =~ s/^\+//;
 539                 $dep =~ s/^.+://;
 540                 $dep =~ s/\/.+$//;
 541                 next unless $dep;
 542                 install_package($feed, $dep, 0) == 0 or $ret = 1;
 543         }
 544
 545         return $ret;
 546 }
 547
 548 sub refresh_config {
 549         my $default = shift;
 550
 551         # Don't create .config if it doesn't already exist so that making a
 552         # config only occurs when the user intends it do (however we do
 553         # want to refresh an existing config).
 554         return if not (-e '.config');
 555
 556         # workaround for timestamp check
 557         system("rm -f tmp/.packageinfo");
 558
 559         # refresh the config
 560         if ($default) {
 561                 system("$mk oldconfig CONFDEFAULT=\"$default\" Config.in >/dev/null 2>/dev/null");
 562         } else {
 563                 system("$mk defconfig Config.in >/dev/null 2>/dev/null");
 564         }
 565 }
 566
 567 sub install {
 568         my $name;
 569         my %opts;
 570         my $feed;
 571         my $ret = 0;
 572
 573         getopts('ap:d:fh', \%opts);
 574
 575         if ($opts{h}) {
 576                 usage();
 577                 return 0;
 578         }
 579
 580         get_installed();
 581
 582         foreach my $f (@feeds) {
 583                 # fetch all feeds
 584                 get_feed($f->[1]);
 585
 586                 # look up the preferred feed
 587                 $opts{p} and $f->[1] eq $opts{p} and $feed = $f;
 588         }
 589
 590         if($opts{a}) {
 591                 foreach my $f (@feeds) {
 592                         if (!defined($opts{p}) or $opts{p} eq $f->[1]) {
 593                                 printf "Installing all packages from feed %s.\n", $f->[1];
 594                                 get_feed($f->[1]);
 595                                 foreach my $name (sort { lc($a) cmp lc($b) } keys %$feed_package) {
 596                                         my $p = $feed_package->{$name};
 597                                         next if $p->{vdepends};
 598                                         if( $p->{name} ) {
 599                                                 install_package($feed, $p->{name}, exists($opts{f})) == 0 or $ret = 1;
 600                                                 get_feed($f->[1]);
 601                                         }
 602                                 }
 603                         }
 604                 }
 605         } else {
 606                 while ($name = shift @ARGV) {
 607                         install_package($feed, $name, exists($opts{f})) == 0 or $ret = 1;
 608                 }
 609         }
 610
 611         # workaround for timestamp check
 612
 613         # set the defaults
 614         if ($opts{d} and $opts{d} =~ /^[ymn]$/) {
 615                 refresh_config($opts{d});
 616         }
 617
 618         return $ret;
 619 }
 620
 621 sub uninstall_target($) {
 622         my $dir = shift;
 623         my $name = $dir;
 624         $name =~ s/.*\///g;
 625
 626         my $dest = readlink $dir;
 627         return unless $dest =~ /..\/..\/feeds/;
 628         warn "Uninstalling target '$name'\n";
 629         unlink "$dir";
 630 }
 631
 632 sub uninstall {
 633         my %opts;
 634         my $name;
 635         my $uninstall;
 636
 637         getopts('ah', \%opts);
 638
 639         if ($opts{h}) {
 640                 usage();
 641                 return 0;
 642         }
 643
 644         if ($opts{a}) {
 645                 system("rm -rvf ./package/feeds");
 646                 foreach my $dir (glob "target/linux/*") {
 647                         next unless -l $dir;
 648                         uninstall_target($dir);
 649                 }
 650                 $uninstall = 1;
 651         } else {
 652                 if($#ARGV == -1) {
 653                         warn "WARNING: no package to uninstall\n";
 654                         return 0;
 655                 }
 656                 get_installed();
 657                 while ($name = shift @ARGV) {
 658                         my $target = "target/linux/$name";
 659                         -l "$target" and do {
 660                                 uninstall_target($target);
 661                                 $uninstall = 1;
 662                                 next;
 663                         };
 664
 665                         my $pkg = $installed{$name};
 666                         $pkg or do {
 667                                 warn "WARNING: $name not installed\n";
 668                                 next;
 669                         };
 670                         $pkg->{src} and $name = $pkg->{src}{name};
 671                         warn "Uninstalling package '$name'\n";
 672                         system("rm -f ./package/feeds/*/$name");
 673                         $uninstall = 1;
 674                 }
 675         }
 676         $uninstall and refresh_config();
 677         return 0;
 678 }
 679
 680 sub update_feed($$$$$)
 681 {
 682         my $type=shift;
 683         my $name=shift;
 684         my $src=shift;
 685         my $perform_update=shift;
 686         my $force_update=shift;
 687         my $force_relocate=update_location( $name, "@$src" );
 688         my $rv=0;
 689
 690         if( $force_relocate ) {
 691                 warn "Source of feed $name has changed, replacing copy\n";
 692         }
 693         $update_method{$type} or do {
 694                 warn "Unknown type '$type' in feed $name\n";
 695                 return 1;
 696         };
 697         $perform_update and do {
 698                 my $failed = 1;
 699                 foreach my $feedsrc (@$src) {
 700                         warn "Updating feed '$name' from '$feedsrc' ...\n";
 701                         if (update_feed_via($type, $name, $feedsrc, $force_relocate, $force_update) != 0) {
 702                                 if ($force_update) {
 703                                         $rv=1;
 704                                         $failed=0;
 705                                         warn "failed, ignore.\n";
 706                                         next;
 707                                 }
 708                                 last;
 709                         }
 710                         $failed = 0;
 711                 }
 712                 $failed and do {
 713                         warn "failed.\n";
 714                         return 1;
 715                 };
 716         };
 717         warn "Create index file './feeds/$name.index' \n";
 718         update_index($name) == 0 or do {
 719                 warn "failed.\n";
 720                 return 1;
 721         };
 722         return $rv;
 723 }
 724
 725 sub update {
 726         my %opts;
 727         my $feed_name;
 728         my $perform_update=1;
 729         my $failed=0;
 730
 731         $ENV{SCAN_COOKIE} = $$;
 732         $ENV{OPENWRT_VERBOSE} = 's';
 733
 734         getopts('ahif', \%opts);
 735
 736         if ($opts{h}) {
 737                 usage();
 738                 return 0;
 739         }
 740
 741         if ($opts{i}) {
 742                 # don't update from (remote) repository
 743                 # only re-create index information
 744                 $perform_update=0;
 745         }
 746
 747         -d "feeds" or do {
 748                         mkdir "feeds" or die "Unable to create the feeds directory";
 749                 };
 750
 751         if ( ($#ARGV == -1) or $opts{a}) {
 752                 foreach my $feed (@feeds) {
 753                         my ($type, $name, $src) = @$feed;
 754                         update_feed($type, $name, $src, $perform_update, $opts{f}) == 0 or $failed=1;
 755                 }
 756         } else {
 757                 while ($feed_name = shift @ARGV) {
 758                         foreach my $feed (@feeds) {
 759                                 my ($type, $name, $src) = @$feed;
 760                                 if($feed_name ne $name) {
 761                                         next;
 762                                 }
 763                                 update_feed($type, $name, $src, $perform_update, $opts{f}) == 0 or $failed=1;
 764                         }
 765                 }
 766         }
 767
 768         refresh_config();
 769
 770         return $failed;
 771 }
 772
 773 sub feed_config() {
 774         foreach my $feed (@feeds) {
 775                 my $installed = (-f "feeds/$feed->[1].index");
 776
 777                 printf "\tconfig FEED_%s\n", $feed->[1];
 778                 printf "\t\tbool \"Enable feed %s\"\n", $feed->[1];
 779                 printf "\t\tdepends on PER_FEED_REPO\n";
 780                 printf "\t\tdefault y\n" if $installed;
 781                 printf "\t\thelp\n";
 782                 printf "\t\t Enable the \\\"%s\\\" feed at %s.\n", $feed->[1], $feed->[2][0];
 783                 printf "\n";
 784         }
 785
 786         return 0;
 787 }
 788
 789 sub usage() {
 790         print <<EOF;
 791 Usage: $0 <command> [options]
 792
 793 Commands:
 794         list [options]: List feeds, their content and revisions (if installed)
 795         Options:
 796             -n :            List of feed names.
 797             -s :            List of feed names and their URL.
 798             -r <feedname>:  List packages of specified feed.
 799             -d <delimiter>: Use specified delimiter to distinguish rows (default: spaces)
 800             -f :            List feeds in feeds.conf compatible format (when using -s).
 801
 802         install [options] <package>: Install a package
 803         Options:
 804             -a :           Install all packages from all feeds or from the specified feed using the -p option.
 805             -p <feedname>: Prefer this feed when installing packages.
 806             -d <y|m|n>:    Set default for newly installed packages.
 807             -f :           Install will be forced even if the package exists in core OpenWrt (override)
 808
 809         search [options] <substring>: Search for a package
 810         Options:
 811             -r <feedname>: Only search in this feed
 812
 813         uninstall -a|<package>: Uninstall a package
 814         Options:
 815             -a :           Uninstalls all packages.
 816
 817         update -a|<feedname(s)>: Update packages and lists of feeds in feeds.conf .
 818         Options:
 819             -a :           Update all feeds listed within feeds.conf. Otherwise the specified feeds will be updated.
 820             -i :           Recreate the index only. No feed update from repository is performed.
 821             -f :           Force updating feeds even if there are changed, uncommitted files.
 822
 823         clean:             Remove downloaded/generated files.
 824
 825 EOF
 826         exit(1);
 827 }
 828
 829 my %commands = (
 830         'list' => \&list,
 831         'update' => \&update,
 832         'install' => \&install,
 833         'search' => \&search,
 834         'uninstall' => \&uninstall,
 835         'feed_config' => \&feed_config,
 836         'clean' => sub {
 837                 system("rm -rf ./feeds ./package/feeds");
 838         }
 839 );
 840
 841 my $arg = shift @ARGV;
 842 $arg or usage();
 843 parse_config;
 844 foreach my $cmd (keys %commands) {
 845         $arg eq $cmd and do {
 846                 exit(&{$commands{$cmd}}());
 847         };
 848 }
 849 usage();