merge r17576 to 8.09
[openwrt/svn-archive/archive.git] / scripts / metadata.pm
1 package metadata;
2 use base 'Exporter';
3 use strict;
4 use warnings;
5 our @EXPORT = qw(%package %srcpackage %category %subdir %preconfig clear_packages parse_package_metadata get_multiline);
6
7 our %package;
8 our %preconfig;
9 our %srcpackage;
10 our %category;
11 our %subdir;
12
13 sub get_multiline {
14 my $fh = shift;
15 my $prefix = shift;
16 my $str;
17 while (<$fh>) {
18 last if /^@@/;
19 s/^\s*//g;
20 $str .= (($_ and $prefix) ? $prefix . $_ : $_);
21 }
22
23 return $str ? $str : "";
24 }
25
26 sub clear_packages() {
27 %subdir = ();
28 %preconfig = ();
29 %package = ();
30 %srcpackage = ();
31 %category = ();
32 }
33
34 sub parse_package_metadata($) {
35 my $file = shift;
36 my $pkg;
37 my $makefile;
38 my $preconfig;
39 my $subdir;
40 my $src;
41
42 open FILE, "<$file" or do {
43 warn "Cannot open '$file': $!\n";
44 return undef;
45 };
46 while (<FILE>) {
47 chomp;
48 /^Source-Makefile: \s*((.+\/)([^\/]+)\/Makefile)\s*$/ and do {
49 $makefile = $1;
50 $subdir = $2;
51 $src = $3;
52 $subdir =~ s/^package\///;
53 $subdir{$src} = $subdir;
54 $srcpackage{$src} = [];
55 undef $pkg;
56 };
57 next unless $src;
58 /^Package:\s*(.+?)\s*$/ and do {
59 $pkg = {};
60 $pkg->{src} = $src;
61 $pkg->{makefile} = $makefile;
62 $pkg->{name} = $1;
63 $pkg->{title} = "";
64 $pkg->{default} = "m if ALL";
65 $pkg->{depends} = [];
66 $pkg->{builddepends} = [];
67 $pkg->{buildtypes} = [];
68 $pkg->{subdir} = $subdir;
69 $pkg->{tristate} = 1;
70 $package{$1} = $pkg;
71 push @{$srcpackage{$src}}, $pkg;
72 };
73 /^Version: \s*(.+)\s*$/ and $pkg->{version} = $1;
74 /^Title: \s*(.+)\s*$/ and $pkg->{title} = $1;
75 /^Menu: \s*(.+)\s*$/ and $pkg->{menu} = $1;
76 /^Submenu: \s*(.+)\s*$/ and $pkg->{submenu} = $1;
77 /^Submenu-Depends: \s*(.+)\s*$/ and $pkg->{submenudep} = $1;
78 /^Source: \s*(.+)\s*$/ and $pkg->{source} = $1;
79 /^Default: \s*(.+)\s*$/ and $pkg->{default} = $1;
80 /^Provides: \s*(.+)\s*$/ and do {
81 my @vpkg = split /\s+/, $1;
82 foreach my $vpkg (@vpkg) {
83 $package{$vpkg} or $package{$vpkg} = {
84 name => $vpkg,
85 vdepends => [],
86 src => $src,
87 subdir => $subdir,
88 makefile => $makefile
89 };
90 push @{$package{$vpkg}->{vdepends}}, $pkg->{name};
91 }
92 };
93 /^Depends: \s*(.+)\s*$/ and $pkg->{depends} = [ split /\s+/, $1 ];
94 /^Build-Only: \s*(.+)\s*$/ and $pkg->{buildonly} = 1;
95 /^Build-Depends: \s*(.+)\s*$/ and $pkg->{builddepends} = [ split /\s+/, $1 ];
96 /^Build-Depends\/(\w+): \s*(.+)\s*$/ and $pkg->{"builddepends/$1"} = [ split /\s+/, $2 ];
97 /^Build-Types:\s*(.+)\s*$/ and $pkg->{buildtypes} = [ split /\s+/, $1 ];
98 /^Category: \s*(.+)\s*$/ and do {
99 $pkg->{category} = $1;
100 defined $category{$1} or $category{$1} = {};
101 defined $category{$1}->{$src} or $category{$1}->{$src} = [];
102 push @{$category{$1}->{$src}}, $pkg;
103 };
104 /^Description: \s*(.*)\s*$/ and $pkg->{description} = "\t\t $1\n". get_multiline(*FILE, "\t\t ");
105 /^Type: \s*(.+)\s*$/ and do {
106 $pkg->{type} = [ split /\s+/, $1 ];
107 undef $pkg->{tristate};
108 foreach my $type (@{$pkg->{type}}) {
109 $type =~ /ipkg/ and $pkg->{tristate} = 1;
110 }
111 };
112 /^Config:\s*(.*)\s*$/ and $pkg->{config} = "$1\n".get_multiline(*FILE, "\t");
113 /^Prereq-Check:/ and $pkg->{prereq} = 1;
114 /^Preconfig:\s*(.+)\s*$/ and do {
115 my $pkgname = $pkg->{name};
116 $preconfig{$pkgname} or $preconfig{$pkgname} = {};
117 if (exists $preconfig{$pkgname}->{$1}) {
118 $preconfig = $preconfig{$pkgname}->{$1};
119 } else {
120 $preconfig = {
121 id => $1
122 };
123 $preconfig{$pkgname}->{$1} = $preconfig;
124 }
125 };
126 /^Preconfig-Type:\s*(.*?)\s*$/ and $preconfig->{type} = $1;
127 /^Preconfig-Label:\s*(.*?)\s*$/ and $preconfig->{label} = $1;
128 /^Preconfig-Default:\s*(.*?)\s*$/ and $preconfig->{default} = $1;
129 }
130 close FILE;
131 return 1;
132 }
133
134 1;