scripts/feeds

   1 #!/usr/bin/env perl
   2 use Getopt::Std;
   3 use FindBin;
   4 use Cwd;
   5 use lib "$FindBin::Bin";
   6 use metadata;
   7 use warnings;
   8 use strict;
   9 use Cwd 'abs_path';
  10
  11 chdir "$FindBin::Bin/..";
  12 $ENV{TOPDIR}=getcwd();
  13 $ENV{GIT_CONFIG_PARAMETERS}="'core.autocrlf=false'";
  14 $ENV{GREP_OPTIONS}="";
  15
  16 my $mk=`which gmake 2>/dev/null`;       # select the right 'make' program
  17 chomp($mk);             # trim trailing newline
  18 $mk or $mk = "make";    # default to 'make'
  19
  20 # check version of make
  21 my @mkver = split /\s+/, `$mk -v`, 4;
  22 my $valid_mk = 1;
  23 $mkver[0] =~ /^GNU/ or $valid_mk = 0;
  24 $mkver[1] =~ /^Make/ or $valid_mk = 0;
  25
  26 my ($mkv1, $mkv2) = split /\./, $mkver[2];
  27 ($mkv1 >= 4 || ($mkv1 == 3 && $mkv2 >= 81)) or $valid_mk = 0;
  28
  29 $valid_mk or die "Unsupported version of make found: $mk\n";
  30
  31 my @feeds;
  32 my %build_packages;
  33 my %installed;
  34 my %installed_targets;
  35 my %feed_cache;
  36
  37 my $feed_package = {};
  38 my $feed_src = {};
  39 my $feed_target = {};
  40
  41 sub parse_config() {
  42         my $line = 0;
  43         my %name;
  44
  45         open FEEDS, "feeds.conf" or
  46                 open FEEDS, "feeds.conf.default" or
  47                 die "Unable to open feeds configuration";
  48         while (<FEEDS>) {
  49                 chomp;
  50                 s/#.+$//;
  51                 next unless /\S/;
  52                 my @line = split /\s+/, $_, 3;
  53                 my @src;
  54                 $line++;
  55
  56                 my $valid = 1;
  57                 $line[0] =~ /^src-[\w-]+$/ or $valid = 0;
  58                 $line[1] =~ /^\w+$/ or $valid = 0;
  59                 @src = split /\s+/, $line[2];
  60                 $valid or die "Syntax error in feeds.conf, line: $line\n";
  61
  62                 $name{$line[1]} and die "Duplicate feed name '$line[1]', line: $line\n";
  63                 $name{$line[1]} = 1;
  64
  65                 push @feeds, [$line[0], $line[1], \@src];
  66         }
  67         close FEEDS;
  68 }
  69
  70 sub update_location($$)
  71 {
  72         my $name = shift;
  73         my $url  = shift;
  74         my $old_url;
  75
  76         -d "./feeds/$name.tmp" or mkdir "./feeds/$name.tmp" or return 1;
  77
  78         if( open LOC, "< ./feeds/$name.tmp/location" )
  79         {
  80                 chomp($old_url = readline LOC);
  81                 close LOC;
  82         }
  83
  84         if( !$old_url || $old_url ne $url )
  85         {
  86                 if( open LOC, "> ./feeds/$name.tmp/location" )
  87                 {
  88                         print LOC $url, "\n";
  89                         close LOC;
  90                 }
  91                 return $old_url ? 1 : 0;
  92         }
  93
  94         return 0;
  95 }
  96
  97 sub update_index($)
  98 {
  99         my $name = shift;
 100
 101         -d "./feeds/$name.tmp" or mkdir "./feeds/$name.tmp" or return 1;
 102         -d "./feeds/$name.tmp/info" or mkdir "./feeds/$name.tmp/info" or return 1;
 103
 104         system("$mk -s prepare-mk OPENWRT_BUILD= TMP_DIR=\"$ENV{TOPDIR}/feeds/$name.tmp\"");
 105         system("$mk -s -f include/scan.mk IS_TTY=1 SCAN_TARGET=\"packageinfo\" SCAN_DIR=\"feeds/$name\" SCAN_NAME=\"package\" SCAN_DEPS=\"$ENV{TOPDIR}/include/package*.mk\" SCAN_DEPTH=5 SCAN_EXTRA=\"\" TMP_DIR=\"$ENV{TOPDIR}/feeds/$name.tmp\"");
 106         system("$mk -s -f include/scan.mk IS_TTY=1 SCAN_TARGET=\"targetinfo\" SCAN_DIR=\"feeds/$name\" SCAN_NAME=\"target\" SCAN_DEPS=\"profiles/*.mk $ENV{TOPDIR}/include/target.mk\" SCAN_DEPTH=5 SCAN_EXTRA=\"\" SCAN_MAKEOPTS=\"TARGET_BUILD=1\" TMP_DIR=\"$ENV{TOPDIR}/feeds/$name.tmp\"");
 107         system("ln -sf $name.tmp/.packageinfo ./feeds/$name.index");
 108         system("ln -sf $name.tmp/.targetinfo ./feeds/$name.targetindex");
 109
 110         return 0;
 111 }
 112
 113 my %update_method = (
 114         'src-svn' => {
 115                 'init'          => "svn checkout '%s' '%s'",
 116                 'update'        => "svn update",
 117                 'controldir'    => ".svn",
 118                 'revision'      => "svn info | grep 'Revision' | cut -d ' ' -f 2 | tr -d '\n'"},
 119         'src-cpy' => {
 120                 'init'          => "cp -Rf '%s' '%s'",
 121                 'update'        => "",
 122                 'revision'      => "echo -n 'local'"},
 123         'src-link' => {
 124                 'init'          => "ln -s '%s' '%s'",
 125                 'update'        => "",
 126                 'revision'      => "echo -n 'local'"},
 127         'src-git' => {
 128                 'init'          => "git clone --depth 1 '%s' '%s'",
 129                 'init_branch'   => "git clone --depth 1 --branch '%s' '%s' '%s'",
 130                 'init_commit'   => "git clone '%s' '%s' && cd '%s' && git checkout -b '%s' '%s' && cd -",
 131                 'update'        => "git pull --ff",
 132                 'update_force'  => "git pull --ff || (git reset --hard HEAD; git pull --ff; exit 1)",
 133                 'controldir'    => ".git",
 134                 'revision'      => "git rev-parse --short HEAD | tr -d '\n'"},
 135         'src-git-full' => {
 136                 'init'          => "git clone '%s' '%s'",
 137                 'init_branch'   => "git clone --branch '%s' '%s' '%s'",
 138                 'init_commit'   => "git clone '%s' '%s' && cd '%s' && git checkout -b '%s' '%s' && cd -",
 139                 'update'        => "git pull --ff",
 140                 'update_force'  => "git pull --ff || (git reset --hard HEAD; git pull --ff; exit 1)",
 141                 'controldir'    => ".git",
 142                 'revision'      => "git rev-parse --short HEAD | tr -d '\n'"},
 143         'src-gitsvn' => {
 144                 'init'  => "git svn clone -r HEAD '%s' '%s'",
 145                 'update'        => "git svn rebase",
 146                 'controldir'    => ".git",
 147                 'revision'      => "git rev-parse --short HEAD | tr -d '\n'"},
 148         'src-bzr' => {
 149                 'init'          => "bzr checkout --lightweight '%s' '%s'",
 150                 'update'        => "bzr update",
 151                 'controldir'    => ".bzr"},
 152         'src-hg' => {
 153                 'init'          => "hg clone '%s' '%s'",
 154                 'update'        => "hg pull --update",
 155                 'controldir'    => ".hg"},
 156         'src-darcs' => {
 157                 'init'    => "darcs get '%s' '%s'",
 158                 'update'  => "darcs pull -a",
 159                 'controldir' => "_darcs"},
 160 );
 161
 162 # src-git: pull broken
 163 # src-cpy: broken if `basename $src` != $name
 164
 165 sub update_feed_via($$$$$) {
 166         my $type = shift;
 167         my $name = shift;
 168         my $src = shift;
 169         my $relocate = shift;
 170         my $force = shift;
 171
 172         my $m = $update_method{$type};
 173         my $localpath = "./feeds/$name";
 174         my $safepath = $localpath;
 175         $safepath =~ s/'/'\\''/;
 176         my ($base_branch, $branch) = split(/;/, $src, 2);
 177         my ($base_commit, $commit) = split(/\^/, $src, 2);
 178
 179         if( $relocate || !$m->{'update'} || !-d "$localpath/$m->{'controldir'}" ) {
 180                 system("rm -rf '$safepath'");
 181                 if ($m->{'init_branch'} and $branch) {
 182                         system(sprintf($m->{'init_branch'}, $branch, $base_branch, $safepath)) == 0 or return 1;
 183                 } elsif ($m->{'init_commit'} and $commit) {
 184                         system(sprintf($m->{'init_commit'}, $base_commit, $safepath, $safepath, $commit, $commit)) == 0 or return 1;
 185                 } else {
 186                         system(sprintf($m->{'init'}, $src, $safepath)) == 0 or return 1;
 187                 }
 188         } elsif ($m->{'init_commit'} and $commit) {
 189                 # in case git hash has been provided don't update the feed
 190         } else {
 191                 my $update_cmd = $m->{'update'};
 192                 if ($force && exists $m->{'update_force'}) {
 193                         $update_cmd = $m->{'update_force'};
 194                 }
 195                 system("cd '$safepath'; $update_cmd") == 0 or return 1;
 196         }
 197
 198         return 0;
 199 }
 200
 201 sub get_targets($) {
 202         my $file = shift;
 203         my @target = parse_target_metadata($file);
 204         my %target;
 205         foreach my $target (@target) {
 206                 $target{$target->{id}} = $target;
 207         }
 208         return %target
 209 }
 210
 211 sub get_feed($) {
 212         my $feed = shift;
 213
 214         if (!defined($feed_cache{$feed})) {
 215                 my $file = "./feeds/$feed.index";
 216
 217                 clear_packages();
 218                 -f $file or do {
 219                         print "Ignoring feed '$feed' - index missing\n";
 220                         return;
 221                 };
 222                 parse_package_metadata($file) or return;
 223                 my %target = get_targets("./feeds/$feed.targetindex");
 224
 225                 $feed_cache{$feed} = [ { %package }, { %srcpackage }, { %target } ];
 226         }
 227
 228         $feed_package = $feed_cache{$feed}->[0];
 229         $feed_src = $feed_cache{$feed}->[1];
 230         $feed_target = $feed_cache{$feed}->[2];
 231         return $feed_cache{$feed}->[0];
 232 }
 233
 234 sub get_installed() {
 235         system("$mk -s prepare-tmpinfo OPENWRT_BUILD=");
 236         clear_packages();
 237         parse_package_metadata("./tmp/.packageinfo");
 238         %installed = %package;
 239         %installed_targets = get_targets("./tmp/.targetinfo");
 240 }
 241
 242 sub search_feed {
 243         my $feed = shift;
 244         my @substr = @_;
 245         my $display;
 246
 247         return unless @substr > 0;
 248         get_feed($feed);
 249         foreach my $name (sort { lc($a) cmp lc($b) } keys %$feed_package) {
 250                 my $pkg = $feed_package->{$name};
 251                 my $substr;
 252                 my $pkgmatch = 1;
 253
 254                 next if $pkg->{vdepends};
 255                 foreach my $substr (@substr) {
 256                         my $match;
 257                         foreach my $key (qw(name title description src)) {
 258                                 $pkg->{$key} and $substr and $pkg->{$key} =~ m/$substr/i and $match = 1;
 259                         }
 260                         $match or undef $pkgmatch;
 261                 };
 262                 $pkgmatch and do {
 263                         $display or do {
 264                                 print "Search results in feed '$feed':\n";
 265                                 $display = 1;
 266                         };
 267                         printf "\%-25s\t\%s\n", $pkg->{name}, $pkg->{title};
 268                 };
 269         }
 270
 271         foreach my $name (sort { lc($a) cmp lc($b) } keys %$feed_target) {
 272                 my $target = $feed_target->{$name};
 273                 my $targetmatch = 1;
 274
 275                 foreach my $substr (@substr) {
 276                         my $match;
 277                         foreach my $key (qw(id name description)) {
 278                                 $target->{$key} and $substr and $target->{$key} =~ m/$substr/i and $match = 1;
 279                         }
 280                         $match or undef $targetmatch;
 281                 };
 282                 $targetmatch and do {
 283                         $display or do {
 284                                 print "Search results in feed '$feed':\n";
 285                                 $display = 1;
 286                         };
 287                         printf "TARGET: \%-17s\t\%s\n", $target->{id}, $target->{name};
 288                 };
 289         }
 290         return 0;
 291 }
 292
 293 sub search {
 294         my %opts;
 295
 296         getopt('r:', \%opts);
 297         foreach my $feed (@feeds) {
 298                 search_feed($feed->[1], @ARGV) if (!defined($opts{r}) or $opts{r} eq $feed->[1]);
 299         }
 300 }
 301
 302 sub list_feed {
 303         my $feed = shift;
 304
 305         get_feed($feed);
 306         foreach my $name (sort { lc($a) cmp lc($b) } keys %$feed_package) {
 307                 my $pkg = $feed_package->{$name};
 308                 next if $pkg->{vdepends};
 309                 if($pkg->{name}) {
 310                         printf "\%-32s\t\%s\n", $pkg->{name}, $pkg->{title};
 311                 }
 312         }
 313
 314         foreach my $name (sort { lc($a) cmp lc($b) } keys %$feed_target) {
 315                 my $target = $feed_target->{$name};
 316                 if($target->{name}) {
 317                         printf "TARGET: \%-24s\t\%s\n", $target->{id}, $target->{name};
 318                 }
 319         }
 320
 321         return 0;
 322 }
 323
 324 sub list {
 325         my %opts;
 326
 327         getopts('r:d:nshf', \%opts);
 328         if ($opts{h}) {
 329                 usage();
 330                 return 0;
 331         }
 332         if ($opts{n}) {
 333                 foreach my $feed (@feeds) {
 334                         printf "%s\n", $feed->[1];
 335                 }
 336                 return 0;
 337         }
 338         if ($opts{s}) {
 339                 foreach my $feed (@feeds) {
 340                         my $localpath = "./feeds/$feed->[1]";
 341                         my $m = $update_method{$feed->[0]};
 342                         my $revision;
 343                         if (!-d "$localpath" || !$m->{'revision'}) {
 344                                 $revision = "X";
 345                         }
 346                         elsif( $m->{'controldir'} && -d "$localpath/$m->{'controldir'}" ) {
 347                                 $revision = `cd '$localpath'; $m->{'revision'}`;
 348                         }
 349                         else {
 350                                 $revision = "local";
 351                         }
 352                         if ($opts{d}) {
 353                                 printf "%s%s%s%s%s%s%s\n", $feed->[1], $opts{d}, $feed->[0], $opts{d}, $revision, $opts{d}, join(", ", @{$feed->[2]});
 354                         }
 355                         elsif ($opts{f}) {
 356                                 my $uri = join(", ", @{$feed->[2]});
 357                                 if ($revision ne "local" && $revision ne "X") {
 358                                         $uri =~ s/[;^].*//;
 359                                         $uri .= "^" . $revision;
 360                                 }
 361                                 printf "%s %s %s\n", $feed->[0], $feed->[1], $uri;
 362                         }
 363                         else {
 364                                 printf "\%-10s \%-8s \%-8s \%s\n", $feed->[1], $feed->[0], $revision, join(", ", @{$feed->[2]});
 365                         }
 366                 }
 367                 return 0;
 368         }
 369         foreach my $feed (@feeds) {
 370                 list_feed($feed->[1], @ARGV) if (!defined($opts{r}) or $opts{r} eq $feed->[1]);
 371         }
 372         return 0;
 373 }
 374
 375 sub do_install_package($$) {
 376         my $feed = shift;
 377         my $pkg = shift;
 378         my $path = $pkg->{makefile};
 379
 380         if($path) {
 381                 $path =~ s/\/Makefile$//;
 382
 383                 -d "./package/feeds" or mkdir "./package/feeds";
 384                 -d "./package/feeds/$feed->[1]" or mkdir "./package/feeds/$feed->[1]";
 385                 system("ln -sf ../../../$path ./package/feeds/$feed->[1]/");
 386         } else {
 387                 warn "Package is not valid\n";
 388                 return 1;
 389         }
 390
 391         return 0;
 392 }
 393
 394 sub do_install_target($) {
 395         my $target = shift;
 396         my $path = $target->{makefile};
 397
 398         if ($path) {
 399                 $path =~ s/\/Makefile$//;
 400                 my $name = $path;
 401                 $name =~ s/.*\///;
 402                 my $dest = "./target/linux/$name";
 403
 404                 -e $dest and do {
 405                         warn "Path $dest already exists";
 406                         return 1;
 407                 };
 408
 409                 system("ln -sf ../../$path ./target/linux/");
 410         } else {
 411                 warn "Target is not valid\n";
 412                 return 1;
 413         }
 414
 415         return 0;
 416 }
 417
 418 sub lookup_package($$) {
 419         my $feed = shift;
 420         my $package = shift;
 421
 422         foreach my $feed ($feed, @feeds) {
 423                 next unless $feed->[1];
 424                 next unless $feed_cache{$feed->[1]};
 425                 $feed_cache{$feed->[1]}->[0]->{$package} and return $feed;
 426         }
 427         return;
 428 }
 429
 430 sub lookup_target($$) {
 431         my $feed = shift;
 432         my $target = shift;
 433
 434         foreach my $feed ($feed, @feeds) {
 435                 next unless $feed->[1];
 436                 next unless $feed_cache{$feed->[1]};
 437                 $feed_cache{$feed->[1]}->[2]->{$target} and return $feed;
 438         }
 439         return;
 440 }
 441
 442 sub is_core_package($) {
 443         my $package = shift;
 444         foreach my $file ("tmp/info/.packageinfo-$package", glob("tmp/info/.packageinfo-*_$package")) {
 445                 next unless index($file, "tmp/info/.packageinfo-feeds_");
 446                 return 1 if -s $file;
 447         }
 448         return 0;
 449 }
 450
 451 sub install_target {
 452         my $feed = shift;
 453         my $name = shift;
 454
 455         $feed = $feed_cache{$feed->[1]}->[2];
 456         $feed or return 0;
 457
 458         my $target = $feed->{$name};
 459         $target or return 0;
 460
 461         warn "Installing target '$name'\n";
 462         return do_install_target($target);
 463 }
 464
 465 sub install_package {
 466         my $feed = shift;
 467         my $name = shift;
 468         my $force = shift;
 469         my $ret = 0;
 470
 471         my $this_feed_target = lookup_target($feed, $name);
 472         $this_feed_target and do {
 473                 $installed_targets{$name} and return 0;
 474                 install_target($this_feed_target, $name);
 475                 return 0;
 476         };
 477
 478         $feed = lookup_package($feed, $name);
 479         $feed or do {
 480                 $installed{$name} and return 0;
 481                 # TODO: check if it's already installed within ./package directory
 482                 $feed_src->{$name} or is_core_package($name) or warn "WARNING: No feed for package '$name' found, maybe it's already part of the standard packages?\n";
 483                 return 0;
 484         };
 485
 486         # switch to the metadata for the selected feed
 487         my $cur = get_feed($feed->[1]);
 488
 489         my $pkg = $cur->{$name} or return 1;
 490         $pkg->{name} or do {
 491                 $installed{$name} and return 0;
 492                 # TODO: check if this is an alias package, maybe it's known by another name
 493                 warn "WARNING: Package '$name' is not available in feed $feed->[1].\n";
 494                 return 0;
 495         };
 496         my $src = $pkg->{src};
 497         my $type = $feed->[0];
 498         $src or $src = $name;
 499
 500         # If it's a core package and we don't want to override, just return
 501         !$force and is_core_package($src) and return 0;
 502
 503         # previously installed packages set the runtime package
 504         # newly installed packages set the source package to 1
 505         $installed{$src} and $installed{$src} == 1 and return 0;
 506
 507         # we'll trigger the override only with the 3 conditions below:
 508         # - override is allowed by command line (-f)
 509         # - a package with the same src exists in the core packages list
 510         # - the package previously installed is not from a feed
 511         my $override = 1 if ($force and is_core_package($src) and !$installed{$name}->{feed});
 512
 513         # check previously installed packages
 514         $installed{$name} and !$override and return 0;
 515         $installed{$src} = 1;
 516
 517         defined($override) and $override == 1
 518                 and warn "Overriding core package '$src' with version from $feed->[1]\n"
 519                 or warn "Installing package '$src' from $feed->[1]\n";
 520
 521         do_install_package($feed, $pkg) == 0 or do {
 522                 warn "failed.\n";
 523                 return 1;
 524         };
 525
 526         # install all dependencies referenced from the source package
 527         foreach my $vpkg (@{$feed_src->{$src}}) {
 528                 foreach my $dep (@{$vpkg->{depends}}, @{$vpkg->{builddepends}}, @{$vpkg->{"builddepends/host"}}) {
 529                         next if $dep =~ /@/;
 530                         $dep =~ s/^\+//;
 531                         $dep =~ s/^.+://;
 532                         $dep =~ s/\/.+$//;
 533                         next unless $dep;
 534                         install_package($feed, $dep, 0) == 0 or $ret = 1;
 535                 }
 536         }
 537
 538         return $ret;
 539 }
 540
 541 sub refresh_config {
 542         my $default = shift;
 543
 544         # Don't create .config if it doesn't already exist so that making a
 545         # config only occurs when the user intends it do (however we do
 546         # want to refresh an existing config).
 547         return if not (-e '.config');
 548
 549         # workaround for timestamp check
 550         system("rm -f tmp/.packageinfo");
 551
 552         # refresh the config
 553         if ($default) {
 554                 system("$mk oldconfig CONFDEFAULT=\"$default\" Config.in >/dev/null 2>/dev/null");
 555         } else {
 556                 system("$mk defconfig Config.in >/dev/null 2>/dev/null");
 557         }
 558 }
 559
 560 sub install {
 561         my $name;
 562         my %opts;
 563         my $feed;
 564         my $ret = 0;
 565
 566         getopts('ap:d:fh', \%opts);
 567
 568         if ($opts{h}) {
 569                 usage();
 570                 return 0;
 571         }
 572
 573         get_installed();
 574
 575         foreach my $f (@feeds) {
 576                 # fetch all feeds
 577                 get_feed($f->[1]);
 578
 579                 # look up the preferred feed
 580                 $opts{p} and $f->[1] eq $opts{p} and $feed = $f;
 581         }
 582
 583         if($opts{a}) {
 584                 foreach my $f (@feeds) {
 585                         if (!defined($opts{p}) or $opts{p} eq $f->[1]) {
 586                                 printf "Installing all packages from feed %s.\n", $f->[1];
 587                                 get_feed($f->[1]);
 588                                 foreach my $name (sort { lc($a) cmp lc($b) } keys %$feed_package) {
 589                                         my $p = $feed_package->{$name};
 590                                         next if $p->{vdepends};
 591                                         if( $p->{name} ) {
 592                                                 install_package($feed, $p->{name}, exists($opts{f})) == 0 or $ret = 1;
 593                                                 get_feed($f->[1]);
 594                                         }
 595                                 }
 596                         }
 597                 }
 598         } else {
 599                 while ($name = shift @ARGV) {
 600                         install_package($feed, $name, exists($opts{f})) == 0 or $ret = 1;
 601                 }
 602         }
 603
 604         # workaround for timestamp check
 605
 606         # set the defaults
 607         if ($opts{d} and $opts{d} =~ /^[ymn]$/) {
 608                 refresh_config($opts{d});
 609         }
 610
 611         return $ret;
 612 }
 613
 614 sub uninstall_target($) {
 615         my $dir = shift;
 616         my $name = $dir;
 617         $name =~ s/.*\///g;
 618
 619         my $dest = readlink $dir;
 620         return unless $dest =~ /..\/..\/feeds/;
 621         warn "Uninstalling target '$name'\n";
 622         unlink "$dir";
 623 }
 624
 625 sub uninstall {
 626         my %opts;
 627         my $name;
 628         my $uninstall;
 629
 630         getopts('ah', \%opts);
 631
 632         if ($opts{h}) {
 633                 usage();
 634                 return 0;
 635         }
 636
 637         if ($opts{a}) {
 638                 system("rm -rvf ./package/feeds");
 639                 foreach my $dir (glob "target/linux/*") {
 640                         next unless -l $dir;
 641                         uninstall_target($dir);
 642                 }
 643                 $uninstall = 1;
 644         } else {
 645                 if($#ARGV == -1) {
 646                         warn "WARNING: no package to uninstall\n";
 647                         return 0;
 648                 }
 649                 get_installed();
 650                 while ($name = shift @ARGV) {
 651                         my $target = "target/linux/$name";
 652                         -l "$target" and do {
 653                                 uninstall_target($target);
 654                                 $uninstall = 1;
 655                                 next;
 656                         };
 657
 658                         my $pkg = $installed{$name};
 659                         $pkg or do {
 660                                 warn "WARNING: $name not installed\n";
 661                                 next;
 662                         };
 663                         $pkg->{src} and $name = $pkg->{src};
 664                         warn "Uninstalling package '$name'\n";
 665                         system("rm -f ./package/feeds/*/$name");
 666                         $uninstall = 1;
 667                 }
 668         }
 669         $uninstall and refresh_config();
 670         return 0;
 671 }
 672
 673 sub update_feed($$$$$)
 674 {
 675         my $type=shift;
 676         my $name=shift;
 677         my $src=shift;
 678         my $perform_update=shift;
 679         my $force_update=shift;
 680         my $force_relocate=update_location( $name, "@$src" );
 681         my $rv=0;
 682
 683         if( $force_relocate ) {
 684                 warn "Source of feed $name has changed, replacing copy\n";
 685         }
 686         $update_method{$type} or do {
 687                 warn "Unknown type '$type' in feed $name\n";
 688                 return 1;
 689         };
 690         $perform_update and do {
 691                 my $failed = 1;
 692                 foreach my $feedsrc (@$src) {
 693                         warn "Updating feed '$name' from '$feedsrc' ...\n";
 694                         if (update_feed_via($type, $name, $feedsrc, $force_relocate, $force_update) != 0) {
 695                                 if ($force_update) {
 696                                         $rv=1;
 697                                         $failed=0;
 698                                         warn "failed, ignore.\n";
 699                                         next;
 700                                 }
 701                                 last;
 702                         }
 703                         $failed = 0;
 704                 }
 705                 $failed and do {
 706                         warn "failed.\n";
 707                         return 1;
 708                 };
 709         };
 710         warn "Create index file './feeds/$name.index' \n";
 711         update_index($name) == 0 or do {
 712                 warn "failed.\n";
 713                 return 1;
 714         };
 715         return $rv;
 716 }
 717
 718 sub update {
 719         my %opts;
 720         my $feed_name;
 721         my $perform_update=1;
 722         my $failed=0;
 723
 724         $ENV{SCAN_COOKIE} = $$;
 725         $ENV{OPENWRT_VERBOSE} = 's';
 726
 727         getopts('ahif', \%opts);
 728
 729         if ($opts{h}) {
 730                 usage();
 731                 return 0;
 732         }
 733
 734         if ($opts{i}) {
 735                 # don't update from (remote) repository
 736                 # only re-create index information
 737                 $perform_update=0;
 738         }
 739
 740         -d "feeds" or do {
 741                         mkdir "feeds" or die "Unable to create the feeds directory";
 742                 };
 743
 744         if ( ($#ARGV == -1) or $opts{a}) {
 745                 foreach my $feed (@feeds) {
 746                         my ($type, $name, $src) = @$feed;
 747                         update_feed($type, $name, $src, $perform_update, $opts{f}) == 0 or $failed=1;
 748                 }
 749         } else {
 750                 while ($feed_name = shift @ARGV) {
 751                         foreach my $feed (@feeds) {
 752                                 my ($type, $name, $src) = @$feed;
 753                                 if($feed_name ne $name) {
 754                                         next;
 755                                 }
 756                                 update_feed($type, $name, $src, $perform_update, $opts{f}) == 0 or $failed=1;
 757                         }
 758                 }
 759         }
 760
 761         refresh_config();
 762
 763         return $failed;
 764 }
 765
 766 sub feed_config() {
 767         foreach my $feed (@feeds) {
 768                 my $installed = (-f "feeds/$feed->[1].index");
 769
 770                 printf "\tconfig FEED_%s\n", $feed->[1];
 771                 printf "\t\tbool \"Enable feed %s\"\n", $feed->[1];
 772                 printf "\t\tdepends on PER_FEED_REPO\n";
 773                 printf "\t\tdefault y\n" if $installed;
 774                 printf "\t\thelp\n";
 775                 printf "\t\t Enable the \\\"%s\\\" feed at %s.\n", $feed->[1], $feed->[2][0];
 776                 printf "\n";
 777         }
 778
 779         return 0;
 780 }
 781
 782 sub usage() {
 783         print <<EOF;
 784 Usage: $0 <command> [options]
 785
 786 Commands:
 787         list [options]: List feeds, their content and revisions (if installed)
 788         Options:
 789             -n :            List of feed names.
 790             -s :            List of feed names and their URL.
 791             -r <feedname>:  List packages of specified feed.
 792             -d <delimiter>: Use specified delimiter to distinguish rows (default: spaces)
 793             -f :            List feeds in feeds.conf compatible format (when using -s).
 794
 795         install [options] <package>: Install a package
 796         Options:
 797             -a :           Install all packages from all feeds or from the specified feed using the -p option.
 798             -p <feedname>: Prefer this feed when installing packages.
 799             -d <y|m|n>:    Set default for newly installed packages.
 800             -f :           Install will be forced even if the package exists in core OpenWrt (override)
 801
 802         search [options] <substring>: Search for a package
 803         Options:
 804             -r <feedname>: Only search in this feed
 805
 806         uninstall -a|<package>: Uninstall a package
 807         Options:
 808             -a :           Uninstalls all packages.
 809
 810         update -a|<feedname(s)>: Update packages and lists of feeds in feeds.conf .
 811         Options:
 812             -a :           Update all feeds listed within feeds.conf. Otherwise the specified feeds will be updated.
 813             -i :           Recreate the index only. No feed update from repository is performed.
 814             -f :           Force updating feeds even if there are changed, uncommitted files.
 815
 816         clean:             Remove downloaded/generated files.
 817
 818 EOF
 819         exit(1);
 820 }
 821
 822 my %commands = (
 823         'list' => \&list,
 824         'update' => \&update,
 825         'install' => \&install,
 826         'search' => \&search,
 827         'uninstall' => \&uninstall,
 828         'feed_config' => \&feed_config,
 829         'clean' => sub {
 830                 system("rm -rf ./feeds ./package/feeds");
 831         }
 832 );
 833
 834 my $arg = shift @ARGV;
 835 $arg or usage();
 836 parse_config;
 837 foreach my $cmd (keys %commands) {
 838         $arg eq $cmd and do {
 839                 exit(&{$commands{$cmd}}());
 840         };
 841 }
 842 usage();