scripts/config/zconf.y

   1 %{
   2 /*
   3  * Copyright (C) 2002 Roman Zippel <zippel@linux-m68k.org>
   4  * Released under the terms of the GNU GPL v2.0.
   5  */
   6
   7 #include <ctype.h>
   8 #include <stdarg.h>
   9 #include <stdio.h>
  10 #include <stdlib.h>
  11 #include <string.h>
  12 #include <stdbool.h>
  13
  14 #include "lkc.h"
  15
  16 #define printd(mask, fmt...) if (cdebug & (mask)) printf(fmt)
  17
  18 #define PRINTD          0x0001
  19 #define DEBUG_PARSE     0x0002
  20
  21 int cdebug = PRINTD;
  22
  23 extern int zconflex(void);
  24 static void zconfprint(const char *err, ...);
  25 static void zconf_error(const char *err, ...);
  26 static void zconferror(const char *err);
  27 static bool zconf_endtoken(const struct kconf_id *id, int starttoken, int endtoken);
  28
  29 struct symbol *symbol_hash[SYMBOL_HASHSIZE];
  30
  31 static struct menu *current_menu, *current_entry;
  32
  33 %}
  34 %expect 30
  35
  36 %union
  37 {
  38         char *string;
  39         struct file *file;
  40         struct symbol *symbol;
  41         struct expr *expr;
  42         struct menu *menu;
  43         const struct kconf_id *id;
  44 }
  45
  46 %token <id>T_MAINMENU
  47 %token <id>T_MENU
  48 %token <id>T_ENDMENU
  49 %token <id>T_SOURCE
  50 %token <id>T_CHOICE
  51 %token <id>T_ENDCHOICE
  52 %token <id>T_COMMENT
  53 %token <id>T_CONFIG
  54 %token <id>T_MENUCONFIG
  55 %token <id>T_HELP
  56 %token <string> T_HELPTEXT
  57 %token <id>T_IF
  58 %token <id>T_ENDIF
  59 %token <id>T_DEPENDS
  60 %token <id>T_OPTIONAL
  61 %token <id>T_PROMPT
  62 %token <id>T_TYPE
  63 %token <id>T_DEFAULT
  64 %token <id>T_SELECT
  65 %token <id>T_RANGE
  66 %token <id>T_VISIBLE
  67 %token <id>T_OPTION
  68 %token <id>T_ON
  69 %token <id>T_RESET
  70 %token <string> T_WORD
  71 %token <string> T_WORD_QUOTE
  72 %token T_UNEQUAL
  73 %token T_LESS
  74 %token T_LESS_EQUAL
  75 %token T_GREATER
  76 %token T_GREATER_EQUAL
  77 %token T_CLOSE_PAREN
  78 %token T_OPEN_PAREN
  79 %token T_EOL
  80
  81 %left T_OR
  82 %left T_AND
  83 %left T_EQUAL T_UNEQUAL
  84 %left T_LESS T_LESS_EQUAL T_GREATER T_GREATER_EQUAL
  85 %nonassoc T_NOT
  86
  87 %type <string> prompt
  88 %type <symbol> symbol
  89 %type <expr> expr
  90 %type <expr> if_expr
  91 %type <id> end
  92 %type <id> option_name
  93 %type <menu> if_entry menu_entry choice_entry
  94 %type <string> symbol_option_arg word_opt
  95
  96 %destructor {
  97         fprintf(stderr, "%s:%d: missing end statement for this entry\n",
  98                 $$->file->name, $$->lineno);
  99         if (current_menu == $$)
 100                 menu_end_menu();
 101 } if_entry menu_entry choice_entry
 102
 103 %{
 104 /* Include zconf.hash.c here so it can see the token constants. */
 105 #include "zconf.hash.c"
 106 %}
 107
 108 %%
 109 input: nl start | start;
 110
 111 start: mainmenu_stmt stmt_list | stmt_list;
 112
 113 stmt_list:
 114           /* empty */
 115         | stmt_list common_stmt
 116         | stmt_list choice_stmt
 117         | stmt_list menu_stmt
 118         | stmt_list end                 { zconf_error("unexpected end statement"); }
 119         | stmt_list T_WORD error T_EOL  { zconf_error("unknown statement \"%s\"", $2); }
 120         | stmt_list option_name error T_EOL
 121 {
 122         zconf_error("unexpected option \"%s\"", kconf_id_strings + $2->name);
 123 }
 124         | stmt_list error T_EOL         { zconf_error("invalid statement"); }
 125 ;
 126
 127 option_name:
 128         T_DEPENDS | T_PROMPT | T_TYPE | T_SELECT | T_OPTIONAL | T_RANGE | T_DEFAULT | T_VISIBLE | T_RESET
 129 ;
 130
 131 common_stmt:
 132           T_EOL
 133         | if_stmt
 134         | comment_stmt
 135         | config_stmt
 136         | menuconfig_stmt
 137         | source_stmt
 138 ;
 139
 140 option_error:
 141           T_WORD error T_EOL            { zconf_error("unknown option \"%s\"", $1); }
 142         | error T_EOL                   { zconf_error("invalid option"); }
 143 ;
 144
 145
 146 /* config/menuconfig entry */
 147
 148 config_entry_start: T_CONFIG T_WORD T_EOL
 149 {
 150         struct symbol *sym = sym_lookup($2, 0);
 151         sym->flags |= SYMBOL_OPTIONAL;
 152         menu_add_entry(sym);
 153         printd(DEBUG_PARSE, "%s:%d:config %s\n", zconf_curname(), zconf_lineno(), $2);
 154 };
 155
 156 config_stmt: config_entry_start config_option_list
 157 {
 158         menu_end_entry();
 159         printd(DEBUG_PARSE, "%s:%d:endconfig\n", zconf_curname(), zconf_lineno());
 160 };
 161
 162 menuconfig_entry_start: T_MENUCONFIG T_WORD T_EOL
 163 {
 164         struct symbol *sym = sym_lookup($2, 0);
 165         sym->flags |= SYMBOL_OPTIONAL;
 166         menu_add_entry(sym);
 167         printd(DEBUG_PARSE, "%s:%d:menuconfig %s\n", zconf_curname(), zconf_lineno(), $2);
 168 };
 169
 170 menuconfig_stmt: menuconfig_entry_start config_option_list
 171 {
 172         if (current_entry->prompt)
 173                 current_entry->prompt->type = P_MENU;
 174         else
 175                 zconfprint("warning: menuconfig statement without prompt");
 176         menu_end_entry();
 177         printd(DEBUG_PARSE, "%s:%d:endconfig\n", zconf_curname(), zconf_lineno());
 178 };
 179
 180 config_option_list:
 181           /* empty */
 182         | config_option_list config_option
 183         | config_option_list symbol_option
 184         | config_option_list depends
 185         | config_option_list help
 186         | config_option_list option_error
 187         | config_option_list T_EOL
 188 ;
 189
 190 config_option: T_TYPE prompt_stmt_opt T_EOL
 191 {
 192         menu_set_type($1->stype);
 193         printd(DEBUG_PARSE, "%s:%d:type(%u)\n",
 194                 zconf_curname(), zconf_lineno(),
 195                 $1->stype);
 196 };
 197
 198 config_option: T_PROMPT prompt if_expr T_EOL
 199 {
 200         menu_add_prompt(P_PROMPT, $2, $3);
 201         printd(DEBUG_PARSE, "%s:%d:prompt\n", zconf_curname(), zconf_lineno());
 202 };
 203
 204 config_option: T_DEFAULT expr if_expr T_EOL
 205 {
 206         menu_add_expr(P_DEFAULT, $2, $3);
 207         if ($1->stype != S_UNKNOWN)
 208                 menu_set_type($1->stype);
 209         printd(DEBUG_PARSE, "%s:%d:default(%u)\n",
 210                 zconf_curname(), zconf_lineno(),
 211                 $1->stype);
 212 };
 213
 214 config_option: T_SELECT T_WORD if_expr T_EOL
 215 {
 216         menu_add_symbol(P_SELECT, sym_lookup($2, 0), $3);
 217         printd(DEBUG_PARSE, "%s:%d:select\n", zconf_curname(), zconf_lineno());
 218 };
 219
 220 config_option: T_RANGE symbol symbol if_expr T_EOL
 221 {
 222         menu_add_expr(P_RANGE, expr_alloc_comp(E_RANGE,$2, $3), $4);
 223         printd(DEBUG_PARSE, "%s:%d:range\n", zconf_curname(), zconf_lineno());
 224 };
 225
 226 symbol_option: T_OPTION symbol_option_list T_EOL
 227 ;
 228
 229 symbol_option_list:
 230           /* empty */
 231         | symbol_option_list T_WORD symbol_option_arg
 232 {
 233         const struct kconf_id *id = kconf_id_lookup($2, strlen($2));
 234         if (id && id->flags & TF_OPTION)
 235                 menu_add_option(id->token, $3);
 236         else
 237                 zconfprint("warning: ignoring unknown option %s", $2);
 238         free($2);
 239 };
 240
 241 symbol_option_arg:
 242           /* empty */           { $$ = NULL; }
 243         | T_EQUAL prompt        { $$ = $2; }
 244 ;
 245
 246 /* choice entry */
 247
 248 choice: T_CHOICE word_opt T_EOL
 249 {
 250         struct symbol *sym = sym_lookup($2, SYMBOL_CHOICE);
 251         sym->flags |= SYMBOL_AUTO;
 252         menu_add_entry(sym);
 253         menu_add_expr(P_CHOICE, NULL, NULL);
 254         printd(DEBUG_PARSE, "%s:%d:choice\n", zconf_curname(), zconf_lineno());
 255 };
 256
 257 choice_entry: choice choice_option_list
 258 {
 259         $$ = menu_add_menu();
 260 };
 261
 262 choice_end: end
 263 {
 264         if (zconf_endtoken($1, T_CHOICE, T_ENDCHOICE)) {
 265                 menu_end_menu();
 266                 printd(DEBUG_PARSE, "%s:%d:endchoice\n", zconf_curname(), zconf_lineno());
 267         }
 268 };
 269
 270 choice_stmt: choice_entry choice_block choice_end
 271 ;
 272
 273 choice_option_list:
 274           /* empty */
 275         | choice_option_list choice_option
 276         | choice_option_list depends
 277         | choice_option_list help
 278         | choice_option_list T_EOL
 279         | choice_option_list option_error
 280 ;
 281
 282 choice_option: T_PROMPT prompt if_expr T_EOL
 283 {
 284         menu_add_prompt(P_PROMPT, $2, $3);
 285         printd(DEBUG_PARSE, "%s:%d:prompt\n", zconf_curname(), zconf_lineno());
 286 };
 287
 288 choice_option: T_TYPE prompt_stmt_opt T_EOL
 289 {
 290         if ($1->stype == S_BOOLEAN || $1->stype == S_TRISTATE) {
 291                 menu_set_type($1->stype);
 292                 printd(DEBUG_PARSE, "%s:%d:type(%u)\n",
 293                         zconf_curname(), zconf_lineno(),
 294                         $1->stype);
 295         } else
 296                 YYERROR;
 297 };
 298
 299 choice_option: T_OPTIONAL T_EOL
 300 {
 301         current_entry->sym->flags |= SYMBOL_OPTIONAL;
 302         printd(DEBUG_PARSE, "%s:%d:optional\n", zconf_curname(), zconf_lineno());
 303 };
 304
 305 choice_option: T_RESET if_expr T_EOL
 306 {
 307         menu_add_prop(P_RESET, NULL, NULL, $2);
 308 };
 309
 310 choice_option: T_DEFAULT T_WORD if_expr T_EOL
 311 {
 312         if ($1->stype == S_UNKNOWN) {
 313                 menu_add_symbol(P_DEFAULT, sym_lookup($2, 0), $3);
 314                 printd(DEBUG_PARSE, "%s:%d:default\n",
 315                         zconf_curname(), zconf_lineno());
 316         } else
 317                 YYERROR;
 318 };
 319
 320 choice_block:
 321           /* empty */
 322         | choice_block common_stmt
 323 ;
 324
 325 /* if entry */
 326
 327 if_entry: T_IF expr nl
 328 {
 329         printd(DEBUG_PARSE, "%s:%d:if\n", zconf_curname(), zconf_lineno());
 330         menu_add_entry(NULL);
 331         menu_add_dep($2);
 332         $$ = menu_add_menu();
 333 };
 334
 335 if_end: end
 336 {
 337         if (zconf_endtoken($1, T_IF, T_ENDIF)) {
 338                 menu_end_menu();
 339                 printd(DEBUG_PARSE, "%s:%d:endif\n", zconf_curname(), zconf_lineno());
 340         }
 341 };
 342
 343 if_stmt: if_entry if_block if_end
 344 ;
 345
 346 if_block:
 347           /* empty */
 348         | if_block common_stmt
 349         | if_block menu_stmt
 350         | if_block choice_stmt
 351 ;
 352
 353 /* mainmenu entry */
 354
 355 mainmenu_stmt: T_MAINMENU prompt nl
 356 {
 357         menu_add_prompt(P_MENU, $2, NULL);
 358 };
 359
 360 /* menu entry */
 361
 362 menu: T_MENU prompt T_EOL
 363 {
 364         menu_add_entry(NULL);
 365         menu_add_prompt(P_MENU, $2, NULL);
 366         printd(DEBUG_PARSE, "%s:%d:menu\n", zconf_curname(), zconf_lineno());
 367 };
 368
 369 menu_entry: menu visibility_list depends_list
 370 {
 371         $$ = menu_add_menu();
 372 };
 373
 374 menu_end: end
 375 {
 376         if (zconf_endtoken($1, T_MENU, T_ENDMENU)) {
 377                 menu_end_menu();
 378                 printd(DEBUG_PARSE, "%s:%d:endmenu\n", zconf_curname(), zconf_lineno());
 379         }
 380 };
 381
 382 menu_stmt: menu_entry menu_block menu_end
 383 ;
 384
 385 menu_block:
 386           /* empty */
 387         | menu_block common_stmt
 388         | menu_block menu_stmt
 389         | menu_block choice_stmt
 390 ;
 391
 392 source_stmt: T_SOURCE prompt T_EOL
 393 {
 394         printd(DEBUG_PARSE, "%s:%d:source %s\n", zconf_curname(), zconf_lineno(), $2);
 395         zconf_nextfile($2);
 396 };
 397
 398 /* comment entry */
 399
 400 comment: T_COMMENT prompt T_EOL
 401 {
 402         menu_add_entry(NULL);
 403         menu_add_prompt(P_COMMENT, $2, NULL);
 404         printd(DEBUG_PARSE, "%s:%d:comment\n", zconf_curname(), zconf_lineno());
 405 };
 406
 407 comment_stmt: comment depends_list
 408 {
 409         menu_end_entry();
 410 };
 411
 412 /* help option */
 413
 414 help_start: T_HELP T_EOL
 415 {
 416         printd(DEBUG_PARSE, "%s:%d:help\n", zconf_curname(), zconf_lineno());
 417         zconf_starthelp();
 418 };
 419
 420 help: help_start T_HELPTEXT
 421 {
 422         current_entry->help = $2;
 423 };
 424
 425 /* depends option */
 426
 427 depends_list:
 428           /* empty */
 429         | depends_list depends
 430         | depends_list T_EOL
 431         | depends_list option_error
 432 ;
 433
 434 depends: T_DEPENDS T_ON expr T_EOL
 435 {
 436         menu_add_dep($3);
 437         printd(DEBUG_PARSE, "%s:%d:depends on\n", zconf_curname(), zconf_lineno());
 438 } | T_DEPENDS expr T_EOL
 439 {
 440         menu_add_dep($2);
 441         zconfprint("warning: deprecated 'depends' syntax, use 'depends on' instead.");
 442 };
 443
 444 /* visibility option */
 445
 446 visibility_list:
 447           /* empty */
 448         | visibility_list visible
 449         | visibility_list T_EOL
 450 ;
 451
 452 visible: T_VISIBLE if_expr
 453 {
 454         menu_add_visibility($2);
 455 };
 456
 457 /* prompt statement */
 458
 459 prompt_stmt_opt:
 460           /* empty */
 461         | prompt if_expr
 462 {
 463         menu_add_prompt(P_PROMPT, $1, $2);
 464 };
 465
 466 prompt:   T_WORD
 467         | T_WORD_QUOTE
 468 ;
 469
 470 end:      T_ENDMENU T_EOL       { $$ = $1; }
 471         | T_ENDCHOICE T_EOL     { $$ = $1; }
 472         | T_ENDIF T_EOL         { $$ = $1; }
 473 ;
 474
 475 nl:
 476           T_EOL
 477         | nl T_EOL
 478 ;
 479
 480 if_expr:  /* empty */                   { $$ = NULL; }
 481         | T_IF expr                     { $$ = $2; }
 482 ;
 483
 484 expr:     symbol                                { $$ = expr_alloc_symbol($1); }
 485         | symbol T_LESS symbol                  { $$ = expr_alloc_comp(E_LTH, $1, $3); }
 486         | symbol T_LESS_EQUAL symbol            { $$ = expr_alloc_comp(E_LEQ, $1, $3); }
 487         | symbol T_GREATER symbol               { $$ = expr_alloc_comp(E_GTH, $1, $3); }
 488         | symbol T_GREATER_EQUAL symbol         { $$ = expr_alloc_comp(E_GEQ, $1, $3); }
 489         | symbol T_EQUAL symbol                 { $$ = expr_alloc_comp(E_EQUAL, $1, $3); }
 490         | symbol T_UNEQUAL symbol               { $$ = expr_alloc_comp(E_UNEQUAL, $1, $3); }
 491         | T_OPEN_PAREN expr T_CLOSE_PAREN       { $$ = $2; }
 492         | T_NOT expr                            { $$ = expr_alloc_one(E_NOT, $2); }
 493         | expr T_OR expr                        { $$ = expr_alloc_two(E_OR, $1, $3); }
 494         | expr T_AND expr                       { $$ = expr_alloc_two(E_AND, $1, $3); }
 495 ;
 496
 497 symbol:   T_WORD        { $$ = sym_lookup($1, 0); free($1); }
 498         | T_WORD_QUOTE  { $$ = sym_lookup($1, SYMBOL_CONST); free($1); }
 499 ;
 500
 501 word_opt: /* empty */                   { $$ = NULL; }
 502         | T_WORD
 503
 504 %%
 505
 506 void conf_parse(const char *name)
 507 {
 508         struct symbol *sym;
 509         int i;
 510
 511         zconf_initscan(name);
 512
 513         sym_init();
 514         _menu_init();
 515         rootmenu.prompt = menu_add_prompt(P_MENU, "Linux Kernel Configuration", NULL);
 516
 517 #if YYDEBUG
 518         if (getenv("ZCONF_DEBUG"))
 519                 zconfdebug = 1;
 520 #endif
 521         zconfparse();
 522         if (zconfnerrs)
 523                 exit(1);
 524         if (!modules_sym)
 525                 modules_sym = sym_find( "n" );
 526
 527         rootmenu.prompt->text = _(rootmenu.prompt->text);
 528         rootmenu.prompt->text = sym_expand_string_value(rootmenu.prompt->text);
 529
 530         menu_finalize(&rootmenu);
 531         for_all_symbols(i, sym) {
 532                 if (sym_check_deps(sym))
 533                         zconfnerrs++;
 534         }
 535         if (zconfnerrs)
 536                 exit(1);
 537         sym_set_change_count(1);
 538 }
 539
 540 static const char *zconf_tokenname(int token)
 541 {
 542         switch (token) {
 543         case T_MENU:            return "menu";
 544         case T_ENDMENU:         return "endmenu";
 545         case T_CHOICE:          return "choice";
 546         case T_ENDCHOICE:       return "endchoice";
 547         case T_IF:              return "if";
 548         case T_ENDIF:           return "endif";
 549         case T_DEPENDS:         return "depends";
 550         case T_VISIBLE:         return "visible";
 551         }
 552         return "<token>";
 553 }
 554
 555 static bool zconf_endtoken(const struct kconf_id *id, int starttoken, int endtoken)
 556 {
 557         if (id->token != endtoken) {
 558                 zconf_error("unexpected '%s' within %s block",
 559                         kconf_id_strings + id->name, zconf_tokenname(starttoken));
 560                 zconfnerrs++;
 561                 return false;
 562         }
 563         if (current_menu->file != current_file) {
 564                 zconf_error("'%s' in different file than '%s'",
 565                         kconf_id_strings + id->name, zconf_tokenname(starttoken));
 566                 fprintf(stderr, "%s:%d: location of the '%s'\n",
 567                         current_menu->file->name, current_menu->lineno,
 568                         zconf_tokenname(starttoken));
 569                 zconfnerrs++;
 570                 return false;
 571         }
 572         return true;
 573 }
 574
 575 static void zconfprint(const char *err, ...)
 576 {
 577         va_list ap;
 578
 579         fprintf(stderr, "%s:%d: ", zconf_curname(), zconf_lineno());
 580         va_start(ap, err);
 581         vfprintf(stderr, err, ap);
 582         va_end(ap);
 583         fprintf(stderr, "\n");
 584 }
 585
 586 static void zconf_error(const char *err, ...)
 587 {
 588         va_list ap;
 589
 590         zconfnerrs++;
 591         fprintf(stderr, "%s:%d: ", zconf_curname(), zconf_lineno());
 592         va_start(ap, err);
 593         vfprintf(stderr, err, ap);
 594         va_end(ap);
 595         fprintf(stderr, "\n");
 596 }
 597
 598 static void zconferror(const char *err)
 599 {
 600         fprintf(stderr, "%s:%d: %s\n", zconf_curname(), zconf_lineno() + 1, err);
 601 }
 602
 603 static void print_quoted_string(FILE *out, const char *str)
 604 {
 605         const char *p;
 606         int len;
 607
 608         putc('"', out);
 609         while ((p = strchr(str, '"'))) {
 610                 len = p - str;
 611                 if (len)
 612                         fprintf(out, "%.*s", len, str);
 613                 fputs("\\\"", out);
 614                 str = p + 1;
 615         }
 616         fputs(str, out);
 617         putc('"', out);
 618 }
 619
 620 static void print_symbol(FILE *out, struct menu *menu)
 621 {
 622         struct symbol *sym = menu->sym;
 623         struct property *prop;
 624
 625         if (sym_is_choice(sym))
 626                 fprintf(out, "\nchoice\n");
 627         else
 628                 fprintf(out, "\nconfig %s\n", sym->name);
 629         switch (sym->type) {
 630         case S_BOOLEAN:
 631                 fputs("  boolean\n", out);
 632                 break;
 633         case S_TRISTATE:
 634                 fputs("  tristate\n", out);
 635                 break;
 636         case S_STRING:
 637                 fputs("  string\n", out);
 638                 break;
 639         case S_INT:
 640                 fputs("  integer\n", out);
 641                 break;
 642         case S_HEX:
 643                 fputs("  hex\n", out);
 644                 break;
 645         default:
 646                 fputs("  ???\n", out);
 647                 break;
 648         }
 649         for (prop = sym->prop; prop; prop = prop->next) {
 650                 if (prop->menu != menu)
 651                         continue;
 652                 switch (prop->type) {
 653                 case P_PROMPT:
 654                         fputs("  prompt ", out);
 655                         print_quoted_string(out, prop->text);
 656                         if (!expr_is_yes(prop->visible.expr)) {
 657                                 fputs(" if ", out);
 658                                 expr_fprint(prop->visible.expr, out);
 659                         }
 660                         fputc('\n', out);
 661                         break;
 662                 case P_DEFAULT:
 663                         fputs( "  default ", out);
 664                         expr_fprint(prop->expr, out);
 665                         if (!expr_is_yes(prop->visible.expr)) {
 666                                 fputs(" if ", out);
 667                                 expr_fprint(prop->visible.expr, out);
 668                         }
 669                         fputc('\n', out);
 670                         break;
 671                 case P_CHOICE:
 672                         fputs("  #choice value\n", out);
 673                         break;
 674                 case P_SELECT:
 675                         fputs( "  select ", out);
 676                         expr_fprint(prop->expr, out);
 677                         fputc('\n', out);
 678                         break;
 679                 case P_RANGE:
 680                         fputs( "  range ", out);
 681                         expr_fprint(prop->expr, out);
 682                         fputc('\n', out);
 683                         break;
 684                 case P_MENU:
 685                         fputs( "  menu ", out);
 686                         print_quoted_string(out, prop->text);
 687                         fputc('\n', out);
 688                         break;
 689                 default:
 690                         fprintf(out, "  unknown prop %d!\n", prop->type);
 691                         break;
 692                 }
 693         }
 694         if (menu->help) {
 695                 int len = strlen(menu->help);
 696                 while (menu->help[--len] == '\n')
 697                         menu->help[len] = 0;
 698                 fprintf(out, "  help\n%s\n", menu->help);
 699         }
 700 }
 701
 702 void zconfdump(FILE *out)
 703 {
 704         struct property *prop;
 705         struct symbol *sym;
 706         struct menu *menu;
 707
 708         menu = rootmenu.list;
 709         while (menu) {
 710                 if ((sym = menu->sym))
 711                         print_symbol(out, menu);
 712                 else if ((prop = menu->prompt)) {
 713                         switch (prop->type) {
 714                         case P_COMMENT:
 715                                 fputs("\ncomment ", out);
 716                                 print_quoted_string(out, prop->text);
 717                                 fputs("\n", out);
 718                                 break;
 719                         case P_MENU:
 720                                 fputs("\nmenu ", out);
 721                                 print_quoted_string(out, prop->text);
 722                                 fputs("\n", out);
 723                                 break;
 724                         default:
 725                                 ;
 726                         }
 727                         if (!expr_is_yes(prop->visible.expr)) {
 728                                 fputs("  depends ", out);
 729                                 expr_fprint(prop->visible.expr, out);
 730                                 fputc('\n', out);
 731                         }
 732                 }
 733
 734                 if (menu->list)
 735                         menu = menu->list;
 736                 else if (menu->next)
 737                         menu = menu->next;
 738                 else while ((menu = menu->parent)) {
 739                         if (menu->prompt && menu->prompt->type == P_MENU)
 740                                 fputs("\nendmenu\n", out);
 741                         if (menu->next) {
 742                                 menu = menu->next;
 743                                 break;
 744                         }
 745                 }
 746         }
 747 }
 748
 749 #include "zconf.lex.c"
 750 #include "util.c"
 751 #include "confdata.c"
 752 #include "expr.c"
 753 #include "symbol.c"
 754 #include "menu.c"