bc: update to 1.07.1
[openwrt/openwrt.git] / scripts / metadata.pm
1 package metadata;
2 use base 'Exporter';
3 use strict;
4 use warnings;
5 our @EXPORT = qw(%package %vpackage %srcpackage %category %overrides clear_packages parse_package_metadata parse_target_metadata get_multiline @ignore %usernames %groupnames);
6
7 our %package;
8 our %vpackage;
9 our %srcpackage;
10 our %category;
11 our %overrides;
12 our @ignore;
13
14 our %usernames;
15 our %groupnames;
16 our %userids;
17 our %groupids;
18
19 sub get_multiline {
20 my $fh = shift;
21 my $prefix = shift;
22 my $str;
23 while (<$fh>) {
24 last if /^@@/;
25 $str .= (($_ and $prefix) ? $prefix . $_ : $_);
26 }
27
28 return $str ? $str : "";
29 }
30
31 sub confstr($) {
32 my $conf = shift;
33 $conf =~ tr#/\.\-/#___#;
34 return $conf;
35 }
36
37 sub parse_package_metadata_usergroup($$$$$) {
38 my $makefile = shift;
39 my $typename = shift;
40 my $names = shift;
41 my $ids = shift;
42 my $spec = shift;
43 my $name;
44 my $id;
45
46 # the regex for name is taken from is_valid_name() of package shadow
47 if ($spec =~ /^([a-z_][a-z0-9_-]*\$?)$/) {
48 $name = $spec;
49 $id = -1;
50 } elsif ($spec =~ /^([a-z_][a-z0-9_-]*\$?)=(\d+)$/) {
51 $name = $1;
52 $id = $2;
53 } else {
54 warn "$makefile: invalid $typename spec $spec\n";
55 return 0;
56 }
57
58 if ($id =~ /^[1-9]\d*$/) {
59 if ($id >= 65536) {
60 warn "$makefile: $typename $name id $id >= 65536";
61 return 0;
62 }
63 if (not exists $ids->{$id}) {
64 $ids->{$id} = {
65 name => $name,
66 makefile => $makefile,
67 };
68 } elsif ($ids->{$id}{name} ne $name) {
69 warn "$makefile: $typename $name id $id is already taken by $ids->{$id}{makefile}\n";
70 return 0;
71 }
72 } elsif ($id != -1) {
73 warn "$makefile: $typename $name has invalid id $id\n";
74 return 0;
75 }
76
77 if (not exists $names->{$name}) {
78 $names->{$name} = {
79 id => $id,
80 makefile => $makefile,
81 };
82 } elsif ($names->{$name}{id} != $id) {
83 warn "$makefile: id of $typename $name collides with that defined defined in $names->{$name}{makefile}\n";
84 return 0;
85 }
86 return 1;
87 }
88
89 sub parse_target_metadata($) {
90 my $file = shift;
91 my ($target, @target, $profile);
92 my %target;
93 my $makefile;
94
95 open FILE, "<$file" or do {
96 warn "Can't open file '$file': $!\n";
97 return;
98 };
99 while (<FILE>) {
100 chomp;
101 /^Source-Makefile: \s*((.+\/)([^\/]+)\/Makefile)\s*$/ and $makefile = $1;
102 /^Target:\s*(.+)\s*$/ and do {
103 my $name = $1;
104 $target = {
105 id => $name,
106 board => $name,
107 makefile => $makefile,
108 boardconf => confstr($name),
109 conf => confstr($name),
110 profiles => [],
111 features => [],
112 depends => [],
113 subtargets => []
114 };
115 push @target, $target;
116 $target{$name} = $target;
117 if ($name =~ /([^\/]+)\/([^\/]+)/) {
118 push @{$target{$1}->{subtargets}}, $2;
119 $target->{board} = $1;
120 $target->{boardconf} = confstr($1);
121 $target->{subtarget} = 1;
122 $target->{parent} = $target{$1};
123 }
124 };
125 /^Target-Name:\s*(.+)\s*$/ and $target->{name} = $1;
126 /^Target-Arch:\s*(.+)\s*$/ and $target->{arch} = $1;
127 /^Target-Arch-Packages:\s*(.+)\s*$/ and $target->{arch_packages} = $1;
128 /^Target-Features:\s*(.+)\s*$/ and $target->{features} = [ split(/\s+/, $1) ];
129 /^Target-Depends:\s*(.+)\s*$/ and $target->{depends} = [ split(/\s+/, $1) ];
130 /^Target-Description:/ and $target->{desc} = get_multiline(*FILE);
131 /^Target-Optimization:\s*(.+)\s*$/ and $target->{cflags} = $1;
132 /^CPU-Type:\s*(.+)\s*$/ and $target->{cputype} = $1;
133 /^Linux-Version:\s*(.+)\s*$/ and $target->{version} = $1;
134 /^Linux-Testing-Version:\s*(.+)\s*$/ and $target->{testing_version} = $1;
135 /^Linux-Release:\s*(.+)\s*$/ and $target->{release} = $1;
136 /^Linux-Kernel-Arch:\s*(.+)\s*$/ and $target->{karch} = $1;
137 /^Default-Subtarget:\s*(.+)\s*$/ and $target->{def_subtarget} = $1;
138 /^Default-Packages:\s*(.+)\s*$/ and $target->{packages} = [ split(/\s+/, $1) ];
139 /^Target-Profile:\s*(.+)\s*$/ and do {
140 $profile = {
141 id => $1,
142 name => $1,
143 has_image_metadata => 0,
144 supported_devices => [],
145 priority => 999,
146 packages => []
147 };
148 $1 =~ /^DEVICE_/ and $target->{has_devices} = 1;
149 push @{$target->{profiles}}, $profile;
150 };
151 /^Target-Profile-Name:\s*(.+)\s*$/ and $profile->{name} = $1;
152 /^Target-Profile-hasImageMetadata:\s*(\d+)\s*$/ and $profile->{has_image_metadata} = $1;
153 /^Target-Profile-SupportedDevices:\s*(.+)\s*$/ and $profile->{supported_devices} = [ split(/\s+/, $1) ];
154 /^Target-Profile-Priority:\s*(\d+)\s*$/ and do {
155 $profile->{priority} = $1;
156 $target->{sort} = 1;
157 };
158 /^Target-Profile-Packages:\s*(.*)\s*$/ and $profile->{packages} = [ split(/\s+/, $1) ];
159 /^Target-Profile-Description:\s*(.*)\s*/ and $profile->{desc} = get_multiline(*FILE);
160 }
161 close FILE;
162 foreach my $target (@target) {
163 if (@{$target->{subtargets}} > 0) {
164 $target->{profiles} = [];
165 next;
166 }
167 @{$target->{profiles}} > 0 or $target->{profiles} = [
168 {
169 id => 'Default',
170 name => 'Default',
171 packages => []
172 }
173 ];
174
175 $target->{sort} and @{$target->{profiles}} = sort {
176 $a->{priority} <=> $b->{priority} or
177 $a->{name} cmp $b->{name};
178 } @{$target->{profiles}};
179 }
180 return @target;
181 }
182
183 sub clear_packages() {
184 %package = ();
185 %vpackage = ();
186 %srcpackage = ();
187 %category = ();
188 %overrides = ();
189 %usernames = ();
190 %groupnames = ();
191 }
192
193 sub parse_package_metadata($) {
194 my $file = shift;
195 my $pkg;
196 my $src;
197 my $override;
198 my %ignore = map { $_ => 1 } @ignore;
199
200 open FILE, "<$file" or do {
201 warn "Cannot open '$file': $!\n";
202 return undef;
203 };
204 while (<FILE>) {
205 chomp;
206 /^Source-Makefile: \s*((?:package\/)?((?:.+\/)?([^\/]+))\/Makefile)\s*$/ and do {
207 $src = {
208 makefile => $1,
209 path => $2,
210 name => $3,
211 ignore => $ignore{$3},
212 packages => [],
213 buildtypes => [],
214 builddepends => [],
215 };
216 $srcpackage{$3} = $src;
217 $override = "";
218 undef $pkg;
219 };
220 /^Override: \s*(.+?)\s*$/ and do {
221 $override = $1;
222 $overrides{$src->{name}} = 1;
223 };
224 next unless $src;
225 /^Package:\s*(.+?)\s*$/ and do {
226 $pkg = {};
227 $pkg->{src} = $src;
228 $pkg->{name} = $1;
229 $pkg->{title} = "";
230 $pkg->{depends} = [];
231 $pkg->{mdepends} = [];
232 $pkg->{provides} = [$1];
233 $pkg->{tristate} = 1;
234 $pkg->{override} = $override;
235 $package{$1} = $pkg;
236 push @{$src->{packages}}, $pkg;
237
238 $vpackage{$1} or $vpackage{$1} = [];
239 unshift @{$vpackage{$1}}, $pkg;
240 };
241 /^Build-Depends: \s*(.+)\s*$/ and $src->{builddepends} = [ split /\s+/, $1 ];
242 /^Build-Depends\/(\w+): \s*(.+)\s*$/ and $src->{"builddepends/$1"} = [ split /\s+/, $2 ];
243 /^Build-Types:\s*(.+)\s*$/ and $src->{buildtypes} = [ split /\s+/, $1 ];
244 next unless $pkg;
245 /^Version: \s*(.+)\s*$/ and $pkg->{version} = $1;
246 /^ABIVersion: \s*(.+)\s*$/ and $pkg->{abiversion} = $1;
247 /^Title: \s*(.+)\s*$/ and $pkg->{title} = $1;
248 /^Menu: \s*(.+)\s*$/ and $pkg->{menu} = $1;
249 /^Submenu: \s*(.+)\s*$/ and $pkg->{submenu} = $1;
250 /^Submenu-Depends: \s*(.+)\s*$/ and $pkg->{submenudep} = $1;
251 /^Source: \s*(.+)\s*$/ and $pkg->{source} = $1;
252 /^License: \s*(.+)\s*$/ and $pkg->{license} = $1;
253 /^LicenseFiles: \s*(.+)\s*$/ and $pkg->{licensefiles} = $1;
254 /^Default: \s*(.+)\s*$/ and $pkg->{default} = $1;
255 /^Provides: \s*(.+)\s*$/ and do {
256 my @vpkg = split /\s+/, $1;
257 @{$pkg->{provides}} = ($pkg->{name}, @vpkg);
258 foreach my $vpkg (@vpkg) {
259 next if ($vpkg eq $pkg->{name});
260 $vpackage{$vpkg} or $vpackage{$vpkg} = [];
261 push @{$vpackage{$vpkg}}, $pkg;
262 }
263 };
264 /^Menu-Depends: \s*(.+)\s*$/ and $pkg->{mdepends} = [ split /\s+/, $1 ];
265 /^Depends: \s*(.+)\s*$/ and $pkg->{depends} = [ split /\s+/, $1 ];
266 /^Conflicts: \s*(.+)\s*$/ and $pkg->{conflicts} = [ split /\s+/, $1 ];
267 /^Hidden: \s*(.+)\s*$/ and $pkg->{hidden} = 1;
268 /^Build-Variant: \s*([\w\-]+)\s*/ and $pkg->{variant} = $1;
269 /^Default-Variant: .*/ and $pkg->{variant_default} = 1;
270 /^Build-Only: \s*(.+)\s*$/ and $pkg->{buildonly} = 1;
271 /^Repository:\s*(.+?)\s*$/ and $pkg->{repository} = $1;
272 /^Category: \s*(.+)\s*$/ and do {
273 $pkg->{category} = $1;
274 defined $category{$1} or $category{$1} = {};
275 defined $category{$1}{$src->{name}} or $category{$1}{$src->{name}} = [];
276 push @{$category{$1}{$src->{name}}}, $pkg;
277 };
278 /^Description: \s*(.*)\s*$/ and $pkg->{description} = "\t\t $1\n". get_multiline(*FILE, "\t\t ");
279 /^Type: \s*(.+)\s*$/ and do {
280 $pkg->{type} = [ split /\s+/, $1 ];
281 undef $pkg->{tristate};
282 foreach my $type (@{$pkg->{type}}) {
283 $type =~ /ipkg/ and $pkg->{tristate} = 1;
284 }
285 };
286 /^Config:\s*(.*)\s*$/ and $pkg->{config} = "$1\n".get_multiline(*FILE, "\t");
287 /^Prereq-Check:/ and $pkg->{prereq} = 1;
288 /^Require-User:\s*(.*?)\s*$/ and do {
289 my @ugspecs = split /\s+/, $1;
290
291 for my $ugspec (@ugspecs) {
292 my @ugspec = split /:/, $ugspec, 2;
293 if ($ugspec[0]) {
294 parse_package_metadata_usergroup($src->{makefile}, "user", \%usernames, \%userids, $ugspec[0]) or return 0;
295 }
296 if ($ugspec[1]) {
297 parse_package_metadata_usergroup($src->{makefile}, "group", \%groupnames, \%groupids, $ugspec[1]) or return 0;
298 }
299 }
300 };
301 }
302 close FILE;
303 return 1;
304 }
305
306 1;