metadata: simplify generation of build depends from runtime depends
[openwrt/staging/chunkeey.git] / scripts / package-metadata.pl
1 #!/usr/bin/env perl
2 use FindBin;
3 use lib "$FindBin::Bin";
4 use strict;
5 use metadata;
6 use Getopt::Long;
7
8 my %board;
9
10 sub version_to_num($) {
11 my $str = shift;
12 my $num = 0;
13
14 if (defined($str) && $str =~ /^\d+(?:\.\d+)+$/)
15 {
16 my @n = (split(/\./, $str), 0, 0, 0, 0);
17 $num = ($n[0] << 24) | ($n[1] << 16) | ($n[2] << 8) | $n[3];
18 }
19
20 return $num;
21 }
22
23 sub version_filter_list(@) {
24 my $cmpver = version_to_num(shift @_);
25 my @items;
26
27 foreach my $item (@_)
28 {
29 if ($item =~ s/@(lt|le|gt|ge|eq|ne)(\d+(?:\.\d+)+)\b//)
30 {
31 my $op = $1;
32 my $symver = version_to_num($2);
33
34 if ($symver > 0 && $cmpver > 0)
35 {
36 next unless (($op eq 'lt' && $cmpver < $symver) ||
37 ($op eq 'le' && $cmpver <= $symver) ||
38 ($op eq 'gt' && $cmpver > $symver) ||
39 ($op eq 'ge' && $cmpver >= $symver) ||
40 ($op eq 'eq' && $cmpver == $symver) ||
41 ($op eq 'ne' && $cmpver != $symver));
42 }
43 }
44
45 push @items, $item;
46 }
47
48 return @items;
49 }
50
51 sub gen_kconfig_overrides() {
52 my %config;
53 my %kconfig;
54 my $package;
55 my $pkginfo = shift @ARGV;
56 my $cfgfile = shift @ARGV;
57 my $patchver = shift @ARGV;
58
59 # parameter 2: build system config
60 open FILE, "<$cfgfile" or return;
61 while (<FILE>) {
62 /^(CONFIG_.+?)=(.+)$/ and $config{$1} = 1;
63 }
64 close FILE;
65
66 # parameter 1: package metadata
67 open FILE, "<$pkginfo" or return;
68 while (<FILE>) {
69 /^Package:\s*(.+?)\s*$/ and $package = $1;
70 /^Kernel-Config:\s*(.+?)\s*$/ and do {
71 my @config = split /\s+/, $1;
72 foreach my $config (version_filter_list($patchver, @config)) {
73 my $val = 'm';
74 my $override;
75 if ($config =~ /^(.+?)=(.+)$/) {
76 $config = $1;
77 $override = 1;
78 $val = $2;
79 }
80 if ($config{"CONFIG_PACKAGE_$package"} and ($config ne 'n')) {
81 next if $kconfig{$config} eq 'y';
82 $kconfig{$config} = $val;
83 } elsif (!$override) {
84 $kconfig{$config} or $kconfig{$config} = 'n';
85 }
86 }
87 };
88 };
89 close FILE;
90
91 foreach my $kconfig (sort keys %kconfig) {
92 if ($kconfig{$kconfig} eq 'n') {
93 print "# $kconfig is not set\n";
94 } else {
95 print "$kconfig=$kconfig{$kconfig}\n";
96 }
97 }
98 }
99
100 my %dep_check;
101 sub __find_package_dep($$) {
102 my $pkg = shift;
103 my $name = shift;
104 my $deps = ($pkg->{vdepends} or $pkg->{depends});
105
106 return 0 unless defined $deps;
107 foreach my $dep (@{$deps}) {
108 next if $dep_check{$dep};
109 $dep_check{$dep} = 1;
110 return 1 if $dep eq $name;
111 return 1 if ($package{$dep} and (__find_package_dep($package{$dep},$name) == 1));
112 }
113 return 0;
114 }
115
116 # wrapper to avoid infinite recursion
117 sub find_package_dep($$) {
118 my $pkg = shift;
119 my $name = shift;
120
121 %dep_check = ();
122 return __find_package_dep($pkg, $name);
123 }
124
125 sub package_depends($$) {
126 my $a = shift;
127 my $b = shift;
128 my $ret;
129
130 return 0 if ($a->{submenu} ne $b->{submenu});
131 if (find_package_dep($a, $b->{name}) == 1) {
132 $ret = 1;
133 } elsif (find_package_dep($b, $a->{name}) == 1) {
134 $ret = -1;
135 } else {
136 return 0;
137 }
138 return $ret;
139 }
140
141 sub mconf_depends {
142 my $pkgname = shift;
143 my $depends = shift;
144 my $only_dep = shift;
145 my $res;
146 my $dep = shift;
147 my $seen = shift;
148 my $parent_condition = shift;
149 $dep or $dep = {};
150 $seen or $seen = {};
151 my @t_depends;
152
153 $depends or return;
154 my @depends = @$depends;
155 foreach my $depend (@depends) {
156 my $m = "depends on";
157 my $flags = "";
158 $depend =~ s/^([@\+]+)// and $flags = $1;
159 my $vdep;
160 my $condition = $parent_condition;
161
162 next if $condition eq $depend;
163 next if $seen->{"$parent_condition:$depend"};
164 next if $seen->{":$depend"};
165 $seen->{"$parent_condition:$depend"} = 1;
166 if ($depend =~ /^(.+):(.+)$/) {
167 if ($1 ne "PACKAGE_$pkgname") {
168 if ($condition) {
169 $condition = "$condition && $1";
170 } else {
171 $condition = $1;
172 }
173 }
174 $depend = $2;
175 }
176 next if $package{$depend} and $package{$depend}->{buildonly};
177 if ($flags =~ /\+/) {
178 if ($vdep = $package{$depend}->{vdepends}) {
179 my @vdeps;
180 $depend = undef;
181
182 foreach my $v (@$vdep) {
183 if ($package{$v} && $package{$v}->{variant_default}) {
184 $depend = $v;
185 } else {
186 push @vdeps, $v;
187 }
188 }
189
190 if (!$depend) {
191 $depend = shift @vdeps;
192 }
193
194 if (@vdeps > 1) {
195 $condition = ($condition ? "$condition && " : '') . '!('.join("||", map { "PACKAGE_".$_ } @vdeps).')';
196 } elsif (@vdeps > 0) {
197 $condition = ($condition ? "$condition && " : '') . '!PACKAGE_'.$vdeps[0];
198 }
199 }
200
201 # Menuconfig will not treat 'select FOO' as a real dependency
202 # thus if FOO depends on other config options, these dependencies
203 # will not be checked. To fix this, we simply emit all of FOO's
204 # depends here as well.
205 $package{$depend} and push @t_depends, [ $package{$depend}->{depends}, $condition ];
206
207 $m = "select";
208 next if $only_dep;
209
210 $flags =~ /@/ or $depend = "PACKAGE_$depend";
211 } else {
212 if ($vdep = $package{$depend}->{vdepends}) {
213 $depend = join("||", map { "PACKAGE_".$_ } @$vdep);
214 } else {
215 $flags =~ /@/ or $depend = "PACKAGE_$depend";
216 }
217 }
218
219 if ($condition) {
220 if ($m =~ /select/) {
221 next if $depend eq $condition;
222 $depend = "$depend if $condition";
223 } else {
224 next if $dep->{"$depend if $condition"};
225 $depend = "!($condition) || $depend" unless $dep->{$condition} eq 'select';
226 }
227 }
228 $dep->{$depend} =~ /select/ or $dep->{$depend} = $m;
229 }
230
231 foreach my $tdep (@t_depends) {
232 mconf_depends($pkgname, $tdep->[0], 1, $dep, $seen, $tdep->[1]);
233 }
234
235 foreach my $depend (keys %$dep) {
236 my $m = $dep->{$depend};
237 $res .= "\t\t$m $depend\n";
238 }
239 return $res;
240 }
241
242 sub mconf_conflicts {
243 my $pkgname = shift;
244 my $depends = shift;
245 my $res = "";
246
247 foreach my $depend (@$depends) {
248 next unless $package{$depend};
249 $res .= "\t\tdepends on m || (PACKAGE_$depend != y)\n";
250 }
251 return $res;
252 }
253
254 sub print_package_config_category($) {
255 my $cat = shift;
256 my %menus;
257 my %menu_dep;
258
259 return unless $category{$cat};
260
261 print "menu \"$cat\"\n\n";
262 my %spkg = %{$category{$cat}};
263
264 foreach my $spkg (sort {uc($a) cmp uc($b)} keys %spkg) {
265 foreach my $pkg (@{$spkg{$spkg}}) {
266 next if $pkg->{buildonly};
267 my $menu = $pkg->{submenu};
268 if ($menu) {
269 $menu_dep{$menu} or $menu_dep{$menu} = $pkg->{submenudep};
270 } else {
271 $menu = 'undef';
272 }
273 $menus{$menu} or $menus{$menu} = [];
274 push @{$menus{$menu}}, $pkg;
275 }
276 }
277 my @menus = sort {
278 ($a eq 'undef' ? 1 : 0) or
279 ($b eq 'undef' ? -1 : 0) or
280 ($a cmp $b)
281 } keys %menus;
282
283 foreach my $menu (@menus) {
284 my @pkgs = sort {
285 package_depends($a, $b) or
286 ($a->{name} cmp $b->{name})
287 } @{$menus{$menu}};
288 if ($menu ne 'undef') {
289 $menu_dep{$menu} and print "if $menu_dep{$menu}\n";
290 print "menu \"$menu\"\n";
291 }
292 foreach my $pkg (@pkgs) {
293 next if $pkg->{src}{ignore};
294 my $title = $pkg->{name};
295 my $c = (72 - length($pkg->{name}) - length($pkg->{title}));
296 if ($c > 0) {
297 $title .= ("." x $c). " ". $pkg->{title};
298 }
299 $title = "\"$title\"";
300 print "\t";
301 $pkg->{menu} and print "menu";
302 print "config PACKAGE_".$pkg->{name}."\n";
303 $pkg->{hidden} and $title = "";
304 print "\t\t".($pkg->{tristate} ? 'tristate' : 'bool')." $title\n";
305 print "\t\tdefault y if DEFAULT_".$pkg->{name}."\n";
306 unless ($pkg->{hidden}) {
307 my @def = ("ALL");
308 if (!exists($pkg->{repository})) {
309 push @def, "ALL_NONSHARED";
310 }
311 if ($pkg->{name} =~ /^kmod-/) {
312 push @def, "ALL_KMODS";
313 }
314 $pkg->{default} ||= "m if " . join("||", @def);
315 }
316 if ($pkg->{default}) {
317 foreach my $default (split /\s*,\s*/, $pkg->{default}) {
318 print "\t\tdefault $default\n";
319 }
320 }
321 print mconf_depends($pkg->{name}, $pkg->{depends}, 0);
322 print mconf_depends($pkg->{name}, $pkg->{mdepends}, 0);
323 print mconf_conflicts($pkg->{name}, $pkg->{conflicts});
324 print "\t\thelp\n";
325 print $pkg->{description};
326 print "\n";
327
328 $pkg->{config} and print $pkg->{config}."\n";
329 }
330 if ($menu ne 'undef') {
331 print "endmenu\n";
332 $menu_dep{$menu} and print "endif\n";
333 }
334 }
335 print "endmenu\n\n";
336
337 undef $category{$cat};
338 }
339
340 sub print_package_features() {
341 keys %features > 0 or return;
342 print "menu \"Package features\"\n";
343 foreach my $n (keys %features) {
344 my @features = sort { $b->{priority} <=> $a->{priority} or $a->{title} cmp $b->{title} } @{$features{$n}};
345 print <<EOF;
346 choice
347 prompt "$features[0]->{target_title}"
348 default FEATURE_$features[0]->{name}
349 EOF
350
351 foreach my $feature (@features) {
352 print <<EOF;
353 config FEATURE_$feature->{name}
354 bool "$feature->{title}"
355 EOF
356 $feature->{description} =~ /\w/ and do {
357 print "\t\thelp\n".$feature->{description}."\n";
358 };
359 }
360 print "endchoice\n"
361 }
362 print "endmenu\n\n";
363 }
364
365 sub print_package_overrides() {
366 keys %overrides > 0 or return;
367 print "\tconfig OVERRIDE_PKGS\n";
368 print "\t\tstring\n";
369 print "\t\tdefault \"".join(" ", sort keys %overrides)."\"\n\n";
370 }
371
372 sub gen_package_config() {
373 parse_package_metadata($ARGV[0]) or exit 1;
374 print "menuconfig IMAGEOPT\n\tbool \"Image configuration\"\n\tdefault n\n";
375 print "source \"package/*/image-config.in\"\n";
376 if (scalar glob "package/feeds/*/*/image-config.in") {
377 print "source \"package/feeds/*/*/image-config.in\"\n";
378 }
379 print_package_features();
380 print_package_config_category 'Base system';
381 foreach my $cat (sort {uc($a) cmp uc($b)} keys %category) {
382 print_package_config_category $cat;
383 }
384 print_package_overrides();
385 }
386
387 sub get_conditional_dep($$) {
388 my $condition = shift;
389 my $depstr = shift;
390 if ($condition) {
391 if ($condition =~ /^!(.+)/) {
392 return "\$(if \$(CONFIG_$1),,$depstr)";
393 } else {
394 return "\$(if \$(CONFIG_$condition),$depstr)";
395 }
396 } else {
397 return $depstr;
398 }
399 }
400
401 sub gen_package_mk() {
402 my $line;
403
404 parse_package_metadata($ARGV[0]) or exit 1;
405 foreach my $srcname (sort {uc($a) cmp uc($b)} keys %srcpackage) {
406 my $src = $srcpackage{$srcname};
407 my $variant_default;
408 my %deplines = ('' => {});
409
410 foreach my $pkg (@{$src->{packages}}) {
411 foreach my $dep (@{$pkg->{depends}}) {
412 next if ($dep =~ /@/);
413
414 my $condition;
415
416 $dep =~ s/\+//g;
417 if ($dep =~ /^(.+):(.+)/) {
418 $condition = $1;
419 $dep = $2;
420 }
421
422 my $pkg_dep = $package{$dep};
423 unless (defined $pkg_dep) {
424 warn sprintf "WARNING: Makefile '%s' has a dependency on '%s', which does not exist\n",
425 $src->{makefile}, $dep;
426 next;
427 }
428
429 unless ($pkg_dep->{vdepends}) {
430 next if $srcname eq $pkg_dep->{src}{name};
431
432 my $depstr = "\$(curdir)/$pkg_dep->{src}{path}/compile";
433 my $depline = get_conditional_dep($condition, $depstr);
434 if ($depline) {
435 $deplines{''}{$depline}++;
436 }
437 next;
438 }
439
440 foreach my $vdep (@{$pkg_dep->{vdepends}}) {
441 my $pkg_vdep = $package{$vdep};
442 next if $srcname eq $pkg_vdep->{src}{name};
443
444 my $depstr = "\$(if \$(CONFIG_PACKAGE_$vdep),\$(curdir)/$pkg_vdep->{src}{path}/compile)";
445 my $depline = get_conditional_dep($condition, $depstr);
446 if ($depline) {
447 $deplines{''}{$depline}++;
448 }
449 }
450 }
451
452 next if defined $pkg->{vdepends};
453
454 my $config = '';
455 $config = "\$(CONFIG_PACKAGE_$pkg->{name})" unless $pkg->{buildonly};
456
457 $pkg->{prereq} and print "prereq-$config += $src->{path}\n";
458
459 next if $pkg->{buildonly};
460
461 print "package-$config += $src->{path}\n";
462
463 if ($pkg->{variant}) {
464 if (!defined($variant_default) or $pkg->{variant_default}) {
465 $variant_default = $pkg->{variant};
466 }
467 print "\$(curdir)/$src->{path}/variants += \$(if $config,$pkg->{variant})\n";
468 }
469 }
470
471 if (defined($variant_default)) {
472 print "\$(curdir)/$src->{path}/default-variant := $variant_default\n";
473 }
474
475 unless (grep {!$_->{buildonly}} @{$src->{packages}}) {
476 print "package- += $src->{path}\n";
477 }
478
479 if (@{$src->{buildtypes}} > 0) {
480 print "buildtypes-$src->{path} = ".join(' ', @{$src->{buildtypes}})."\n";
481 }
482
483 foreach my $type ('', @{$src->{buildtypes}}) {
484 my $suffix = '';
485
486 $suffix = "/$type" if $type;
487
488 next unless $src->{"builddepends$suffix"};
489
490 defined $deplines{$suffix} or $deplines{$suffix} = {};
491
492 foreach my $dep (@{$src->{"builddepends$suffix"}}) {
493 my $depsuffix = "";
494 my $deptype = "";
495 my $condition;
496
497 if ($dep =~ /^(.+):(.+)/) {
498 $condition = $1;
499 $dep = $2;
500 }
501 if ($dep =~ /^(.+)\/(.+)/) {
502 $dep = $1;
503 $deptype = $2;
504 $depsuffix = "/$2";
505 }
506
507 next if $srcname.$suffix eq $dep.$depsuffix;
508
509 my $src_dep = $srcpackage{$dep};
510 unless (defined($src_dep) && (!$deptype || grep { $_ eq $deptype } @{$src_dep->{buildtypes}})) {
511 warn sprintf "WARNING: Makefile '%s' has a build dependency on '%s%s', which does not exist\n",
512 $src->{makefile}, $dep, $depsuffix;
513 next;
514 }
515
516 my $depstr = "\$(curdir)/$src_dep->{path}$depsuffix/compile";
517 my $depline = get_conditional_dep($condition, $depstr);
518 if ($depline) {
519 $deplines{$suffix}{$depline}++;
520 }
521 }
522 }
523
524 foreach my $suffix (sort keys %deplines) {
525 my $depline = join(" ", sort keys %{$deplines{$suffix}});
526 if ($depline) {
527 $line .= "\$(curdir)/$src->{path}$suffix/compile += $depline\n";
528 }
529 }
530 }
531
532 if ($line ne "") {
533 print "\n$line";
534 }
535 }
536
537 sub gen_package_source() {
538 parse_package_metadata($ARGV[0]) or exit 1;
539 foreach my $name (sort {uc($a) cmp uc($b)} keys %package) {
540 my $pkg = $package{$name};
541 if ($pkg->{name} && $pkg->{source}) {
542 print "$pkg->{name}: ";
543 print "$pkg->{source}\n";
544 }
545 }
546 }
547
548 sub gen_package_subdirs() {
549 parse_package_metadata($ARGV[0]) or exit 1;
550 foreach my $name (sort {uc($a) cmp uc($b)} keys %package) {
551 my $pkg = $package{$name};
552 if ($pkg->{name} && $pkg->{repository}) {
553 print "Package/$name/subdir = $pkg->{repository}\n";
554 }
555 }
556 }
557
558 sub gen_package_license($) {
559 my $level = shift;
560 parse_package_metadata($ARGV[0]) or exit 1;
561 foreach my $name (sort {uc($a) cmp uc($b)} keys %package) {
562 my $pkg = $package{$name};
563 if ($pkg->{name}) {
564 if ($pkg->{license}) {
565 print "$pkg->{name}: ";
566 print "$pkg->{license}\n";
567 if ($pkg->{licensefiles} && $level == 0) {
568 print "\tFiles: $pkg->{licensefiles}\n";
569 }
570 } else {
571 if ($level == 1) {
572 print "$pkg->{name}: Missing license! ";
573 print "Please fix $pkg->{src}{makefile}\n";
574 }
575 }
576 }
577 }
578 }
579
580 sub gen_version_filtered_list() {
581 foreach my $item (version_filter_list(@ARGV)) {
582 print "$item\n";
583 }
584 }
585
586 sub gen_usergroup_list() {
587 parse_package_metadata($ARGV[0]) or exit 1;
588 for my $name (keys %usernames) {
589 print "user $name $usernames{$name}{id} $usernames{$name}{makefile}\n";
590 }
591 for my $name (keys %groupnames) {
592 print "group $name $groupnames{$name}{id} $groupnames{$name}{makefile}\n";
593 }
594 }
595
596 sub parse_command() {
597 GetOptions("ignore=s", \@ignore);
598 my $cmd = shift @ARGV;
599 for ($cmd) {
600 /^mk$/ and return gen_package_mk();
601 /^config$/ and return gen_package_config();
602 /^kconfig/ and return gen_kconfig_overrides();
603 /^source$/ and return gen_package_source();
604 /^subdirs$/ and return gen_package_subdirs();
605 /^license$/ and return gen_package_license(0);
606 /^licensefull$/ and return gen_package_license(1);
607 /^usergroup$/ and return gen_usergroup_list();
608 /^version_filter$/ and return gen_version_filtered_list();
609 }
610 die <<EOF
611 Available Commands:
612 $0 mk [file] Package metadata in makefile format
613 $0 config [file] Package metadata in Kconfig format
614 $0 kconfig [file] [config] [patchver] Kernel config overrides
615 $0 source [file] Package source file information
616 $0 subdirs [file] Package subdir information in makefile format
617 $0 license [file] Package license information
618 $0 licensefull [file] Package license information (full list)
619 $0 usergroup [file] Package usergroup allocation list
620 $0 version_filter [patchver] [list...] Filter list of version tagged strings
621
622 Options:
623 --ignore <name> Ignore the source package <name>
624 EOF
625 }
626
627 parse_command();