qos-scripts update:
[openwrt/svn-archive/archive.git] / package / qos-scripts / files / usr / lib / qos / tcrules.awk
1 BEGIN {
2 dmax=100
3 if (!(linespeed > 0)) linespeed = 128
4 FS=":"
5 n = 0
6 }
7
8 ($1 != "") {
9 n++
10 class[n] = $1
11 prio[n] = $2
12 avgrate[n] = ($3 * linespeed / 100)
13 pktsize[n] = $4
14 delay[n] = $5
15 maxrate[n] = ($6 * linespeed / 100)
16 }
17
18 END {
19 allocated = 0
20 maxdelay = 0
21
22 for (i = 1; i <= n; i++) {
23 # set defaults
24 if (!(pktsize[i] > 0)) pktsize[i] = 1500
25 if (!(prio[i] > 0)) prio[i] = 1
26
27 allocated += avgrate[i]
28 sum_prio += prio[i]
29 if ((avgrate[i] > 0) && !(delay[i] > 0)) {
30 sum_rtprio += prio[i]
31 }
32 }
33
34 # allocation of m1 in rt classes:
35 # sum(d * m1) must not exceed dmax * (linespeed - allocated)
36 dmax = 0
37 for (i = 1; i <= n; i++) {
38 if (avgrate[i] > 0) {
39 rtm2[i] = avgrate[i]
40 if (delay[i] > 0) {
41 d[i] = delay[i]
42 } else {
43 d[i] = 2 * pktsize[i] * 1000 / (linespeed * 1024)
44 if (d[i] > dmax) dmax = d[i]
45 }
46 }
47 }
48
49 ds_avail = dmax * (linespeed - allocated)
50 for (i = 1; i <= n; i++) {
51 lsm1[i] = 0
52 rtm1[i] = 0
53 lsm2[i] = linespeed * prio[i] / sum_prio
54 if ((avgrate[i] > 0) && (d[i] > 0)) {
55 if (!(delay[i] > 0)) {
56 ds = ds_avail * prio[i] / sum_rtprio
57 ds_avail -= ds
58 rtm1[i] = rtm2[i] + ds/d[i]
59 }
60 lsm1[i] = rtm1[i]
61 }
62 else {
63 d[i] = 0
64 }
65 }
66
67 # main qdisc
68 for (i = 1; i <= n; i++) {
69 printf "tc class add dev "device" parent 1:1 classid 1:"class[i]"0 hfsc"
70 if (rtm1[i] > 0) {
71 printf " rt m1 " int(rtm1[i]) "kbit d " int(d[i] * 1000) "us m2 " int(rtm2[i])"kbit"
72 }
73 printf " ls m1 " int(lsm1[i]) "kbit d " int(d[i] * 1000) "us m2 " int(lsm2[i]) "kbit"
74 print " ul rate " int(maxrate[i]) "kbit"
75 }
76
77 # leaf qdisc
78 avpkt = 1200
79 for (i = 1; i <= n; i++) {
80 printf "tc qdisc add dev "device" parent 1:"class[i]"0 handle "class[i]"00: "
81
82 # RED parameters - also used to determine the queue length for sfq
83 # calculate min value. for links <= 256 kbit, we use 1500 bytes
84 # use 50 ms queue length as min threshold for faster links
85 # max threshold is fixed to 3*min
86 base_pkt=3000
87 base_rate=256
88 min_lat=50
89 if (maxrate[i] <= base_rate) min = base_pkt
90 else min = int(maxrate[i] * 1024 / 8 * 0.05)
91 max = 3 * min
92 limit = (min + max) * 3
93
94 if (rtm1[i] > 0) {
95 # rt class - use sfq
96 print "sfq perturb 2 limit " limit
97 } else {
98 # non-rt class - use RED
99
100 avpkt = pktsize[i]
101 # don't use avpkt values less than 500 bytes
102 if (avpkt < 500) avpkt = 500
103 # if avpkt is too close to min, scale down avpkt to allow proper bursting
104 if (avpkt > min * 0.70) avpkt *= 0.70
105
106
107 # according to http://www.cs.unc.edu/~jeffay/papers/IEEE-ToN-01.pdf a drop
108 # probability somewhere between 0.1 and 0.2 should be a good tradeoff
109 # between link utilization and response time (0.1: response; 0.2: utilization)
110 prob="0.12"
111
112 rburst=int((2*min + max) / (3 * avpkt))
113 if (rburst < 2) rburst = 2
114 print "red min " min " max " max " burst " rburst " avpkt " avpkt " limit " limit " probability " prob " ecn"
115 }
116 }
117
118 # filter rule
119 for (i = 1; i <= n; i++) {
120 print "tc filter add dev "device" parent 1: prio "class[i]" protocol ip handle "class[i]" fw flowid 1:"class[i] "0"
121 }
122 }
123