netfilter: extension fixes (partially closes: #7045) * add missing xt_owner (2.6...
[openwrt/openwrt.git] / scripts / metadata.pm
1 package metadata;
2 use base 'Exporter';
3 use strict;
4 use warnings;
5 our @EXPORT = qw(%package %srcpackage %category %subdir %preconfig %features clear_packages parse_package_metadata get_multiline);
6
7 our %package;
8 our %preconfig;
9 our %srcpackage;
10 our %category;
11 our %subdir;
12 our %features;
13
14 sub get_multiline {
15 my $fh = shift;
16 my $prefix = shift;
17 my $str;
18 while (<$fh>) {
19 last if /^@@/;
20 $str .= (($_ and $prefix) ? $prefix . $_ : $_);
21 }
22
23 return $str ? $str : "";
24 }
25
26 sub clear_packages() {
27 %subdir = ();
28 %preconfig = ();
29 %package = ();
30 %srcpackage = ();
31 %category = ();
32 %features = ();
33 }
34
35 sub parse_package_metadata($) {
36 my $file = shift;
37 my $pkg;
38 my $feature;
39 my $makefile;
40 my $preconfig;
41 my $subdir;
42 my $src;
43
44 open FILE, "<$file" or do {
45 warn "Cannot open '$file': $!\n";
46 return undef;
47 };
48 while (<FILE>) {
49 chomp;
50 /^Source-Makefile: \s*((.+\/)([^\/]+)\/Makefile)\s*$/ and do {
51 $makefile = $1;
52 $subdir = $2;
53 $src = $3;
54 $subdir =~ s/^package\///;
55 $subdir{$src} = $subdir;
56 $srcpackage{$src} = [];
57 undef $pkg;
58 };
59 next unless $src;
60 /^Package:\s*(.+?)\s*$/ and do {
61 undef $feature;
62 $pkg = {};
63 $pkg->{src} = $src;
64 $pkg->{makefile} = $makefile;
65 $pkg->{name} = $1;
66 $pkg->{title} = "";
67 $pkg->{default} = "m if ALL";
68 $pkg->{depends} = [];
69 $pkg->{builddepends} = [];
70 $pkg->{buildtypes} = [];
71 $pkg->{subdir} = $subdir;
72 $pkg->{tristate} = 1;
73 $package{$1} = $pkg;
74 push @{$srcpackage{$src}}, $pkg;
75 };
76 /^Feature:\s*(.+?)\s*$/ and do {
77 undef $pkg;
78 $feature = {};
79 $feature->{name} = $1;
80 $feature->{priority} = 0;
81 };
82 $feature and do {
83 /^Target-Name:\s*(.+?)\s*$/ and do {
84 $features{$1} or $features{$1} = [];
85 push @{$features{$1}}, $feature;
86 };
87 /^Target-Title:\s*(.+?)\s*$/ and $feature->{target_title} = $1;
88 /^Feature-Priority:\s*(\d+)\s*$/ and $feature->{priority} = $1;
89 /^Feature-Name:\s*(.+?)\s*$/ and $feature->{title} = $1;
90 /^Feature-Description:/ and $feature->{description} = get_multiline(\*FILE, "\t\t\t");
91 next;
92 };
93 next unless $pkg;
94 /^Version: \s*(.+)\s*$/ and $pkg->{version} = $1;
95 /^Title: \s*(.+)\s*$/ and $pkg->{title} = $1;
96 /^Menu: \s*(.+)\s*$/ and $pkg->{menu} = $1;
97 /^Submenu: \s*(.+)\s*$/ and $pkg->{submenu} = $1;
98 /^Submenu-Depends: \s*(.+)\s*$/ and $pkg->{submenudep} = $1;
99 /^Source: \s*(.+)\s*$/ and $pkg->{source} = $1;
100 /^Default: \s*(.+)\s*$/ and $pkg->{default} = $1;
101 /^Provides: \s*(.+)\s*$/ and do {
102 my @vpkg = split /\s+/, $1;
103 foreach my $vpkg (@vpkg) {
104 $package{$vpkg} or $package{$vpkg} = {
105 name => $vpkg,
106 vdepends => [],
107 src => $src,
108 subdir => $subdir,
109 makefile => $makefile
110 };
111 push @{$package{$vpkg}->{vdepends}}, $pkg->{name};
112 }
113 };
114 /^Depends: \s*(.+)\s*$/ and $pkg->{depends} = [ split /\s+/, $1 ];
115 /^Build-Variant: \s*([\w\-]+)\s*/ and $pkg->{variant} = $1;
116 /^Build-Only: \s*(.+)\s*$/ and $pkg->{buildonly} = 1;
117 /^Build-Depends: \s*(.+)\s*$/ and $pkg->{builddepends} = [ split /\s+/, $1 ];
118 /^Build-Depends\/(\w+): \s*(.+)\s*$/ and $pkg->{"builddepends/$1"} = [ split /\s+/, $2 ];
119 /^Build-Types:\s*(.+)\s*$/ and $pkg->{buildtypes} = [ split /\s+/, $1 ];
120 /^Category: \s*(.+)\s*$/ and do {
121 $pkg->{category} = $1;
122 defined $category{$1} or $category{$1} = {};
123 defined $category{$1}->{$src} or $category{$1}->{$src} = [];
124 push @{$category{$1}->{$src}}, $pkg;
125 };
126 /^Description: \s*(.*)\s*$/ and $pkg->{description} = "\t\t $1\n". get_multiline(*FILE, "\t\t ");
127 /^Type: \s*(.+)\s*$/ and do {
128 $pkg->{type} = [ split /\s+/, $1 ];
129 undef $pkg->{tristate};
130 foreach my $type (@{$pkg->{type}}) {
131 $type =~ /ipkg/ and $pkg->{tristate} = 1;
132 }
133 };
134 /^Config:\s*(.*)\s*$/ and $pkg->{config} = "$1\n".get_multiline(*FILE, "\t");
135 /^Prereq-Check:/ and $pkg->{prereq} = 1;
136 /^Preconfig:\s*(.+)\s*$/ and do {
137 my $pkgname = $pkg->{name};
138 $preconfig{$pkgname} or $preconfig{$pkgname} = {};
139 if (exists $preconfig{$pkgname}->{$1}) {
140 $preconfig = $preconfig{$pkgname}->{$1};
141 } else {
142 $preconfig = {
143 id => $1
144 };
145 $preconfig{$pkgname}->{$1} = $preconfig;
146 }
147 };
148 /^Preconfig-Type:\s*(.*?)\s*$/ and $preconfig->{type} = $1;
149 /^Preconfig-Label:\s*(.*?)\s*$/ and $preconfig->{label} = $1;
150 /^Preconfig-Default:\s*(.*?)\s*$/ and $preconfig->{default} = $1;
151 }
152 close FILE;
153 return 1;
154 }
155
156 1;