scripts/feeds

   1 #!/usr/bin/env perl
   2 use Getopt::Std;
   3 use FindBin;
   4 use Cwd;
   5 use lib "$FindBin::Bin";
   6 use metadata;
   7 use warnings;
   8 use strict;
   9 use Cwd 'abs_path';
  10
  11 chdir "$FindBin::Bin/..";
  12 $ENV{TOPDIR} //= getcwd();
  13 chdir $ENV{TOPDIR};
  14 $ENV{GIT_CONFIG_PARAMETERS}="'core.autocrlf=false'";
  15 $ENV{GREP_OPTIONS}="";
  16
  17 my $mk=`which gmake 2>/dev/null`;       # select the right 'make' program
  18 chomp($mk);             # trim trailing newline
  19 $mk or $mk = "make";    # default to 'make'
  20
  21 # check version of make
  22 my @mkver = split /\s+/, `$mk -v`, 4;
  23 my $valid_mk = 1;
  24 $mkver[0] =~ /^GNU/ or $valid_mk = 0;
  25 $mkver[1] =~ /^Make/ or $valid_mk = 0;
  26
  27 my ($mkv1, $mkv2) = split /\./, $mkver[2];
  28 ($mkv1 >= 4 || ($mkv1 == 3 && $mkv2 >= 81)) or $valid_mk = 0;
  29
  30 $valid_mk or die "Unsupported version of make found: $mk\n";
  31
  32 my @feeds;
  33 my %build_packages;
  34 my %installed;
  35 my %installed_targets;
  36 my %feed_cache;
  37
  38 my $feed_package = {};
  39 my $feed_src = {};
  40 my $feed_target = {};
  41
  42 sub parse_config() {
  43         my $line = 0;
  44         my %name;
  45
  46         open FEEDS, "feeds.conf" or
  47                 open FEEDS, "feeds.conf.default" or
  48                 die "Unable to open feeds configuration";
  49         while (<FEEDS>) {
  50                 chomp;
  51                 s/#.+$//;
  52                 next unless /\S/;
  53                 my @line = split /\s+/, $_, 3;
  54                 my @src;
  55                 $line++;
  56
  57                 my $valid = 1;
  58                 $line[0] =~ /^src-[\w-]+$/ or $valid = 0;
  59                 $line[1] =~ /^\w+$/ or $valid = 0;
  60                 @src = split /\s+/, $line[2];
  61                 $valid or die "Syntax error in feeds.conf, line: $line\n";
  62
  63                 $name{$line[1]} and die "Duplicate feed name '$line[1]', line: $line\n";
  64                 $name{$line[1]} = 1;
  65
  66                 push @feeds, [$line[0], $line[1], \@src];
  67         }
  68         close FEEDS;
  69 }
  70
  71 sub update_location($$)
  72 {
  73         my $name = shift;
  74         my $url  = shift;
  75         my $old_url;
  76
  77         -d "./feeds/$name.tmp" or mkdir "./feeds/$name.tmp" or return 1;
  78
  79         if( open LOC, "< ./feeds/$name.tmp/location" )
  80         {
  81                 chomp($old_url = readline LOC);
  82                 close LOC;
  83         }
  84
  85         if( !$old_url || $old_url ne $url )
  86         {
  87                 if( open LOC, "> ./feeds/$name.tmp/location" )
  88                 {
  89                         print LOC $url, "\n";
  90                         close LOC;
  91                 }
  92                 return $old_url ? 1 : 0;
  93         }
  94
  95         return 0;
  96 }
  97
  98 sub update_index($)
  99 {
 100         my $name = shift;
 101
 102         -d "./feeds/$name.tmp" or mkdir "./feeds/$name.tmp" or return 1;
 103         -d "./feeds/$name.tmp/info" or mkdir "./feeds/$name.tmp/info" or return 1;
 104
 105         system("$mk -s prepare-mk OPENWRT_BUILD= TMP_DIR=\"$ENV{TOPDIR}/feeds/$name.tmp\"");
 106         system("$mk -s -f include/scan.mk IS_TTY=1 SCAN_TARGET=\"packageinfo\" SCAN_DIR=\"feeds/$name\" SCAN_NAME=\"package\" SCAN_DEPS=\"$ENV{TOPDIR}/include/package*.mk\" SCAN_DEPTH=5 SCAN_EXTRA=\"\" TMP_DIR=\"$ENV{TOPDIR}/feeds/$name.tmp\"");
 107         system("$mk -s -f include/scan.mk IS_TTY=1 SCAN_TARGET=\"targetinfo\" SCAN_DIR=\"feeds/$name\" SCAN_NAME=\"target\" SCAN_DEPS=\"profiles/*.mk $ENV{TOPDIR}/include/target.mk\" SCAN_DEPTH=5 SCAN_EXTRA=\"\" SCAN_MAKEOPTS=\"TARGET_BUILD=1\" TMP_DIR=\"$ENV{TOPDIR}/feeds/$name.tmp\"");
 108         system("ln -sf $name.tmp/.packageinfo ./feeds/$name.index");
 109         system("ln -sf $name.tmp/.targetinfo ./feeds/$name.targetindex");
 110
 111         return 0;
 112 }
 113
 114 my %update_method = (
 115         'src-svn' => {
 116                 'init'          => "svn checkout '%s' '%s'",
 117                 'update'        => "svn update",
 118                 'controldir'    => ".svn",
 119                 'revision'      => "svn info | grep 'Revision' | cut -d ' ' -f 2 | tr -d '\n'"},
 120         'src-cpy' => {
 121                 'init'          => "cp -Rf '%s' '%s'",
 122                 'update'        => "",
 123                 'revision'      => "echo -n 'local'"},
 124         'src-link' => {
 125                 'init'          => "ln -s '%s' '%s'",
 126                 'update'        => "",
 127                 'revision'      => "echo -n 'local'"},
 128         'src-git' => {
 129                 'init'          => "git clone --depth 1 '%s' '%s'",
 130                 'init_branch'   => "git clone --depth 1 --branch '%s' '%s' '%s'",
 131                 'init_commit'   => "git clone '%s' '%s' && cd '%s' && git checkout -b '%s' '%s' && cd -",
 132                 'update'        => "git pull --ff",
 133                 'update_force'  => "git pull --ff || (git reset --hard HEAD; git pull --ff; exit 1)",
 134                 'controldir'    => ".git",
 135                 'revision'      => "git rev-parse --short HEAD | tr -d '\n'"},
 136         'src-git-full' => {
 137                 'init'          => "git clone '%s' '%s'",
 138                 'init_branch'   => "git clone --branch '%s' '%s' '%s'",
 139                 'init_commit'   => "git clone '%s' '%s' && cd '%s' && git checkout -b '%s' '%s' && cd -",
 140                 'update'        => "git pull --ff",
 141                 'update_force'  => "git pull --ff || (git reset --hard HEAD; git pull --ff; exit 1)",
 142                 'controldir'    => ".git",
 143                 'revision'      => "git rev-parse --short HEAD | tr -d '\n'"},
 144         'src-gitsvn' => {
 145                 'init'  => "git svn clone -r HEAD '%s' '%s'",
 146                 'update'        => "git svn rebase",
 147                 'controldir'    => ".git",
 148                 'revision'      => "git rev-parse --short HEAD | tr -d '\n'"},
 149         'src-bzr' => {
 150                 'init'          => "bzr checkout --lightweight '%s' '%s'",
 151                 'update'        => "bzr update",
 152                 'controldir'    => ".bzr"},
 153         'src-hg' => {
 154                 'init'          => "hg clone '%s' '%s'",
 155                 'update'        => "hg pull --update",
 156                 'controldir'    => ".hg"},
 157         'src-darcs' => {
 158                 'init'    => "darcs get '%s' '%s'",
 159                 'update'  => "darcs pull -a",
 160                 'controldir' => "_darcs"},
 161 );
 162
 163 # src-git: pull broken
 164 # src-cpy: broken if `basename $src` != $name
 165
 166 sub update_feed_via($$$$$) {
 167         my $type = shift;
 168         my $name = shift;
 169         my $src = shift;
 170         my $relocate = shift;
 171         my $force = shift;
 172
 173         my $m = $update_method{$type};
 174         my $localpath = "./feeds/$name";
 175         my $safepath = $localpath;
 176         $safepath =~ s/'/'\\''/;
 177         my ($base_branch, $branch) = split(/;/, $src, 2);
 178         my ($base_commit, $commit) = split(/\^/, $src, 2);
 179
 180         if( $relocate || !$m->{'update'} || !-d "$localpath/$m->{'controldir'}" ) {
 181                 system("rm -rf '$safepath'");
 182                 if ($m->{'init_branch'} and $branch) {
 183                         system(sprintf($m->{'init_branch'}, $branch, $base_branch, $safepath)) == 0 or return 1;
 184                 } elsif ($m->{'init_commit'} and $commit) {
 185                         system(sprintf($m->{'init_commit'}, $base_commit, $safepath, $safepath, $commit, $commit)) == 0 or return 1;
 186                 } else {
 187                         system(sprintf($m->{'init'}, $src, $safepath)) == 0 or return 1;
 188                 }
 189         } elsif ($m->{'init_commit'} and $commit) {
 190                 # in case git hash has been provided don't update the feed
 191         } else {
 192                 my $update_cmd = $m->{'update'};
 193                 if ($force && exists $m->{'update_force'}) {
 194                         $update_cmd = $m->{'update_force'};
 195                 }
 196                 system("cd '$safepath'; $update_cmd") == 0 or return 1;
 197         }
 198
 199         return 0;
 200 }
 201
 202 sub get_targets($) {
 203         my $file = shift;
 204         my @target = parse_target_metadata($file);
 205         my %target;
 206         foreach my $target (@target) {
 207                 $target{$target->{id}} = $target;
 208         }
 209         return %target
 210 }
 211
 212 sub get_feed($) {
 213         my $feed = shift;
 214
 215         if (!defined($feed_cache{$feed})) {
 216                 my $file = "./feeds/$feed.index";
 217
 218                 clear_packages();
 219                 -f $file or do {
 220                         print "Ignoring feed '$feed' - index missing\n";
 221                         return;
 222                 };
 223                 parse_package_metadata($file) or return;
 224                 my %target = get_targets("./feeds/$feed.targetindex");
 225
 226                 $feed_cache{$feed} = [ { %package }, { %srcpackage }, { %target } ];
 227         }
 228
 229         $feed_package = $feed_cache{$feed}->[0];
 230         $feed_src = $feed_cache{$feed}->[1];
 231         $feed_target = $feed_cache{$feed}->[2];
 232         return $feed_cache{$feed}->[0];
 233 }
 234
 235 sub get_installed() {
 236         system("$mk -s prepare-tmpinfo OPENWRT_BUILD=");
 237         clear_packages();
 238         parse_package_metadata("./tmp/.packageinfo");
 239         %installed = %package;
 240         %installed_targets = get_targets("./tmp/.targetinfo");
 241 }
 242
 243 sub search_feed {
 244         my $feed = shift;
 245         my @substr = @_;
 246         my $display;
 247
 248         return unless @substr > 0;
 249         get_feed($feed);
 250         foreach my $name (sort { lc($a) cmp lc($b) } keys %$feed_package) {
 251                 my $pkg = $feed_package->{$name};
 252                 my $substr;
 253                 my $pkgmatch = 1;
 254
 255                 foreach my $substr (@substr) {
 256                         my $match;
 257                         foreach my $key (qw(name title description src)) {
 258                                 $pkg->{$key} and $substr and $pkg->{$key} =~ m/$substr/i and $match = 1;
 259                         }
 260                         $match or undef $pkgmatch;
 261                 };
 262                 $pkgmatch and do {
 263                         $display or do {
 264                                 print "Search results in feed '$feed':\n";
 265                                 $display = 1;
 266                         };
 267                         printf "\%-25s\t\%s\n", $pkg->{name}, $pkg->{title};
 268                 };
 269         }
 270
 271         foreach my $name (sort { lc($a) cmp lc($b) } keys %$feed_target) {
 272                 my $target = $feed_target->{$name};
 273                 my $targetmatch = 1;
 274
 275                 foreach my $substr (@substr) {
 276                         my $match;
 277                         foreach my $key (qw(id name description)) {
 278                                 $target->{$key} and $substr and $target->{$key} =~ m/$substr/i and $match = 1;
 279                         }
 280                         $match or undef $targetmatch;
 281                 };
 282                 $targetmatch and do {
 283                         $display or do {
 284                                 print "Search results in feed '$feed':\n";
 285                                 $display = 1;
 286                         };
 287                         printf "TARGET: \%-17s\t\%s\n", $target->{id}, $target->{name};
 288                 };
 289         }
 290         return 0;
 291 }
 292
 293 sub search {
 294         my %opts;
 295
 296         getopt('r:', \%opts);
 297         foreach my $feed (@feeds) {
 298                 search_feed($feed->[1], @ARGV) if (!defined($opts{r}) or $opts{r} eq $feed->[1]);
 299         }
 300 }
 301
 302 sub list_feed {
 303         my $feed = shift;
 304
 305         get_feed($feed);
 306         foreach my $name (sort { lc($a) cmp lc($b) } keys %$feed_package) {
 307                 my $pkg = $feed_package->{$name};
 308                 if($pkg->{name}) {
 309                         printf "\%-32s\t\%s\n", $pkg->{name}, $pkg->{title};
 310                 }
 311         }
 312
 313         foreach my $name (sort { lc($a) cmp lc($b) } keys %$feed_target) {
 314                 my $target = $feed_target->{$name};
 315                 if($target->{name}) {
 316                         printf "TARGET: \%-24s\t\%s\n", $target->{id}, $target->{name};
 317                 }
 318         }
 319
 320         return 0;
 321 }
 322
 323 sub list {
 324         my %opts;
 325
 326         getopts('r:d:nshf', \%opts);
 327         if ($opts{h}) {
 328                 usage();
 329                 return 0;
 330         }
 331         if ($opts{n}) {
 332                 foreach my $feed (@feeds) {
 333                         printf "%s\n", $feed->[1];
 334                 }
 335                 return 0;
 336         }
 337         if ($opts{s}) {
 338                 foreach my $feed (@feeds) {
 339                         my $localpath = "./feeds/$feed->[1]";
 340                         my $m = $update_method{$feed->[0]};
 341                         my $revision;
 342                         if (!-d "$localpath" || !$m->{'revision'}) {
 343                                 $revision = "X";
 344                         }
 345                         elsif( $m->{'controldir'} && -d "$localpath/$m->{'controldir'}" ) {
 346                                 $revision = `cd '$localpath'; $m->{'revision'}`;
 347                         }
 348                         else {
 349                                 $revision = "local";
 350                         }
 351                         if ($opts{d}) {
 352                                 printf "%s%s%s%s%s%s%s\n", $feed->[1], $opts{d}, $feed->[0], $opts{d}, $revision, $opts{d}, join(", ", @{$feed->[2]});
 353                         }
 354                         elsif ($opts{f}) {
 355                                 my $uri = join(", ", @{$feed->[2]});
 356                                 if ($revision ne "local" && $revision ne "X") {
 357                                         $uri =~ s/[;^].*//;
 358                                         $uri .= "^" . $revision;
 359                                 }
 360                                 printf "%s %s %s\n", $feed->[0], $feed->[1], $uri;
 361                         }
 362                         else {
 363                                 printf "\%-10s \%-8s \%-8s \%s\n", $feed->[1], $feed->[0], $revision, join(", ", @{$feed->[2]});
 364                         }
 365                 }
 366                 return 0;
 367         }
 368         foreach my $feed (@feeds) {
 369                 list_feed($feed->[1], @ARGV) if (!defined($opts{r}) or $opts{r} eq $feed->[1]);
 370         }
 371         return 0;
 372 }
 373
 374 # TODO: do_install_package etc. should deal with source packages rather
 375 # than binary packages
 376 sub do_install_package($$) {
 377         my $feed = shift;
 378         my $pkg = shift;
 379
 380         my $path;
 381         $pkg->{src} and $path = $pkg->{src}{makefile};
 382
 383         if($path) {
 384                 $path =~ s/\/Makefile$//;
 385
 386                 -d "./package/feeds" or mkdir "./package/feeds";
 387                 -d "./package/feeds/$feed->[1]" or mkdir "./package/feeds/$feed->[1]";
 388                 system("ln -sf ../../../$path ./package/feeds/$feed->[1]/");
 389         } else {
 390                 warn "Package is not valid\n";
 391                 return 1;
 392         }
 393
 394         return 0;
 395 }
 396
 397 sub do_install_target($) {
 398         my $target = shift;
 399         my $path = $target->{makefile};
 400
 401         if ($path) {
 402                 $path =~ s/\/Makefile$//;
 403                 my $name = $path;
 404                 $name =~ s/.*\///;
 405                 my $dest = "./target/linux/$name";
 406
 407                 -e $dest and do {
 408                         warn "Path $dest already exists";
 409                         return 1;
 410                 };
 411
 412                 system("ln -sf ../../$path ./target/linux/");
 413         } else {
 414                 warn "Target is not valid\n";
 415                 return 1;
 416         }
 417
 418         return 0;
 419 }
 420
 421 sub lookup_package($$) {
 422         my $feed = shift;
 423         my $package = shift;
 424
 425         foreach my $feed ($feed, @feeds) {
 426                 next unless $feed->[1];
 427                 next unless $feed_cache{$feed->[1]};
 428                 $feed_cache{$feed->[1]}->[0]->{$package} and return $feed;
 429         }
 430         return;
 431 }
 432
 433 sub lookup_target($$) {
 434         my $feed = shift;
 435         my $target = shift;
 436
 437         foreach my $feed ($feed, @feeds) {
 438                 next unless $feed->[1];
 439                 next unless $feed_cache{$feed->[1]};
 440                 $feed_cache{$feed->[1]}->[2]->{$target} and return $feed;
 441         }
 442         return;
 443 }
 444
 445 sub is_core_package($) {
 446         my $package = shift;
 447         foreach my $file ("tmp/info/.packageinfo-$package", glob("tmp/info/.packageinfo-*_$package")) {
 448                 next unless index($file, "tmp/info/.packageinfo-feeds_");
 449                 return 1 if -s $file;
 450         }
 451         return 0;
 452 }
 453
 454 sub install_target {
 455         my $feed = shift;
 456         my $name = shift;
 457
 458         $feed = $feed_cache{$feed->[1]}->[2];
 459         $feed or return 0;
 460
 461         my $target = $feed->{$name};
 462         $target or return 0;
 463
 464         warn "Installing target '$name'\n";
 465         return do_install_target($target);
 466 }
 467
 468 sub install_package {
 469         my $feed = shift;
 470         my $name = shift;
 471         my $force = shift;
 472         my $ret = 0;
 473
 474         my $this_feed_target = lookup_target($feed, $name);
 475         $this_feed_target and do {
 476                 $installed_targets{$name} and return 0;
 477                 install_target($this_feed_target, $name);
 478                 return 0;
 479         };
 480
 481         $feed = lookup_package($feed, $name);
 482         $feed or do {
 483                 $installed{$name} and return 0;
 484                 # TODO: check if it's already installed within ./package directory
 485                 $feed_src->{$name} or is_core_package($name) or warn "WARNING: No feed for package '$name' found, maybe it's already part of the standard packages?\n";
 486                 return 0;
 487         };
 488
 489         # switch to the metadata for the selected feed
 490         my $cur = get_feed($feed->[1]);
 491
 492         my $pkg = $cur->{$name} or return 1;
 493         $pkg->{name} or do {
 494                 $installed{$name} and return 0;
 495                 # TODO: check if this is an alias package, maybe it's known by another name
 496                 warn "WARNING: Package '$name' is not available in feed $feed->[1].\n";
 497                 return 0;
 498         };
 499         my $src = $pkg->{src}{name};
 500         my $type = $feed->[0];
 501         $src or $src = $name;
 502
 503         # If it's a core package and we don't want to override, just return
 504         !$force and is_core_package($src) and return 0;
 505
 506         # previously installed packages set the runtime package
 507         # newly installed packages set the source package to 1
 508         $installed{$src} and $installed{$src} == 1 and return 0;
 509
 510         # we'll trigger the override only with the 3 conditions below:
 511         # - override is allowed by command line (-f)
 512         # - a package with the same src exists in the core packages list
 513         # - the package previously installed is not from a feed
 514         my $override = 1 if ($force and is_core_package($src) and !$installed{$name}->{feed});
 515
 516         # check previously installed packages
 517         $installed{$name} and !$override and return 0;
 518         $installed{$src} = 1;
 519
 520         defined($override) and $override == 1
 521                 and warn "Overriding core package '$src' with version from $feed->[1]\n"
 522                 or warn "Installing package '$src' from $feed->[1]\n";
 523
 524         do_install_package($feed, $pkg) == 0 or do {
 525                 warn "failed.\n";
 526                 return 1;
 527         };
 528
 529         # install all dependencies referenced from the source package
 530         foreach my $dep (
 531                 @{$feed_src->{$src}{builddepends}},
 532                 @{$feed_src->{$src}{"builddepends/host"}},
 533                 map { @{$_->{depends}} } @{$feed_src->{$src}{packages}}
 534         ) {
 535                 # TODO: handle virtual packages and PROVIDES
 536                 next if $dep =~ /@/;
 537                 $dep =~ s/^\+//;
 538                 $dep =~ s/^.+://;
 539                 $dep =~ s/\/.+$//;
 540                 next unless $dep;
 541                 install_package($feed, $dep, 0) == 0 or $ret = 1;
 542         }
 543
 544         return $ret;
 545 }
 546
 547 sub refresh_config {
 548         my $default = shift;
 549
 550         # Don't create .config if it doesn't already exist so that making a
 551         # config only occurs when the user intends it do (however we do
 552         # want to refresh an existing config).
 553         return if not (-e '.config');
 554
 555         # workaround for timestamp check
 556         system("rm -f tmp/.packageinfo");
 557
 558         # refresh the config
 559         if ($default) {
 560                 system("$mk oldconfig CONFDEFAULT=\"$default\" Config.in >/dev/null 2>/dev/null");
 561         } else {
 562                 system("$mk defconfig Config.in >/dev/null 2>/dev/null");
 563         }
 564 }
 565
 566 sub install {
 567         my $name;
 568         my %opts;
 569         my $feed;
 570         my $ret = 0;
 571
 572         getopts('ap:d:fh', \%opts);
 573
 574         if ($opts{h}) {
 575                 usage();
 576                 return 0;
 577         }
 578
 579         get_installed();
 580
 581         foreach my $f (@feeds) {
 582                 # fetch all feeds
 583                 get_feed($f->[1]);
 584
 585                 # look up the preferred feed
 586                 $opts{p} and $f->[1] eq $opts{p} and $feed = $f;
 587         }
 588
 589         if($opts{a}) {
 590                 foreach my $f (@feeds) {
 591                         if (!defined($opts{p}) or $opts{p} eq $f->[1]) {
 592                                 printf "Installing all packages from feed %s.\n", $f->[1];
 593                                 get_feed($f->[1]);
 594                                 foreach my $name (sort { lc($a) cmp lc($b) } keys %$feed_package) {
 595                                         my $p = $feed_package->{$name};
 596                                         if( $p->{name} ) {
 597                                                 install_package($feed, $p->{name}, exists($opts{f})) == 0 or $ret = 1;
 598                                                 get_feed($f->[1]);
 599                                         }
 600                                 }
 601                         }
 602                 }
 603         } else {
 604                 while ($name = shift @ARGV) {
 605                         install_package($feed, $name, exists($opts{f})) == 0 or $ret = 1;
 606                 }
 607         }
 608
 609         # workaround for timestamp check
 610
 611         # set the defaults
 612         if ($opts{d} and $opts{d} =~ /^[ymn]$/) {
 613                 refresh_config($opts{d});
 614         }
 615
 616         return $ret;
 617 }
 618
 619 sub uninstall_target($) {
 620         my $dir = shift;
 621         my $name = $dir;
 622         $name =~ s/.*\///g;
 623
 624         my $dest = readlink $dir;
 625         return unless $dest =~ /..\/..\/feeds/;
 626         warn "Uninstalling target '$name'\n";
 627         unlink "$dir";
 628 }
 629
 630 sub uninstall {
 631         my %opts;
 632         my $name;
 633         my $uninstall;
 634
 635         getopts('ah', \%opts);
 636
 637         if ($opts{h}) {
 638                 usage();
 639                 return 0;
 640         }
 641
 642         if ($opts{a}) {
 643                 system("rm -rvf ./package/feeds");
 644                 foreach my $dir (glob "target/linux/*") {
 645                         next unless -l $dir;
 646                         uninstall_target($dir);
 647                 }
 648                 $uninstall = 1;
 649         } else {
 650                 if($#ARGV == -1) {
 651                         warn "WARNING: no package to uninstall\n";
 652                         return 0;
 653                 }
 654                 get_installed();
 655                 while ($name = shift @ARGV) {
 656                         my $target = "target/linux/$name";
 657                         -l "$target" and do {
 658                                 uninstall_target($target);
 659                                 $uninstall = 1;
 660                                 next;
 661                         };
 662
 663                         my $pkg = $installed{$name};
 664                         $pkg or do {
 665                                 warn "WARNING: $name not installed\n";
 666                                 next;
 667                         };
 668                         $pkg->{src} and $name = $pkg->{src}{name};
 669                         warn "Uninstalling package '$name'\n";
 670                         system("rm -f ./package/feeds/*/$name");
 671                         $uninstall = 1;
 672                 }
 673         }
 674         $uninstall and refresh_config();
 675         return 0;
 676 }
 677
 678 sub update_feed($$$$$)
 679 {
 680         my $type=shift;
 681         my $name=shift;
 682         my $src=shift;
 683         my $perform_update=shift;
 684         my $force_update=shift;
 685         my $force_relocate=update_location( $name, "@$src" );
 686         my $rv=0;
 687
 688         if( $force_relocate ) {
 689                 warn "Source of feed $name has changed, replacing copy\n";
 690         }
 691         $update_method{$type} or do {
 692                 warn "Unknown type '$type' in feed $name\n";
 693                 return 1;
 694         };
 695         $perform_update and do {
 696                 my $failed = 1;
 697                 foreach my $feedsrc (@$src) {
 698                         warn "Updating feed '$name' from '$feedsrc' ...\n";
 699                         if (update_feed_via($type, $name, $feedsrc, $force_relocate, $force_update) != 0) {
 700                                 if ($force_update) {
 701                                         $rv=1;
 702                                         $failed=0;
 703                                         warn "failed, ignore.\n";
 704                                         next;
 705                                 }
 706                                 last;
 707                         }
 708                         $failed = 0;
 709                 }
 710                 $failed and do {
 711                         warn "failed.\n";
 712                         return 1;
 713                 };
 714         };
 715         warn "Create index file './feeds/$name.index' \n";
 716         update_index($name) == 0 or do {
 717                 warn "failed.\n";
 718                 return 1;
 719         };
 720         return $rv;
 721 }
 722
 723 sub update {
 724         my %opts;
 725         my $feed_name;
 726         my $perform_update=1;
 727         my $failed=0;
 728
 729         $ENV{SCAN_COOKIE} = $$;
 730         $ENV{OPENWRT_VERBOSE} = 's';
 731
 732         getopts('ahif', \%opts);
 733
 734         if ($opts{h}) {
 735                 usage();
 736                 return 0;
 737         }
 738
 739         if ($opts{i}) {
 740                 # don't update from (remote) repository
 741                 # only re-create index information
 742                 $perform_update=0;
 743         }
 744
 745         -d "feeds" or do {
 746                         mkdir "feeds" or die "Unable to create the feeds directory";
 747                 };
 748
 749         if ( ($#ARGV == -1) or $opts{a}) {
 750                 foreach my $feed (@feeds) {
 751                         my ($type, $name, $src) = @$feed;
 752                         update_feed($type, $name, $src, $perform_update, $opts{f}) == 0 or $failed=1;
 753                 }
 754         } else {
 755                 while ($feed_name = shift @ARGV) {
 756                         foreach my $feed (@feeds) {
 757                                 my ($type, $name, $src) = @$feed;
 758                                 if($feed_name ne $name) {
 759                                         next;
 760                                 }
 761                                 update_feed($type, $name, $src, $perform_update, $opts{f}) == 0 or $failed=1;
 762                         }
 763                 }
 764         }
 765
 766         refresh_config();
 767
 768         return $failed;
 769 }
 770
 771 sub feed_config() {
 772         foreach my $feed (@feeds) {
 773                 my $installed = (-f "feeds/$feed->[1].index");
 774
 775                 printf "\tconfig FEED_%s\n", $feed->[1];
 776                 printf "\t\tbool \"Enable feed %s\"\n", $feed->[1];
 777                 printf "\t\tdepends on PER_FEED_REPO\n";
 778                 printf "\t\tdefault y\n" if $installed;
 779                 printf "\t\thelp\n";
 780                 printf "\t\t Enable the \\\"%s\\\" feed at %s.\n", $feed->[1], $feed->[2][0];
 781                 printf "\n";
 782         }
 783
 784         return 0;
 785 }
 786
 787 sub usage() {
 788         print <<EOF;
 789 Usage: $0 <command> [options]
 790
 791 Commands:
 792         list [options]: List feeds, their content and revisions (if installed)
 793         Options:
 794             -n :            List of feed names.
 795             -s :            List of feed names and their URL.
 796             -r <feedname>:  List packages of specified feed.
 797             -d <delimiter>: Use specified delimiter to distinguish rows (default: spaces)
 798             -f :            List feeds in feeds.conf compatible format (when using -s).
 799
 800         install [options] <package>: Install a package
 801         Options:
 802             -a :           Install all packages from all feeds or from the specified feed using the -p option.
 803             -p <feedname>: Prefer this feed when installing packages.
 804             -d <y|m|n>:    Set default for newly installed packages.
 805             -f :           Install will be forced even if the package exists in core OpenWrt (override)
 806
 807         search [options] <substring>: Search for a package
 808         Options:
 809             -r <feedname>: Only search in this feed
 810
 811         uninstall -a|<package>: Uninstall a package
 812         Options:
 813             -a :           Uninstalls all packages.
 814
 815         update -a|<feedname(s)>: Update packages and lists of feeds in feeds.conf .
 816         Options:
 817             -a :           Update all feeds listed within feeds.conf. Otherwise the specified feeds will be updated.
 818             -i :           Recreate the index only. No feed update from repository is performed.
 819             -f :           Force updating feeds even if there are changed, uncommitted files.
 820
 821         clean:             Remove downloaded/generated files.
 822
 823 EOF
 824         exit(1);
 825 }
 826
 827 my %commands = (
 828         'list' => \&list,
 829         'update' => \&update,
 830         'install' => \&install,
 831         'search' => \&search,
 832         'uninstall' => \&uninstall,
 833         'feed_config' => \&feed_config,
 834         'clean' => sub {
 835                 system("rm -rf ./feeds ./package/feeds");
 836         }
 837 );
 838
 839 my $arg = shift @ARGV;
 840 $arg or usage();
 841 parse_config;
 842 foreach my $cmd (keys %commands) {
 843         $arg eq $cmd and do {
 844                 exit(&{$commands{$cmd}}());
 845         };
 846 }
 847 usage();