scripts/metadata.pm

   1 package metadata;
   2 use base 'Exporter';
   3 use strict;
   4 use warnings;
   5 our @EXPORT = qw(%package %srcpackage %category %subdir %preconfig %features %overrides clear_packages parse_package_metadata parse_target_metadata get_multiline @ignore);
   6
   7 our %package;
   8 our %preconfig;
   9 our %srcpackage;
  10 our %category;
  11 our %subdir;
  12 our %features;
  13 our %overrides;
  14 our @ignore;
  15
  16 sub get_multiline {
  17         my $fh = shift;
  18         my $prefix = shift;
  19         my $str;
  20         while (<$fh>) {
  21                 last if /^@@/;
  22                 $str .= (($_ and $prefix) ? $prefix . $_ : $_);
  23         }
  24
  25         return $str ? $str : "";
  26 }
  27
  28 sub confstr($) {
  29         my $conf = shift;
  30         $conf =~ tr#/\.\-/#___#;
  31         return $conf;
  32 }
  33
  34 sub parse_target_metadata($) {
  35         my $file = shift;
  36         my ($target, @target, $profile);
  37         my %target;
  38         my $makefile;
  39
  40         open FILE, "<$file" or do {
  41                 warn "Can't open file '$file': $!\n";
  42                 return;
  43         };
  44         while (<FILE>) {
  45                 chomp;
  46                 /^Source-Makefile: \s*((.+\/)([^\/]+)\/Makefile)\s*$/ and $makefile = $1;
  47                 /^Target:\s*(.+)\s*$/ and do {
  48                         my $name = $1;
  49                         $target = {
  50                                 id => $name,
  51                                 board => $name,
  52                                 makefile => $makefile,
  53                                 boardconf => confstr($name),
  54                                 conf => confstr($name),
  55                                 profiles => [],
  56                                 features => [],
  57                                 depends => [],
  58                                 subtargets => []
  59                         };
  60                         push @target, $target;
  61                         $target{$name} = $target;
  62                         if ($name =~ /([^\/]+)\/([^\/]+)/) {
  63                                 push @{$target{$1}->{subtargets}}, $2;
  64                                 $target->{board} = $1;
  65                                 $target->{boardconf} = confstr($1);
  66                                 $target->{subtarget} = 1;
  67                                 $target->{parent} = $target{$1};
  68                         }
  69                 };
  70                 /^Target-Name:\s*(.+)\s*$/ and $target->{name} = $1;
  71                 /^Target-Arch:\s*(.+)\s*$/ and $target->{arch} = $1;
  72                 /^Target-Arch-Packages:\s*(.+)\s*$/ and $target->{arch_packages} = $1;
  73                 /^Target-Features:\s*(.+)\s*$/ and $target->{features} = [ split(/\s+/, $1) ];
  74                 /^Target-Depends:\s*(.+)\s*$/ and $target->{depends} = [ split(/\s+/, $1) ];
  75                 /^Target-Description:/ and $target->{desc} = get_multiline(*FILE);
  76                 /^Target-Optimization:\s*(.+)\s*$/ and $target->{cflags} = $1;
  77                 /^CPU-Type:\s*(.+)\s*$/ and $target->{cputype} = $1;
  78                 /^Linux-Version:\s*(.+)\s*$/ and $target->{version} = $1;
  79                 /^Linux-Release:\s*(.+)\s*$/ and $target->{release} = $1;
  80                 /^Linux-Kernel-Arch:\s*(.+)\s*$/ and $target->{karch} = $1;
  81                 /^Default-Subtarget:\s*(.+)\s*$/ and $target->{def_subtarget} = $1;
  82                 /^Default-Packages:\s*(.+)\s*$/ and $target->{packages} = [ split(/\s+/, $1) ];
  83                 /^Target-Profile:\s*(.+)\s*$/ and do {
  84                         $profile = {
  85                                 id => $1,
  86                                 name => $1,
  87                                 priority => 999,
  88                                 packages => []
  89                         };
  90                         push @{$target->{profiles}}, $profile;
  91                 };
  92                 /^Target-Profile-Name:\s*(.+)\s*$/ and $profile->{name} = $1;
  93                 /^Target-Profile-Priority:\s*(\d+)\s*$/ and do {
  94                         $profile->{priority} = $1;
  95                         $target->{sort} = 1;
  96                 };
  97                 /^Target-Profile-Packages:\s*(.*)\s*$/ and $profile->{packages} = [ split(/\s+/, $1) ];
  98                 /^Target-Profile-Description:\s*(.*)\s*/ and $profile->{desc} = get_multiline(*FILE);
  99         }
 100         close FILE;
 101         foreach my $target (@target) {
 102                 if (@{$target->{subtargets}} > 0) {
 103                         $target->{profiles} = [];
 104                         next;
 105                 }
 106                 @{$target->{profiles}} > 0 or $target->{profiles} = [
 107                         {
 108                                 id => 'Default',
 109                                 name => 'Default',
 110                                 packages => []
 111                         }
 112                 ];
 113
 114                 $target->{sort} and @{$target->{profiles}} = sort {
 115                         $a->{priority} <=> $b->{priority} or
 116                         $a->{name} cmp $b->{name};
 117                 } @{$target->{profiles}};
 118         }
 119         return @target;
 120 }
 121
 122 sub clear_packages() {
 123         %subdir = ();
 124         %preconfig = ();
 125         %package = ();
 126         %srcpackage = ();
 127         %category = ();
 128         %features = ();
 129         %overrides = ();
 130 }
 131
 132 sub parse_package_metadata($) {
 133         my $file = shift;
 134         my $pkg;
 135         my $feature;
 136         my $makefile;
 137         my $preconfig;
 138         my $subdir;
 139         my $src;
 140         my $override;
 141         my %ignore = map { $_ => 1 } @ignore;
 142
 143         open FILE, "<$file" or do {
 144                 warn "Cannot open '$file': $!\n";
 145                 return undef;
 146         };
 147         while (<FILE>) {
 148                 chomp;
 149                 /^Source-Makefile: \s*((.+\/)([^\/]+)\/Makefile)\s*$/ and do {
 150                         $makefile = $1;
 151                         $subdir = $2;
 152                         $src = $3;
 153                         $subdir =~ s/^package\///;
 154                         $subdir{$src} = $subdir;
 155                         $srcpackage{$src} = [];
 156                         $override = "";
 157                         undef $pkg;
 158                 };
 159                 /^Override: \s*(.+?)\s*$/ and do {
 160                         $override = $1;
 161                         $overrides{$src} = 1;
 162                 };
 163                 next unless $src;
 164                 next if $ignore{$src};
 165                 /^Package:\s*(.+?)\s*$/ and do {
 166                         undef $feature;
 167                         $pkg = {};
 168                         $pkg->{src} = $src;
 169                         $pkg->{makefile} = $makefile;
 170                         $pkg->{name} = $1;
 171                         $pkg->{title} = "";
 172                         $pkg->{depends} = [];
 173                         $pkg->{mdepends} = [];
 174                         $pkg->{builddepends} = [];
 175                         $pkg->{buildtypes} = [];
 176                         $pkg->{subdir} = $subdir;
 177                         $pkg->{tristate} = 1;
 178                         $pkg->{override} = $override;
 179                         $package{$1} = $pkg;
 180                         push @{$srcpackage{$src}}, $pkg;
 181                 };
 182                 /^Feature:\s*(.+?)\s*$/ and do {
 183                         undef $pkg;
 184                         $feature = {};
 185                         $feature->{name} = $1;
 186                         $feature->{priority} = 0;
 187                 };
 188                 $feature and do {
 189                         /^Target-Name:\s*(.+?)\s*$/ and do {
 190                                 $features{$1} or $features{$1} = [];
 191                                 push @{$features{$1}}, $feature;
 192                         };
 193                         /^Target-Title:\s*(.+?)\s*$/ and $feature->{target_title} = $1;
 194                         /^Feature-Priority:\s*(\d+)\s*$/ and $feature->{priority} = $1;
 195                         /^Feature-Name:\s*(.+?)\s*$/ and $feature->{title} = $1;
 196                         /^Feature-Description:/ and $feature->{description} = get_multiline(\*FILE, "\t\t\t");
 197                         next;
 198                 };
 199                 next unless $pkg;
 200                 /^Version: \s*(.+)\s*$/ and $pkg->{version} = $1;
 201                 /^Title: \s*(.+)\s*$/ and $pkg->{title} = $1;
 202                 /^Menu: \s*(.+)\s*$/ and $pkg->{menu} = $1;
 203                 /^Submenu: \s*(.+)\s*$/ and $pkg->{submenu} = $1;
 204                 /^Submenu-Depends: \s*(.+)\s*$/ and $pkg->{submenudep} = $1;
 205                 /^Source: \s*(.+)\s*$/ and $pkg->{source} = $1;
 206                 /^License: \s*(.+)\s*$/ and $pkg->{license} = $1;
 207                 /^LicenseFiles: \s*(.+)\s*$/ and $pkg->{licensefiles} = $1;
 208                 /^Default: \s*(.+)\s*$/ and $pkg->{default} = $1;
 209                 /^Provides: \s*(.+)\s*$/ and do {
 210                         my @vpkg = split /\s+/, $1;
 211                         foreach my $vpkg (@vpkg) {
 212                                 $package{$vpkg} or $package{$vpkg} = {
 213                                         name => $vpkg,
 214                                         vdepends => [],
 215                                         src => $src,
 216                                         subdir => $subdir,
 217                                         makefile => $makefile
 218                                 };
 219                                 push @{$package{$vpkg}->{vdepends}}, $pkg->{name};
 220                         }
 221                 };
 222                 /^Menu-Depends: \s*(.+)\s*$/ and $pkg->{mdepends} = [ split /\s+/, $1 ];
 223                 /^Depends: \s*(.+)\s*$/ and $pkg->{depends} = [ split /\s+/, $1 ];
 224                 /^Conflicts: \s*(.+)\s*$/ and $pkg->{conflicts} = [ split /\s+/, $1 ];
 225                 /^Hidden: \s*(.+)\s*$/ and $pkg->{hidden} = 1;
 226                 /^Build-Variant: \s*([\w\-]+)\s*/ and $pkg->{variant} = $1;
 227                 /^Default-Variant: .*/ and $pkg->{variant_default} = 1;
 228                 /^Build-Only: \s*(.+)\s*$/ and $pkg->{buildonly} = 1;
 229                 /^Build-Depends: \s*(.+)\s*$/ and $pkg->{builddepends} = [ split /\s+/, $1 ];
 230                 /^Build-Depends\/(\w+): \s*(.+)\s*$/ and $pkg->{"builddepends/$1"} = [ split /\s+/, $2 ];
 231                 /^Build-Types:\s*(.+)\s*$/ and $pkg->{buildtypes} = [ split /\s+/, $1 ];
 232                 /^Repository:\s*(.+?)\s*$/ and $pkg->{repository} = $1;
 233                 /^Category: \s*(.+)\s*$/ and do {
 234                         $pkg->{category} = $1;
 235                         defined $category{$1} or $category{$1} = {};
 236                         defined $category{$1}->{$src} or $category{$1}->{$src} = [];
 237                         push @{$category{$1}->{$src}}, $pkg;
 238                 };
 239                 /^Description: \s*(.*)\s*$/ and $pkg->{description} = "\t\t $1\n". get_multiline(*FILE, "\t\t ");
 240                 /^Type: \s*(.+)\s*$/ and do {
 241                         $pkg->{type} = [ split /\s+/, $1 ];
 242                         undef $pkg->{tristate};
 243                         foreach my $type (@{$pkg->{type}}) {
 244                                 $type =~ /ipkg/ and $pkg->{tristate} = 1;
 245                         }
 246                 };
 247                 /^Config:\s*(.*)\s*$/ and $pkg->{config} = "$1\n".get_multiline(*FILE, "\t");
 248                 /^Prereq-Check:/ and $pkg->{prereq} = 1;
 249                 /^Preconfig:\s*(.+)\s*$/ and do {
 250                         my $pkgname = $pkg->{name};
 251                         $preconfig{$pkgname} or $preconfig{$pkgname} = {};
 252                         if (exists $preconfig{$pkgname}->{$1}) {
 253                                 $preconfig = $preconfig{$pkgname}->{$1};
 254                         } else {
 255                                 $preconfig = {
 256                                         id => $1
 257                                 };
 258                                 $preconfig{$pkgname}->{$1} = $preconfig;
 259                         }
 260                 };
 261                 /^Preconfig-Type:\s*(.*?)\s*$/ and $preconfig->{type} = $1;
 262                 /^Preconfig-Label:\s*(.*?)\s*$/ and $preconfig->{label} = $1;
 263                 /^Preconfig-Default:\s*(.*?)\s*$/ and $preconfig->{default} = $1;
 264         }
 265         close FILE;
 266         return 1;
 267 }
 268
 269 1;