scripts/feeds

   1 #!/usr/bin/perl
   2 use Getopt::Std;
   3 use FindBin;
   4 use Cwd;
   5 use lib "$FindBin::Bin";
   6 use metadata;
   7 use warnings;
   8 use strict;
   9 use Cwd 'abs_path';
  10
  11 chdir "$FindBin::Bin/..";
  12 $ENV{TOPDIR}=getcwd();
  13 $ENV{GIT_CONFIG_PARAMETERS}="'core.autocrlf=false'";
  14
  15 my $mk=`which gmake 2>/dev/null`;       # select the right 'make' program
  16 chomp($mk);             # trim trailing newline
  17 $mk or $mk = "make";    # default to 'make'
  18
  19 # check version of make
  20 my @mkver = split /\s+/, `$mk -v`, 4;
  21 my $valid_mk = 1;
  22 $mkver[0] =~ /^GNU/ or $valid_mk = 0;
  23 $mkver[1] =~ /^Make/ or $valid_mk = 0;
  24 $mkver[2] >= "3.81" or $valid_mk = 0;
  25 $valid_mk or die "Unsupported version of make found: $mk\n";
  26
  27 my @feeds;
  28 my %build_packages;
  29 my %installed;
  30 my %feed_cache;
  31
  32 my $feed_package = {};
  33 my $feed_src = {};
  34
  35 sub parse_config() {
  36         my $line = 0;
  37         my %name;
  38
  39         open FEEDS, "feeds.conf" or
  40                 open FEEDS, "feeds.conf.default" or
  41                 die "Unable to open feeds configuration";
  42         while (<FEEDS>) {
  43                 chomp;
  44                 s/#.+$//;
  45                 next unless /\S/;
  46                 my @line = split /\s+/, $_, 3;
  47                 my @src;
  48                 $line++;
  49
  50                 my $valid = 1;
  51                 $line[0] =~ /^src-\w+$/ or $valid = 0;
  52                 $line[1] =~ /^\w+$/ or $valid = 0;
  53                 @src = split /\s+/, $line[2];
  54                 $valid or die "Syntax error in feeds.conf, line: $line\n";
  55
  56                 $name{$line[1]} and die "Duplicate feed name '$line[1]', line: $line\n";
  57                 $name{$line[1]} = 1;
  58
  59                 push @feeds, [$line[0], $line[1], \@src];
  60         }
  61         close FEEDS;
  62 }
  63
  64 sub update_location($$)
  65 {
  66         my $name = shift;
  67         my $url  = shift;
  68         my $old_url;
  69
  70         -d "./feeds/$name.tmp" or mkdir "./feeds/$name.tmp" or return 1;
  71
  72         if( open LOC, "< ./feeds/$name.tmp/location" )
  73         {
  74                 chomp($old_url = readline LOC);
  75                 close LOC;
  76         }
  77
  78         if( !$old_url || $old_url ne $url )
  79         {
  80                 if( open LOC, "> ./feeds/$name.tmp/location" )
  81                 {
  82                         print LOC $url, "\n";
  83                         close LOC;
  84                 }
  85                 return $old_url ? 1 : 0;
  86         }
  87
  88         return 0;
  89 }
  90
  91 sub update_index($)
  92 {
  93         my $name = shift;
  94
  95         -d "./feeds/$name.tmp" or mkdir "./feeds/$name.tmp" or return 1;
  96         -d "./feeds/$name.tmp/info" or mkdir "./feeds/$name.tmp/info" or return 1;
  97
  98         system("$mk -s prepare-mk OPENWRT_BUILD= TMP_DIR=\"$ENV{TOPDIR}/feeds/$name.tmp\"");
  99         system("$mk -s -f include/scan.mk IS_TTY=1 SCAN_TARGET=\"packageinfo\" SCAN_DIR=\"feeds/$name\" SCAN_NAME=\"package\" SCAN_DEPS=\"$ENV{TOPDIR}/include/package*.mk\" SCAN_DEPTH=5 SCAN_EXTRA=\"\" TMP_DIR=\"$ENV{TOPDIR}/feeds/$name.tmp\"");
 100         system("ln -sf $name.tmp/.packageinfo ./feeds/$name.index");
 101
 102         return 0;
 103 }
 104
 105 my %update_method = (
 106         'src-svn' => {
 107                 'init'          => "svn checkout '%s' '%s'",
 108                 'update'        => "svn update",
 109                 'controldir'    => ".svn",
 110                 'revision'      => "svn info | grep 'Revision' | cut -d ' ' -f 2 | tr -d '\n'"},
 111         'src-cpy' => {
 112                 'init'          => "cp -Rf '%s' '%s'",
 113                 'update'        => "",
 114                 'revision'      => "echo -n 'local'"},
 115         'src-link' => {
 116                 'init'          => "ln -s '%s' '%s'",
 117                 'update'        => "",
 118                 'revision'      => "echo -n 'local'"},
 119         'src-git' => {
 120                 'init'          => "git clone --depth 1 '%s' '%s'",
 121                 'init_branch'   => "git clone --depth 1 --branch '%s' '%s' '%s'",
 122                 'update'        => "git pull --ff",
 123                 'controldir'    => ".git",
 124                 'revision'      => "git show --abbrev-commit HEAD | head -n 1 | cut -d ' ' -f 2 | tr -d '\n'"},
 125         'src-gitsvn' => {
 126                 'init'  => "git svn clone -r HEAD '%s' '%s'",
 127                 'update'        => "git svn rebase",
 128                 'controldir'    => ".git",
 129                 'revision'      => "git show --abbrev-commit HEAD | head -n 1 | cut -d ' ' -f 2 | tr -d '\n'"},
 130         'src-bzr' => {
 131                 'init'          => "bzr checkout --lightweight '%s' '%s'",
 132                 'update'        => "bzr update",
 133                 'controldir'    => ".bzr"},
 134         'src-hg' => {
 135                 'init'          => "hg clone '%s' '%s'",
 136                 'update'        => "hg pull --update",
 137                 'controldir'    => ".hg"},
 138         'src-darcs' => {
 139                 'init'    => "darcs get '%s' '%s'",
 140                 'update'  => "darcs pull -a",
 141                 'controldir' => "_darcs"},
 142 );
 143
 144 # src-git: pull broken
 145 # src-cpy: broken if `basename $src` != $name
 146
 147 sub update_feed_via($$$$) {
 148         my $type = shift;
 149         my $name = shift;
 150         my $src = shift;
 151         my $relocate = shift;
 152
 153         my $m = $update_method{$type};
 154         my $localpath = "./feeds/$name";
 155         my $safepath = $localpath;
 156         $safepath =~ s/'/'\\''/;
 157         my ($base, $branch) = split(/;/, $src, 2);
 158
 159         if( $relocate || !$m->{'update'} || !-d "$localpath/$m->{'controldir'}" ) {
 160                 system("rm -rf '$safepath'");
 161                 if ($m->{'init_branch'} and $branch) {
 162                         system(sprintf($m->{'init_branch'}, $branch, $base, $safepath)) == 0 or return 1;
 163                 } else {
 164                         system(sprintf($m->{'init'}, $src, $safepath)) == 0 or return 1;
 165                 }
 166         } else {
 167                 system("cd '$safepath'; $m->{'update'}") == 0 or return 1;
 168         }
 169
 170         return 0;
 171 }
 172
 173 sub get_feed($) {
 174         my $feed = shift;
 175
 176         if (!defined($feed_cache{$feed})) {
 177                 my $file = "./feeds/$feed.index";
 178
 179                 clear_packages();
 180                 -f $file or do {
 181                         print "Ignoring feed '$feed' - index missing\n";
 182                         return;
 183                 };
 184                 parse_package_metadata($file) or return;
 185                 $feed_cache{$feed} = [ { %package }, { %srcpackage } ];
 186         }
 187
 188         $feed_package = $feed_cache{$feed}->[0];
 189         $feed_src = $feed_cache{$feed}->[1];
 190         return $feed_cache{$feed}->[0];
 191 }
 192
 193 sub get_installed() {
 194         system("$mk -s prepare-tmpinfo OPENWRT_BUILD=");
 195         clear_packages();
 196         parse_package_metadata("./tmp/.packageinfo");
 197         %installed = %package;
 198 }
 199
 200 sub search_feed {
 201         my $feed = shift;
 202         my @substr = @_;
 203         my $display;
 204
 205         return unless @substr > 0;
 206         get_feed($feed);
 207         foreach my $name (sort { lc($a) cmp lc($b) } keys %$feed_package) {
 208                 my $pkg = $feed_package->{$name};
 209                 my $substr;
 210                 my $pkgmatch = 1;
 211
 212                 next if $pkg->{vdepends};
 213                 foreach my $substr (@substr) {
 214                         my $match;
 215                         foreach my $key (qw(name title description src)) {
 216                                 $pkg->{$key} and $substr and $pkg->{$key} =~ m/$substr/i and $match = 1;
 217                         }
 218                         $match or undef $pkgmatch;
 219                 };
 220                 $pkgmatch and do {
 221                         $display or do {
 222                                 print "Search results in feed '$feed':\n";
 223                                 $display = 1;
 224                         };
 225                         printf "\%-25s\t\%s\n", $pkg->{name}, $pkg->{title};
 226                 };
 227         }
 228         return 0;
 229 }
 230
 231 sub search {
 232         my %opts;
 233
 234         getopt('r:', \%opts);
 235         foreach my $feed (@feeds) {
 236                 search_feed($feed->[1], @ARGV) if (!defined($opts{r}) or $opts{r} eq $feed->[1]);
 237         }
 238 }
 239
 240 sub list_feed {
 241         my $feed = shift;
 242
 243         get_feed($feed);
 244         foreach my $name (sort { lc($a) cmp lc($b) } keys %$feed_package) {
 245                 my $pkg = $feed_package->{$name};
 246                 next if $pkg->{vdepends};
 247                 if($pkg->{name}) {
 248                         printf "\%-32s\t\%s\n", $pkg->{name}, $pkg->{title};
 249                 }
 250         }
 251
 252         return 0;
 253 }
 254
 255 sub list {
 256         my %opts;
 257
 258         getopts('r:d:sh', \%opts);
 259         if ($opts{h}) {
 260                 usage();
 261                 return 0;
 262         }
 263         if ($opts{s}) {
 264                 foreach my $feed (@feeds) {
 265                         my $localpath = "./feeds/$feed->[1]";
 266                         my $m = $update_method{$feed->[0]};
 267                         my $revision;
 268                         if( !$m->{'revision'} ) {
 269                                 $revision = "X";
 270                         }
 271                         elsif( $m->{'controldir'} && -d "$localpath/$m->{'controldir'}" ) {
 272                                 $revision = `cd '$localpath'; $m->{'revision'}`;
 273                         }
 274                         else {
 275                                 $revision = "local";
 276                         }
 277                         if ($opts{d}) {
 278                                 printf "%s%s%s%s%s%s%s\n", $feed->[1], $opts{d}, $feed->[0], $opts{d}, $revision, $opts{d}, join(", ", @{$feed->[2]});
 279                         }
 280                         else {
 281                                 printf "\%-8s \%-8s \%-8s \%s\n", $feed->[1], $feed->[0], $revision, join(", ", @{$feed->[2]});
 282                         }
 283                 }
 284                 return 0;
 285         }
 286         foreach my $feed (@feeds) {
 287                 list_feed($feed->[1], @ARGV) if (!defined($opts{r}) or $opts{r} eq $feed->[1]);
 288         }
 289         return 0;
 290 }
 291
 292 sub install_generic() {
 293         my $feed = shift;
 294         my $pkg = shift;
 295         my $path = $pkg->{makefile};
 296
 297         if($path) {
 298                 $path =~ s/\/Makefile$//;
 299
 300                 -d "./package/feeds" or mkdir "./package/feeds";
 301                 -d "./package/feeds/$feed->[1]" or mkdir "./package/feeds/$feed->[1]";
 302                 system("ln -sf ../../../$path ./package/feeds/$feed->[1]/");
 303         } else {
 304                 warn "Package is not valid\n";
 305                 return 1;
 306         }
 307
 308         return 0;
 309 }
 310
 311 my %install_method = (
 312         'src-svn' => \&install_generic,
 313         'src-cpy' => \&install_generic,
 314         'src-link' => \&install_generic,
 315         'src-git' => \&install_generic,
 316         'src-gitsvn' => \&install_generic,
 317         'src-bzr' => \&install_generic,
 318         'src-hg' => \&install_generic,
 319         'src-darcs' => \&install_generic,
 320 );
 321
 322 my %feed;
 323
 324 sub lookup_package($$) {
 325         my $feed = shift;
 326         my $package = shift;
 327
 328         foreach my $feed ($feed, @feeds) {
 329                 next unless $feed->[1];
 330                 next unless $feed{$feed->[1]};
 331                 $feed{$feed->[1]}->{$package} and return $feed;
 332         }
 333         return;
 334 }
 335
 336 sub is_core_package($) {
 337         my $package = shift;
 338         foreach my $file ("tmp/info/.packageinfo-$package", glob("tmp/info/.packageinfo-*_$package")) {
 339                 next unless index($file, "tmp/info/.packageinfo-feeds_");
 340                 return 1 if -s $file;
 341         }
 342         return 0;
 343 }
 344
 345 sub install_package {
 346         my $feed = shift;
 347         my $name = shift;
 348         my $ret = 0;
 349
 350         $feed = lookup_package($feed, $name);
 351         $feed or do {
 352                 $installed{$name} and return 0;
 353                 # TODO: check if it's already installed within ./package directory
 354                 $feed_src->{$name} or is_core_package($name) or warn "WARNING: No feed for package '$name' found, maybe it's already part of the standard packages?\n";
 355                 return 0;
 356         };
 357
 358         # switch to the metadata for the selected feed
 359         get_feed($feed->[1]);
 360
 361         my $pkg = $feed{$feed->[1]}->{$name} or return 1;
 362         $pkg->{name} or do {
 363                 $installed{$name} and return 0;
 364                 # TODO: check if this is an alias package, maybe it's known by another name
 365                 warn "WARNING: Package '$name' is not available in feed $feed->[1].\n";
 366                 return 0;
 367         };
 368         my $src = $pkg->{src};
 369         my $type = $feed->[0];
 370         $src or $src = $name;
 371
 372         # previously installed packages set the runtime package
 373         # newly installed packages set the source package
 374         $installed{$src} and return 0;
 375
 376         # check previously installed packages
 377         $installed{$name} and return 0;
 378         $installed{$src} = 1;
 379         warn "Installing package '$src'\n";
 380
 381         $install_method{$type} or do {
 382                 warn "Unknown installation method: '$type'\n";
 383                 return 1;
 384         };
 385
 386         &{$install_method{$type}}($feed, $pkg) == 0 or do {
 387                 warn "failed.\n";
 388                 return 1;
 389         };
 390
 391         # install all dependencies referenced from the source package
 392         foreach my $vpkg (@{$feed_src->{$src}}) {
 393                 foreach my $dep (@{$vpkg->{depends}}, @{$vpkg->{builddepends}}, @{$vpkg->{"builddepends/host"}}) {
 394                         next if $dep =~ /@/;
 395                         $dep =~ s/^\+//;
 396                         $dep =~ s/^.+://;
 397                         $dep =~ s/\/.+$//;
 398                         next unless $dep;
 399                         install_package($feed, $dep) == 0 or $ret = 1;
 400                 }
 401         }
 402
 403         return $ret;
 404 }
 405
 406 sub refresh_config {
 407         my $default = shift;
 408
 409         # workaround for timestamp check
 410         system("rm -f tmp/.packageinfo");
 411
 412         # refresh the config
 413         if ($default) {
 414                 system("$mk oldconfig CONFDEFAULT=\"$default\" Config.in >/dev/null 2>/dev/null");
 415         } else {
 416                 system("$mk defconfig Config.in >/dev/null 2>/dev/null");
 417         }
 418 }
 419
 420 sub install {
 421         my $name;
 422         my %opts;
 423         my $feed;
 424         my $ret = 0;
 425
 426         getopts('ap:d:h', \%opts);
 427
 428         if ($opts{h}) {
 429                 usage();
 430                 return 0;
 431         }
 432
 433         get_installed();
 434
 435         foreach my $f (@feeds) {
 436                 # index all feeds
 437                 $feed{$f->[1]} = get_feed($f->[1]);
 438
 439                 # look up the preferred feed
 440                 $opts{p} and $f->[1] eq $opts{p} and $feed = $f;
 441         }
 442
 443         if($opts{a}) {
 444                 foreach my $f (@feeds) {
 445                         if (!defined($opts{p}) or $opts{p} eq $f->[1]) {
 446                                 printf "Installing all packages from feed %s.\n", $f->[1];
 447                                 get_feed($f->[1]);
 448                                 foreach my $name (sort { lc($a) cmp lc($b) } keys %$feed_package) {
 449                                         my $p = $feed_package->{$name};
 450                                         next if $p->{vdepends};
 451                                         if( $p->{name} ) {
 452                                                 install_package($feed, $p->{name}) == 0 or $ret = 1;
 453                                                 get_feed($f->[1]);
 454                                         }
 455                                 }
 456                         }
 457                 }
 458         } else {
 459                 while ($name = shift @ARGV) {
 460                         install_package($feed, $name) == 0 or $ret = 1;
 461                 }
 462         }
 463
 464         # workaround for timestamp check
 465
 466         # set the defaults
 467         if ($opts{d} and $opts{d} =~ /^[ymn]$/) {
 468                 refresh_config($opts{d});
 469         }
 470
 471         return $ret;
 472 }
 473
 474 sub uninstall {
 475         my %opts;
 476         my $name;
 477         my $uninstall;
 478
 479         getopts('ah', \%opts);
 480
 481         if ($opts{h}) {
 482                 usage();
 483                 return 0;
 484         }
 485
 486         if ($opts{a}) {
 487                 system("rm -rvf ./package/feeds");
 488                 $uninstall = 1;
 489         } else {
 490                 if($#ARGV == -1) {
 491                         warn "WARNING: no package to uninstall\n";
 492                         return 0;
 493                 }
 494                 get_installed();
 495                 while ($name = shift @ARGV) {
 496                         my $pkg = $installed{$name};
 497                         $pkg or do {
 498                                 warn "WARNING: $name not installed\n";
 499                                 next;
 500                         };
 501                         $pkg->{src} and $name = $pkg->{src};
 502                         warn "Uninstalling package '$name'\n";
 503                         system("rm -f ./package/feeds/*/$name");
 504                         $uninstall = 1;
 505                 }
 506         }
 507         $uninstall and refresh_config();
 508         return 0;
 509 }
 510
 511 sub update_feed($$$$)
 512 {
 513         my $type=shift;
 514         my $name=shift;
 515         my $src=shift;
 516         my $perform_update=shift;
 517         my $force_relocate=update_location( $name, "@$src" );
 518
 519         if( $force_relocate ) {
 520                 warn "Source of feed $name has changed, replacing copy\n";
 521         }
 522         $update_method{$type} or do {
 523                 warn "Unknown type '$type' in feed $name\n";
 524                 return 1;
 525         };
 526         $perform_update and do {
 527                 my $failed = 1;
 528                 foreach my $feedsrc (@$src) {
 529                         warn "Updating feed '$name' from '$feedsrc' ...\n";
 530                         next unless update_feed_via($type, $name, $feedsrc, $force_relocate) == 0;
 531                         $failed = 0;
 532                         last;
 533                 }
 534                 $failed and do {
 535                         warn "failed.\n";
 536                         return 1;
 537                 };
 538         };
 539         warn "Create index file './feeds/$name.index' \n";
 540         update_index($name) == 0 or do {
 541                 warn "failed.\n";
 542                 return 1;
 543         };
 544         return 0;
 545 }
 546
 547 sub update {
 548         my %opts;
 549         my $feed_name;
 550         my $perform_update=1;
 551
 552         $ENV{SCAN_COOKIE} = $$;
 553         $ENV{OPENWRT_VERBOSE} = 's';
 554
 555         getopts('ahi', \%opts);
 556
 557         if ($opts{h}) {
 558                 usage();
 559                 return 0;
 560         }
 561
 562         if ($opts{i}) {
 563                 # don't update from (remote) repository
 564                 # only re-create index information
 565                 $perform_update=0;
 566         }
 567
 568         -d "feeds" or do {
 569                         mkdir "feeds" or die "Unable to create the feeds directory";
 570                 };
 571
 572         if ( ($#ARGV == -1) or $opts{a}) {
 573                 foreach my $feed (@feeds) {
 574                         my ($type, $name, $src) = @$feed;
 575                         update_feed($type, $name, $src, $perform_update);
 576                 }
 577         } else {
 578                 while ($feed_name = shift @ARGV) {
 579                         foreach my $feed (@feeds) {
 580                                 my ($type, $name, $src) = @$feed;
 581                                 if($feed_name ne $name) {
 582                                         next;
 583                                 }
 584                                 update_feed($type, $name, $src, $perform_update);
 585                         }
 586                 }
 587         }
 588
 589         refresh_config();
 590
 591         return 0;
 592 }
 593
 594 sub usage() {
 595         print <<EOF;
 596 Usage: $0 <command> [options]
 597
 598 Commands:
 599         list [options]: List feeds, their content and revisions (if installed)
 600         Options:
 601             -s :            List of feed names and their URL.
 602             -r <feedname>:  List packages of specified feed.
 603             -d <delimiter>: Use specified delimiter to distinguish rows (default: spaces)
 604
 605         install [options] <package>: Install a package
 606         Options:
 607             -a :           Install all packages from all feeds or from the specified feed using the -p option.
 608             -p <feedname>: Prefer this feed when installing packages.
 609             -d <y|m|n>:    Set default for newly installed packages.
 610
 611         search [options] <substring>: Search for a package
 612         Options:
 613             -r <feedname>: Only search in this feed
 614
 615         uninstall -a|<package>: Uninstall a package
 616         Options:
 617             -a :           Uninstalls all packages.
 618
 619         update -a|<feedname(s)>: Update packages and lists of feeds in feeds.conf .
 620         Options:
 621             -a :           Update all feeds listed within feeds.conf. Otherwise the specified feeds will be updated.
 622             -i :           Recreate the index only. No feed update from repository is performed.
 623
 624         clean:             Remove downloaded/generated files.
 625
 626 EOF
 627         exit(1);
 628 }
 629
 630 my %commands = (
 631         'list' => \&list,
 632         'update' => \&update,
 633         'install' => \&install,
 634         'search' => \&search,
 635         'uninstall' => \&uninstall,
 636         'clean' => sub {
 637                 system("rm -rf feeds");
 638         }
 639 );
 640
 641 my $arg = shift @ARGV;
 642 $arg or usage();
 643 parse_config;
 644 foreach my $cmd (keys %commands) {
 645         $arg eq $cmd and do {
 646                 exit(&{$commands{$cmd}}());
 647         };
 648 }
 649 usage();