scripts/metadata.pl

   1 #!/usr/bin/env perl
   2 use FindBin;
   3 use lib "$FindBin::Bin";
   4 use strict;
   5 use metadata;
   6 use Getopt::Long;
   7
   8 my %board;
   9
  10 sub version_to_num($) {
  11         my $str = shift;
  12         my $num = 0;
  13
  14         if (defined($str) && $str =~ /^\d+(?:\.\d+)+$/)
  15         {
  16                 my @n = (split(/\./, $str), 0, 0, 0, 0);
  17                 $num = ($n[0] << 24) | ($n[1] << 16) | ($n[2] << 8) | $n[3];
  18         }
  19
  20         return $num;
  21 }
  22
  23 sub version_filter_list(@) {
  24         my $cmpver = version_to_num(shift @_);
  25         my @items;
  26
  27         foreach my $item (@_)
  28         {
  29                 if ($item =~ s/@(lt|le|gt|ge|eq|ne)(\d+(?:\.\d+)+)\b//)
  30                 {
  31                         my $op = $1;
  32                         my $symver = version_to_num($2);
  33
  34                         if ($symver > 0 && $cmpver > 0)
  35                         {
  36                                 next unless (($op eq 'lt' && $cmpver <  $symver) ||
  37                                              ($op eq 'le' && $cmpver <= $symver) ||
  38                                              ($op eq 'gt' && $cmpver >  $symver) ||
  39                                              ($op eq 'ge' && $cmpver >= $symver) ||
  40                                              ($op eq 'eq' && $cmpver == $symver) ||
  41                                              ($op eq 'ne' && $cmpver != $symver));
  42                         }
  43                 }
  44
  45                 push @items, $item;
  46         }
  47
  48         return @items;
  49 }
  50
  51 sub gen_kconfig_overrides() {
  52         my %config;
  53         my %kconfig;
  54         my $package;
  55         my $pkginfo = shift @ARGV;
  56         my $cfgfile = shift @ARGV;
  57         my $patchver = shift @ARGV;
  58
  59         # parameter 2: build system config
  60         open FILE, "<$cfgfile" or return;
  61         while (<FILE>) {
  62                 /^(CONFIG_.+?)=(.+)$/ and $config{$1} = 1;
  63         }
  64         close FILE;
  65
  66         # parameter 1: package metadata
  67         open FILE, "<$pkginfo" or return;
  68         while (<FILE>) {
  69                 /^Package:\s*(.+?)\s*$/ and $package = $1;
  70                 /^Kernel-Config:\s*(.+?)\s*$/ and do {
  71                         my @config = split /\s+/, $1;
  72                         foreach my $config (version_filter_list($patchver, @config)) {
  73                                 my $val = 'm';
  74                                 my $override;
  75                                 if ($config =~ /^(.+?)=(.+)$/) {
  76                                         $config = $1;
  77                                         $override = 1;
  78                                         $val = $2;
  79                                 }
  80                                 if ($config{"CONFIG_PACKAGE_$package"} and ($config ne 'n')) {
  81                                         next if $kconfig{$config} eq 'y';
  82                                         $kconfig{$config} = $val;
  83                                 } elsif (!$override) {
  84                                         $kconfig{$config} or $kconfig{$config} = 'n';
  85                                 }
  86                         }
  87                 };
  88         };
  89         close FILE;
  90
  91         foreach my $kconfig (sort keys %kconfig) {
  92                 if ($kconfig{$kconfig} eq 'n') {
  93                         print "# $kconfig is not set\n";
  94                 } else {
  95                         print "$kconfig=$kconfig{$kconfig}\n";
  96                 }
  97         }
  98 }
  99
 100 sub merge_package_lists($$) {
 101         my $list1 = shift;
 102         my $list2 = shift;
 103         my @l = ();
 104         my %pkgs;
 105
 106         foreach my $pkg (@$list1, @$list2) {
 107                 $pkgs{$pkg} = 1;
 108         }
 109         foreach my $pkg (keys %pkgs) {
 110                 push @l, $pkg unless ($pkg =~ /^-/ or $pkgs{"-$pkg"});
 111         }
 112         return sort(@l);
 113 }
 114
 115 sub target_config_features(@) {
 116         my $ret;
 117
 118         while ($_ = shift @_) {
 119                 /arm_v(\w+)/ and $ret .= "\tselect arm_v$1\n";
 120                 /broken/ and $ret .= "\tdepends on BROKEN\n";
 121                 /audio/ and $ret .= "\tselect AUDIO_SUPPORT\n";
 122                 /display/ and $ret .= "\tselect DISPLAY_SUPPORT\n";
 123                 /dt/ and $ret .= "\tselect USES_DEVICETREE\n";
 124                 /gpio/ and $ret .= "\tselect GPIO_SUPPORT\n";
 125                 /pci/ and $ret .= "\tselect PCI_SUPPORT\n";
 126                 /pcie/ and $ret .= "\tselect PCIE_SUPPORT\n";
 127                 /usb/ and $ret .= "\tselect USB_SUPPORT\n";
 128                 /usbgadget/ and $ret .= "\tselect USB_GADGET_SUPPORT\n";
 129                 /pcmcia/ and $ret .= "\tselect PCMCIA_SUPPORT\n";
 130                 /rtc/ and $ret .= "\tselect RTC_SUPPORT\n";
 131                 /squashfs/ and $ret .= "\tselect USES_SQUASHFS\n";
 132                 /jffs2$/ and $ret .= "\tselect USES_JFFS2\n";
 133                 /jffs2_nand/ and $ret .= "\tselect USES_JFFS2_NAND\n";
 134                 /ext4/ and $ret .= "\tselect USES_EXT4\n";
 135                 /targz/ and $ret .= "\tselect USES_TARGZ\n";
 136                 /cpiogz/ and $ret .= "\tselect USES_CPIOGZ\n";
 137                 /ubifs/ and $ret .= "\tselect USES_UBIFS\n";
 138                 /fpu/ and $ret .= "\tselect HAS_FPU\n";
 139                 /spe_fpu/ and $ret .= "\tselect HAS_SPE_FPU\n";
 140                 /ramdisk/ and $ret .= "\tselect USES_INITRAMFS\n";
 141                 /powerpc64/ and $ret .= "\tselect powerpc64\n";
 142                 /nommu/ and $ret .= "\tselect NOMMU\n";
 143                 /mips16/ and $ret .= "\tselect HAS_MIPS16\n";
 144                 /rfkill/ and $ret .= "\tselect RFKILL_SUPPORT\n";
 145                 /low_mem/ and $ret .= "\tselect LOW_MEMORY_FOOTPRINT\n";
 146                 /nand/ and $ret .= "\tselect NAND_SUPPORT\n";
 147         }
 148         return $ret;
 149 }
 150
 151 sub target_name($) {
 152         my $target = shift;
 153         my $parent = $target->{parent};
 154         if ($parent) {
 155                 return $target->{parent}->{name}." - ".$target->{name};
 156         } else {
 157                 return $target->{name};
 158         }
 159 }
 160
 161 sub kver($) {
 162         my $v = shift;
 163         $v =~ tr/\./_/;
 164         if (substr($v,0,2) eq "2_") {
 165                 $v =~ /(\d+_\d+_\d+)(_\d+)?/ and $v = $1;
 166         } else {
 167                 $v =~ /(\d+_\d+)(_\d+)?/ and $v = $1;
 168         }
 169         return $v;
 170 }
 171
 172 sub print_target($) {
 173         my $target = shift;
 174         my $features = target_config_features(@{$target->{features}});
 175         my $help = $target->{desc};
 176         my $confstr;
 177
 178         chomp $features;
 179         $features .= "\n";
 180         if ($help =~ /\w+/) {
 181                 $help =~ s/^\s*/\t  /mg;
 182                 $help = "\thelp\n$help";
 183         } else {
 184                 undef $help;
 185         }
 186
 187         my $v = kver($target->{version});
 188         if (@{$target->{subtargets}} == 0) {
 189         $confstr = <<EOF;
 190 config TARGET_$target->{conf}
 191         bool "$target->{name}"
 192         select LINUX_$v
 193 EOF
 194         }
 195         else {
 196                 $confstr = <<EOF;
 197 config TARGET_$target->{conf}
 198         bool "$target->{name}"
 199 EOF
 200         }
 201         if ($target->{subtarget}) {
 202                 $confstr .= "\tdepends on TARGET_$target->{boardconf}\n";
 203         }
 204         if (@{$target->{subtargets}} > 0) {
 205                 $confstr .= "\tselect HAS_SUBTARGETS\n";
 206                 grep { /broken/ } @{$target->{features}} and $confstr .= "\tdepends on BROKEN\n";
 207         } else {
 208                 $confstr .= $features;
 209                 if ($target->{arch} =~ /\w/) {
 210                         $confstr .= "\tselect $target->{arch}\n";
 211                 }
 212         }
 213
 214         foreach my $dep (@{$target->{depends}}) {
 215                 my $mode = "depends on";
 216                 my $flags;
 217                 my $name;
 218
 219                 $dep =~ /^([@\+\-]+)(.+)$/;
 220                 $flags = $1;
 221                 $name = $2;
 222
 223                 next if $name =~ /:/;
 224                 $flags =~ /-/ and $mode = "deselect";
 225                 $flags =~ /\+/ and $mode = "select";
 226                 $flags =~ /@/ and $confstr .= "\t$mode $name\n";
 227         }
 228         $confstr .= "$help\n\n";
 229         print $confstr;
 230 }
 231
 232 sub gen_target_config() {
 233         my $file = shift @ARGV;
 234         my @target = parse_target_metadata($file);
 235         my %defaults;
 236
 237         my @target_sort = sort {
 238                 target_name($a) cmp target_name($b);
 239         } @target;
 240
 241
 242         print <<EOF;
 243 choice
 244         prompt "Target System"
 245         default TARGET_ar71xx
 246         reset if !DEVEL
 247
 248 EOF
 249
 250         foreach my $target (@target_sort) {
 251                 next if $target->{subtarget};
 252                 print_target($target);
 253         }
 254
 255         print <<EOF;
 256 endchoice
 257
 258 choice
 259         prompt "Subtarget" if HAS_SUBTARGETS
 260 EOF
 261         foreach my $target (@target) {
 262                 next unless $target->{def_subtarget};
 263                 print <<EOF;
 264         default TARGET_$target->{conf}_$target->{def_subtarget} if TARGET_$target->{conf}
 265 EOF
 266         }
 267         print <<EOF;
 268
 269 EOF
 270         foreach my $target (@target) {
 271                 next unless $target->{subtarget};
 272                 print_target($target);
 273         }
 274
 275 print <<EOF;
 276 endchoice
 277
 278 choice
 279         prompt "Target Profile"
 280
 281 EOF
 282
 283         foreach my $target (@target) {
 284                 my $profiles = $target->{profiles};
 285
 286                 foreach my $profile (@$profiles) {
 287                         print <<EOF;
 288 config TARGET_$target->{conf}_$profile->{id}
 289         bool "$profile->{name}"
 290         depends on TARGET_$target->{conf}
 291 $profile->{config}
 292 EOF
 293                         $profile->{kconfig} and print "\tselect PROFILE_KCONFIG\n";
 294                         my @pkglist = merge_package_lists($target->{packages}, $profile->{packages});
 295                         foreach my $pkg (@pkglist) {
 296                                 print "\tselect DEFAULT_$pkg\n";
 297                                 $defaults{$pkg} = 1;
 298                         }
 299                         my $help = $profile->{desc};
 300                         if ($help =~ /\w+/) {
 301                                 $help =~ s/^\s*/\t  /mg;
 302                                 $help = "\thelp\n$help";
 303                         } else {
 304                                 undef $help;
 305                         }
 306                         print "$help\n";
 307                 }
 308         }
 309
 310         print <<EOF;
 311 endchoice
 312
 313 config HAS_SUBTARGETS
 314         bool
 315
 316 config TARGET_BOARD
 317         string
 318
 319 EOF
 320         foreach my $target (@target) {
 321                 $target->{subtarget} or print "\t\tdefault \"".$target->{board}."\" if TARGET_".$target->{conf}."\n";
 322         }
 323         print <<EOF;
 324 config TARGET_SUBTARGET
 325         string
 326         default "generic" if !HAS_SUBTARGETS
 327
 328 EOF
 329
 330         foreach my $target (@target) {
 331                 foreach my $subtarget (@{$target->{subtargets}}) {
 332                         print "\t\tdefault \"$subtarget\" if TARGET_".$target->{conf}."_$subtarget\n";
 333                 }
 334         }
 335         print <<EOF;
 336 config TARGET_ARCH_PACKAGES
 337         string
 338
 339 EOF
 340         foreach my $target (@target) {
 341                 next if @{$target->{subtargets}} > 0;
 342                 print "\t\tdefault \"".($target->{arch_packages} || $target->{board})."\" if TARGET_".$target->{conf}."\n";
 343         }
 344         print <<EOF;
 345
 346 config DEFAULT_TARGET_OPTIMIZATION
 347         string
 348 EOF
 349         foreach my $target (@target) {
 350                 next if @{$target->{subtargets}} > 0;
 351                 print "\tdefault \"".$target->{cflags}."\" if TARGET_".$target->{conf}."\n";
 352         }
 353         print "\tdefault \"-Os -pipe -funit-at-a-time\"\n";
 354         print <<EOF;
 355
 356 config CPU_TYPE
 357         string
 358 EOF
 359         foreach my $target (@target) {
 360                 next if @{$target->{subtargets}} > 0;
 361                 print "\tdefault \"".$target->{cputype}."\" if TARGET_".$target->{conf}."\n";
 362         }
 363         print "\tdefault \"\"\n";
 364
 365         my %kver;
 366         foreach my $target (@target) {
 367                 my $v = kver($target->{version});
 368                 next if $kver{$v};
 369                 $kver{$v} = 1;
 370                 print <<EOF;
 371
 372 config LINUX_$v
 373         bool
 374
 375 EOF
 376         }
 377         foreach my $def (sort keys %defaults) {
 378                 print "\tconfig DEFAULT_".$def."\n";
 379                 print "\t\tbool\n\n";
 380         }
 381 }
 382
 383 my %dep_check;
 384 sub __find_package_dep($$) {
 385         my $pkg = shift;
 386         my $name = shift;
 387         my $deps = ($pkg->{vdepends} or $pkg->{depends});
 388
 389         return 0 unless defined $deps;
 390         foreach my $dep (@{$deps}) {
 391                 next if $dep_check{$dep};
 392                 $dep_check{$dep} = 1;
 393                 return 1 if $dep eq $name;
 394                 return 1 if ($package{$dep} and (__find_package_dep($package{$dep},$name) == 1));
 395         }
 396         return 0;
 397 }
 398
 399 # wrapper to avoid infinite recursion
 400 sub find_package_dep($$) {
 401         my $pkg = shift;
 402         my $name = shift;
 403
 404         %dep_check = ();
 405         return __find_package_dep($pkg, $name);
 406 }
 407
 408 sub package_depends($$) {
 409         my $a = shift;
 410         my $b = shift;
 411         my $ret;
 412
 413         return 0 if ($a->{submenu} ne $b->{submenu});
 414         if (find_package_dep($a, $b->{name}) == 1) {
 415                 $ret = 1;
 416         } elsif (find_package_dep($b, $a->{name}) == 1) {
 417                 $ret = -1;
 418         } else {
 419                 return 0;
 420         }
 421         return $ret;
 422 }
 423
 424 sub mconf_depends {
 425         my $pkgname = shift;
 426         my $depends = shift;
 427         my $only_dep = shift;
 428         my $res;
 429         my $dep = shift;
 430         my $seen = shift;
 431         my $parent_condition = shift;
 432         $dep or $dep = {};
 433         $seen or $seen = {};
 434         my @t_depends;
 435
 436         $depends or return;
 437         my @depends = @$depends;
 438         foreach my $depend (@depends) {
 439                 my $m = "depends on";
 440                 my $flags = "";
 441                 $depend =~ s/^([@\+]+)// and $flags = $1;
 442                 my $vdep;
 443                 my $condition = $parent_condition;
 444
 445                 next if $condition eq $depend;
 446                 next if $seen->{"$parent_condition:$depend"};
 447                 next if $seen->{":$depend"};
 448                 $seen->{"$parent_condition:$depend"} = 1;
 449                 if ($depend =~ /^(.+):(.+)$/) {
 450                         if ($1 ne "PACKAGE_$pkgname") {
 451                                 if ($condition) {
 452                                         $condition = "$condition && $1";
 453                                 } else {
 454                                         $condition = $1;
 455                                 }
 456                         }
 457                         $depend = $2;
 458                 }
 459                 next if $package{$depend} and $package{$depend}->{buildonly};
 460                 if ($vdep = $package{$depend}->{vdepends}) {
 461                         $depend = join("||", map { "PACKAGE_".$_ } @$vdep);
 462                 } else {
 463                         $flags =~ /\+/ and do {
 464                                 # Menuconfig will not treat 'select FOO' as a real dependency
 465                                 # thus if FOO depends on other config options, these dependencies
 466                                 # will not be checked. To fix this, we simply emit all of FOO's
 467                                 # depends here as well.
 468                                 $package{$depend} and push @t_depends, [ $package{$depend}->{depends}, $condition ];
 469
 470                                 $m = "select";
 471                                 next if $only_dep;
 472                         };
 473                         $flags =~ /@/ or $depend = "PACKAGE_$depend";
 474                         if ($condition) {
 475                                 if ($m =~ /select/) {
 476                                         next if $depend eq $condition;
 477                                         $depend = "$depend if $condition";
 478                                 } else {
 479                                         $depend = "!($condition) || $depend" unless $dep->{$condition} eq 'select';
 480                                 }
 481                         }
 482                 }
 483                 $dep->{$depend} =~ /select/ or $dep->{$depend} = $m;
 484         }
 485
 486         foreach my $tdep (@t_depends) {
 487                 mconf_depends($pkgname, $tdep->[0], 1, $dep, $seen, $tdep->[1]);
 488         }
 489
 490         foreach my $depend (keys %$dep) {
 491                 my $m = $dep->{$depend};
 492                 $res .= "\t\t$m $depend\n";
 493         }
 494         return $res;
 495 }
 496
 497 sub mconf_conflicts {
 498         my $pkgname = shift;
 499         my $depends = shift;
 500         my $res = "";
 501
 502         foreach my $depend (@$depends) {
 503                 next unless $package{$depend};
 504                 $res .= "\t\tdepends on m || (PACKAGE_$depend != y)\n";
 505         }
 506         return $res;
 507 }
 508
 509 sub print_package_config_category($) {
 510         my $cat = shift;
 511         my %menus;
 512         my %menu_dep;
 513
 514         return unless $category{$cat};
 515
 516         print "menu \"$cat\"\n\n";
 517         my %spkg = %{$category{$cat}};
 518
 519         foreach my $spkg (sort {uc($a) cmp uc($b)} keys %spkg) {
 520                 foreach my $pkg (@{$spkg{$spkg}}) {
 521                         next if $pkg->{buildonly};
 522                         my $menu = $pkg->{submenu};
 523                         if ($menu) {
 524                                 $menu_dep{$menu} or $menu_dep{$menu} = $pkg->{submenudep};
 525                         } else {
 526                                 $menu = 'undef';
 527                         }
 528                         $menus{$menu} or $menus{$menu} = [];
 529                         push @{$menus{$menu}}, $pkg;
 530                 }
 531         }
 532         my @menus = sort {
 533                 ($a eq 'undef' ?  1 : 0) or
 534                 ($b eq 'undef' ? -1 : 0) or
 535                 ($a cmp $b)
 536         } keys %menus;
 537
 538         foreach my $menu (@menus) {
 539                 my @pkgs = sort {
 540                         package_depends($a, $b) or
 541                         ($a->{name} cmp $b->{name})
 542                 } @{$menus{$menu}};
 543                 if ($menu ne 'undef') {
 544                         $menu_dep{$menu} and print "if $menu_dep{$menu}\n";
 545                         print "menu \"$menu\"\n";
 546                 }
 547                 foreach my $pkg (@pkgs) {
 548                         my $title = $pkg->{name};
 549                         my $c = (72 - length($pkg->{name}) - length($pkg->{title}));
 550                         if ($c > 0) {
 551                                 $title .= ("." x $c). " ". $pkg->{title};
 552                         }
 553                         $title = "\"$title\"";
 554                         print "\t";
 555                         $pkg->{menu} and print "menu";
 556                         print "config PACKAGE_".$pkg->{name}."\n";
 557                         $pkg->{hidden} and $title = "";
 558                         print "\t\t".($pkg->{tristate} ? 'tristate' : 'bool')." $title\n";
 559                         print "\t\tdefault y if DEFAULT_".$pkg->{name}."\n";
 560                         unless ($pkg->{hidden}) {
 561                                 my @def = ("ALL");
 562                                 if (!exists($pkg->{repository})) {
 563                                         push @def, "ALL_NONSHARED";
 564                                 }
 565                                 if ($pkg->{name} =~ /^kmod-/) {
 566                                         push @def, "ALL_KMODS";
 567                                 }
 568                                 $pkg->{default} ||= "m if " . join("||", @def);
 569                         }
 570                         if ($pkg->{default}) {
 571                                 foreach my $default (split /\s*,\s*/, $pkg->{default}) {
 572                                         print "\t\tdefault $default\n";
 573                                 }
 574                         }
 575                         print mconf_depends($pkg->{name}, $pkg->{depends}, 0);
 576                         print mconf_depends($pkg->{name}, $pkg->{mdepends}, 0);
 577                         print mconf_conflicts($pkg->{name}, $pkg->{conflicts});
 578                         print "\t\thelp\n";
 579                         print $pkg->{description};
 580                         print "\n";
 581
 582                         $pkg->{config} and print $pkg->{config}."\n";
 583                 }
 584                 if ($menu ne 'undef') {
 585                         print "endmenu\n";
 586                         $menu_dep{$menu} and print "endif\n";
 587                 }
 588         }
 589         print "endmenu\n\n";
 590
 591         undef $category{$cat};
 592 }
 593
 594 sub print_package_features() {
 595         keys %features > 0 or return;
 596         print "menu \"Package features\"\n";
 597         foreach my $n (keys %features) {
 598                 my @features = sort { $b->{priority} <=> $a->{priority} or $a->{title} cmp $b->{title} } @{$features{$n}};
 599                 print <<EOF;
 600 choice
 601         prompt "$features[0]->{target_title}"
 602         default FEATURE_$features[0]->{name}
 603 EOF
 604
 605                 foreach my $feature (@features) {
 606                         print <<EOF;
 607         config FEATURE_$feature->{name}
 608                 bool "$feature->{title}"
 609 EOF
 610                         $feature->{description} =~ /\w/ and do {
 611                                 print "\t\thelp\n".$feature->{description}."\n";
 612                         };
 613                 }
 614                 print "endchoice\n"
 615         }
 616         print "endmenu\n\n";
 617 }
 618
 619 sub print_package_overrides() {
 620         keys %overrides > 0 or return;
 621         print "\tconfig OVERRIDE_PKGS\n";
 622         print "\t\tstring\n";
 623         print "\t\tdefault \"".join(" ", keys %overrides)."\"\n\n";
 624 }
 625
 626 sub gen_package_config() {
 627         parse_package_metadata($ARGV[0]) or exit 1;
 628         print "menuconfig IMAGEOPT\n\tbool \"Image configuration\"\n\tdefault n\n";
 629         foreach my $preconfig (keys %preconfig) {
 630                 foreach my $cfg (keys %{$preconfig{$preconfig}}) {
 631                         my $conf = $preconfig{$preconfig}->{$cfg}->{id};
 632                         $conf =~ tr/\.-/__/;
 633                         print <<EOF
 634         config UCI_PRECONFIG_$conf
 635                 string "$preconfig{$preconfig}->{$cfg}->{label}" if IMAGEOPT
 636                 depends on PACKAGE_$preconfig
 637                 default "$preconfig{$preconfig}->{$cfg}->{default}"
 638
 639 EOF
 640                 }
 641         }
 642         print "source \"package/*/image-config.in\"\n";
 643         if (scalar glob "package/feeds/*/*/image-config.in") {
 644             print "source \"package/feeds/*/*/image-config.in\"\n";
 645         }
 646         print_package_features();
 647         print_package_config_category 'Base system';
 648         foreach my $cat (sort {uc($a) cmp uc($b)} keys %category) {
 649                 print_package_config_category $cat;
 650         }
 651         print_package_overrides();
 652 }
 653
 654 sub get_conditional_dep($$) {
 655         my $condition = shift;
 656         my $depstr = shift;
 657         if ($condition) {
 658                 if ($condition =~ /^!(.+)/) {
 659                         return "\$(if \$(CONFIG_$1),,$depstr)";
 660                 } else {
 661                         return "\$(if \$(CONFIG_$condition),$depstr)";
 662                 }
 663         } else {
 664                 return $depstr;
 665         }
 666 }
 667
 668 sub gen_package_mk() {
 669         my %conf;
 670         my %dep;
 671         my %done;
 672         my $line;
 673
 674         parse_package_metadata($ARGV[0]) or exit 1;
 675         foreach my $name (sort {uc($a) cmp uc($b)} keys %package) {
 676                 my $config;
 677                 my $pkg = $package{$name};
 678                 my @srcdeps;
 679
 680                 next if defined $pkg->{vdepends};
 681
 682                 $config = "\$(CONFIG_PACKAGE_$name)";
 683                 if ($config) {
 684                         $pkg->{buildonly} and $config = "";
 685                         print "package-$config += $pkg->{subdir}$pkg->{src}\n";
 686                         if ($pkg->{variant}) {
 687                                 if (!defined($done{$pkg->{src}}) or $pkg->{variant_default}) {
 688                                         print "\$(curdir)/$pkg->{subdir}$pkg->{src}/default-variant := $pkg->{variant}\n";
 689                                 }
 690                                 print "\$(curdir)/$pkg->{subdir}$pkg->{src}/variants += \$(if $config,$pkg->{variant})\n"
 691                         }
 692                         $pkg->{prereq} and print "prereq-$config += $pkg->{subdir}$pkg->{src}\n";
 693                 }
 694
 695                 next if $done{$pkg->{src}};
 696                 $done{$pkg->{src}} = 1;
 697
 698                 if (@{$pkg->{buildtypes}} > 0) {
 699                         print "buildtypes-$pkg->{subdir}$pkg->{src} = ".join(' ', @{$pkg->{buildtypes}})."\n";
 700                 }
 701
 702                 foreach my $spkg (@{$srcpackage{$pkg->{src}}}) {
 703                         foreach my $dep (@{$spkg->{depends}}, @{$spkg->{builddepends}}) {
 704                                 $dep =~ /@/ or do {
 705                                         $dep =~ s/\+//g;
 706                                         push @srcdeps, $dep;
 707                                 };
 708                         }
 709                 }
 710                 foreach my $type (@{$pkg->{buildtypes}}) {
 711                         my @extra_deps;
 712                         my %deplines;
 713
 714                         next unless $pkg->{"builddepends/$type"};
 715                         foreach my $dep (@{$pkg->{"builddepends/$type"}}) {
 716                                 my $suffix = "";
 717                                 my $condition;
 718
 719                                 if ($dep =~ /^(.+):(.+)/) {
 720                                         $condition = $1;
 721                                         $dep = $2;
 722                                 }
 723                                 if ($dep =~ /^(.+)(\/.+)/) {
 724                                         $dep = $1;
 725                                         $suffix = $2;
 726                                 }
 727
 728                                 my $idx = "";
 729                                 my $pkg_dep = $package{$dep};
 730                                 if (defined($pkg_dep) && defined($pkg_dep->{src})) {
 731                                         $idx = $pkg_dep->{subdir}.$pkg_dep->{src};
 732                                 } elsif (defined($srcpackage{$dep})) {
 733                                         $idx = $subdir{$dep}.$dep;
 734                                 } else {
 735                                         next;
 736                                 }
 737                                 my $depstr = "\$(curdir)/$idx$suffix/compile";
 738                                 my $depline = get_conditional_dep($condition, $depstr);
 739                                 if ($depline) {
 740                                         $deplines{$depline}++;
 741                                 }
 742                         }
 743                         my $depline = join(" ", sort keys %deplines);
 744                         if ($depline) {
 745                                 $line .= "\$(curdir)/".$pkg->{subdir}."$pkg->{src}/$type/compile += $depline\n";
 746                         }
 747                 }
 748
 749                 my $hasdeps = 0;
 750                 my %deplines;
 751                 foreach my $deps (@srcdeps) {
 752                         my $idx;
 753                         my $condition;
 754                         my $prefix = "";
 755                         my $suffix = "";
 756
 757                         if ($deps =~ /^(.+):(.+)/) {
 758                                 $condition = $1;
 759                                 $deps = $2;
 760                         }
 761                         if ($deps =~ /^(.+)(\/.+)/) {
 762                                 $deps = $1;
 763                                 $suffix = $2;
 764                         }
 765
 766                         my $pkg_dep = $package{$deps};
 767                         my @deps;
 768
 769                         if ($pkg_dep->{vdepends}) {
 770                                 @deps = @{$pkg_dep->{vdepends}};
 771                         } else {
 772                                 @deps = ($deps);
 773                         }
 774
 775                         foreach my $dep (@deps) {
 776                                 $pkg_dep = $package{$deps};
 777                                 if (defined $pkg_dep->{src}) {
 778                                         ($pkg->{src} ne $pkg_dep->{src}.$suffix) and $idx = $pkg_dep->{subdir}.$pkg_dep->{src};
 779                                 } elsif (defined($srcpackage{$dep})) {
 780                                         $idx = $subdir{$dep}.$dep;
 781                                 }
 782                                 undef $idx if $idx eq 'base-files';
 783                                 if ($idx) {
 784                                         $idx .= $suffix;
 785
 786                                         my $depline;
 787                                         next if $pkg->{src} eq $pkg_dep->{src}.$suffix;
 788                                         next if $dep{$condition.":".$pkg->{src}."->".$idx};
 789                                         next if $dep{$pkg->{src}."->($dep)".$idx} and $pkg_dep->{vdepends};
 790                                         my $depstr;
 791
 792                                         if ($pkg_dep->{vdepends}) {
 793                                                 $depstr = "\$(if \$(CONFIG_PACKAGE_$dep),\$(curdir)/$idx/compile)";
 794                                                 $dep{$pkg->{src}."->($dep)".$idx} = 1;
 795                                         } else {
 796                                                 $depstr = "\$(curdir)/$idx/compile";
 797                                                 $dep{$pkg->{src}."->".$idx} = 1;
 798                                         }
 799                                         $depline = get_conditional_dep($condition, $depstr);
 800                                         if ($depline) {
 801                                                 $deplines{$depline}++;
 802                                         }
 803                                 }
 804                         }
 805                 }
 806                 my $depline = join(" ", sort keys %deplines);
 807                 if ($depline) {
 808                         $line .= "\$(curdir)/".$pkg->{subdir}."$pkg->{src}/compile += $depline\n";
 809                 }
 810         }
 811
 812         if ($line ne "") {
 813                 print "\n$line";
 814         }
 815         foreach my $preconfig (keys %preconfig) {
 816                 my $cmds;
 817                 foreach my $cfg (keys %{$preconfig{$preconfig}}) {
 818                         my $conf = $preconfig{$preconfig}->{$cfg}->{id};
 819                         $conf =~ tr/\.-/__/;
 820                         $cmds .= "\techo \"uci set '$preconfig{$preconfig}->{$cfg}->{id}=\$(subst \",,\$(CONFIG_UCI_PRECONFIG_$conf))'\"; \\\n";
 821                 }
 822                 next unless $cmds;
 823                 print <<EOF
 824
 825 ifndef DUMP_TARGET_DB
 826 \$(TARGET_DIR)/etc/uci-defaults/$preconfig: FORCE
 827         ( \\
 828 $cmds \\
 829         ) > \$@
 830
 831 ifneq (\$(IMAGEOPT)\$(CONFIG_IMAGEOPT),)
 832   package/preconfig: \$(TARGET_DIR)/etc/uci-defaults/$preconfig
 833 endif
 834 endif
 835
 836 EOF
 837         }
 838 }
 839
 840 sub gen_package_source() {
 841         parse_package_metadata($ARGV[0]) or exit 1;
 842         foreach my $name (sort {uc($a) cmp uc($b)} keys %package) {
 843                 my $pkg = $package{$name};
 844                 if ($pkg->{name} && $pkg->{source}) {
 845                         print "$pkg->{name}: ";
 846                         print "$pkg->{source}\n";
 847                 }
 848         }
 849 }
 850
 851 sub gen_package_subdirs() {
 852         parse_package_metadata($ARGV[0]) or exit 1;
 853         foreach my $name (sort {uc($a) cmp uc($b)} keys %package) {
 854                 my $pkg = $package{$name};
 855                 if ($pkg->{name} && $pkg->{repository}) {
 856                         print "Package/$name/subdir = $pkg->{repository}\n";
 857                 }
 858         }
 859 }
 860
 861 sub gen_package_license($) {
 862         my $level = shift;
 863         parse_package_metadata($ARGV[0]) or exit 1;
 864         foreach my $name (sort {uc($a) cmp uc($b)} keys %package) {
 865                 my $pkg = $package{$name};
 866                 if ($pkg->{name}) {
 867                         if ($pkg->{license}) {
 868                                 print "$pkg->{name}: ";
 869                                 print "$pkg->{license}\n";
 870                                 if ($pkg->{licensefiles} && $level == 0) {
 871                                         print "\tFiles: $pkg->{licensefiles}\n";
 872                                 }
 873                         } else {
 874                                 if ($level == 1) {
 875                                         print "$pkg->{name}: Missing license! ";
 876                                         print "Please fix $pkg->{makefile}\n";
 877                                 }
 878                         }
 879                 }
 880         }
 881 }
 882
 883 sub gen_version_filtered_list() {
 884         foreach my $item (version_filter_list(@ARGV)) {
 885                 print "$item\n";
 886         }
 887 }
 888
 889 sub parse_command() {
 890         GetOptions("ignore=s", \@ignore);
 891         my $cmd = shift @ARGV;
 892         for ($cmd) {
 893                 /^target_config$/ and return gen_target_config();
 894                 /^package_mk$/ and return gen_package_mk();
 895                 /^package_config$/ and return gen_package_config();
 896                 /^kconfig/ and return gen_kconfig_overrides();
 897                 /^package_source$/ and return gen_package_source();
 898                 /^package_subdirs$/ and return gen_package_subdirs();
 899                 /^package_license$/ and return gen_package_license(0);
 900                 /^package_licensefull$/ and return gen_package_license(1);
 901                 /^version_filter$/ and return gen_version_filtered_list();
 902         }
 903         print <<EOF
 904 Available Commands:
 905         $0 target_config [file]                 Target metadata in Kconfig format
 906         $0 package_mk [file]                    Package metadata in makefile format
 907         $0 package_config [file]                Package metadata in Kconfig format
 908         $0 kconfig [file] [config] [patchver]   Kernel config overrides
 909         $0 package_source [file]                Package source file information
 910         $0 package_subdirs [file]               Package subdir information in makefile format
 911         $0 package_license [file]               Package license information
 912         $0 package_licensefull [file]           Package license information (full list)
 913         $0 version_filter [patchver] [list...]  Filter list of version tagged strings
 914
 915 Options:
 916         --ignore <name>                         Ignore the source package <name>
 917 EOF
 918 }
 919
 920 parse_command();